[VB.NET] การเชื่อมต่อ MySQL Server ทั้งแบบ Local และ Remote DataBase

thongkorn

โค้ด VB.NET (2010) ชุดนี้เพื่อทดสอบการเชื่อมต่อ MySQL Server (เวอร์ชั่น 5.7.17) แบบ Local DataBase (ระบบ LAN) และแบบ Remote DataBase เพื่อทำให้สามารถเชื่อมต่อจากเครื่องลูก (Client) ของ Windows Application ผ่านอินเทอร์เน็ตเข้ามายังตัว Server ได้ รวมไปถึงการตั้งค่าที่จำเป็นต่างๆ แอดมินได้ย้ายให้ไปเก็บลง Registry ของ Windows แทน ... จากเวอร์ชั่นก่อนๆที่ผ่านมาในส่วนของ Local DataBase ไม่มีปัญหาใดๆ แต่มักจะมีปัญหากับการใช้งานแบบ Remote DataBase ซึ่งครั้งนี้แอดมินได้แก้ไขปรับแต่งโค้ดให้มีการเชื่อมต่อและทำงานได้ (เกือบ) 100% ... ผิดถูกประการใดช่วยแจ้งให้แอดมินได้ทราบด้วย จักเป็นพระคุณอย่างยิ่ง

มาดูโค้ดกันเถอะ ... เราจะเริ่มต้นที่ frmLogin เป็นฟอร์ม Start Up ...

1. Imports MySql.Data.MySqlClient
   
2. Imports Microsoft.Win32
   
3. Imports System.IO
   
4. 
   
5. Public Class frmLogin
   
6. 
   
7.     '// ----------------------------------------------------------------------------------------------------
   
8.     '// S T A R T . . . H E R E
   
9.     '// ----------------------------------------------------------------------------------------------------
   
10.     Private Sub LoginForm_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    
11.         '//
    
12.     End Sub
    
13. 
    
14.     '// ----------------------------------------------------------------------------------------------------
    
15.     '// ล็อคอินเข้าสู่ระบบ
    
16.     '// ----------------------------------------------------------------------------------------------------
    
17.     Private Sub btnLogin_Click(sender As Object, e As EventArgs) Handles btnLogin.Click
    
18.         '// การตรวจสอบค่าว่างสำหรับ TextBox ด้วยการใช้ Dictionary ในการจับคู่
    
19.         '// Key: TextBox, Value: ข้อความแจ้งเตือน
    
20.         '// สร้าง Dictionary สำหรับ TextBox และข้อความแจ้งเตือน
    
21.         Dim RequiredFields As New Dictionary(Of TextBox, String) From {
    
22.             {txtUsername, "Enter your Username."},
    
23.             {txtPassword, "Enter your Password."}
    
24.         }
    
25.         '// ตรวจสอบแต่ละฟิลด์ใน Dictionary
    
26.         For Each Field In RequiredFields
    
27.             If String.IsNullOrWhiteSpace(Field.Key.Text) Then
    
28.                 MessageBox.Show(Field.Value, "Report status", MessageBoxButtons.OK, MessageBoxIcon.Exclamation)
    
29.                 Field.Key.Focus()
    
30.                 Return
    
31.             End If
    
32.         Next
    
33.         '// อ่านค่า Connection String จาก Registry (หากกรณีที่มีการเปลี่ยนแปลงค่าใน frmConnection.vb)
    
34.         MySQLConnectionManager.LoadFromRegistry()
    
35.         '// ตรวจสอบการ Connection ก่อนที่จะเข้าไปอ่านฐานข้อมูลใน Payroll
    
36.         If Not MySQLConnectionManager.TestConnection() Then
    
37.             MessageBox.Show("Connection Manager is not initialized.", "Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
    
38.             '// เปิดฟอร์มการตั้งค่า Connection
    
39.             frmConnection.ShowDialog()
    
40.             Return
    
41.         End If
    
42.         '// ตรวจสอบการ Connection ก่อนที่จะเข้าไปอ่านฐานข้อมูลใน Payroll
    
43.         Using Conn As New MySqlConnection(MySQLConnectionManager.GetConnectionString())
    
44.             Try
    
45.                 Conn.Open()
    
46.                 '// ตรวจสอบข้อมูลผู้ใช้ในฐานข้อมูล
    
47.                 If ValidateUser(Conn, txtUsername.Text, txtPassword.Text) Then
    
48.                     MessageBox.Show("เข้าสู่ระบบสำเร็จสมบูรณ์", "สำเร็จ", MessageBoxButtons.OK, MessageBoxIcon.Information)
    
49.                     Me.Hide()
    
50.                     Dim MainForm As New frmMain
    
51.                     MainForm.ShowDialog()
    
52.                     '// เมื่อฟอร์มหลักปิด ก็กลับมาปิดฟอร์มตัวมันเองด้วย
    
53.                     Me.Close()
    
54.                 Else
    
55.                     MessageBox.Show("Username หรือ Password ไม่ถูกต้อง", "ข้อผิดพลาด", MessageBoxButtons.OK, MessageBoxIcon.Error)
    
56.                 End If
    
57.             Catch ex As Exception
    
58.                 MessageBox.Show("เกิดข้อผิดพลาด: " & ex.Message, "Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
    
59.                 frmConnection.ShowDialog()
    
60.             End Try
    
61.         End Using
    
62.     End Sub
    
63. 
    
64.     '// ----------------------------------------------------------------------------------------------------
    
65.     '// ตรวจสอบ Username และ Password ในตารางข้อมูล tblUser
    
66.     '// ----------------------------------------------------------------------------------------------------
    
67.     Private Function ValidateUser(ByVal Conn As MySqlConnection, ByVal username As String, ByVal password As String) As Boolean
    
68.         Dim query As String = "SELECT * FROM tblUser WHERE username = @username AND password = @password"
    
69.         Using cmd As New MySqlCommand(query, Conn)
    
70.             cmd.Parameters.AddWithValue("@username", username)
    
71.             cmd.Parameters.AddWithValue("@password", password)
    
72.             Using reader As MySqlDataReader = cmd.ExecuteReader()
    
73.                 If reader.HasRows Then
    
74.                     While reader.Read()
    
75.                         '// เก็บข้อมูลการเข้าใช้งานของผู้ใช้ โดยประกาศเป็น Global Variable สำหรับข้อมูลของผู้ใช้งาน
    
76.                         '// Public CurrUser As New MySQLUserInfo (อยู่ใน modGlobalVariables.vb)
    
77.                         CurrUser.UserPK = CInt(reader("UserPK").ToString())
    
78.                         CurrUser.Username = reader("Username").ToString()
    
79.                         CurrUser.CompleteName = reader("CompleteName").ToString()
    
80.                         CurrUser.TimeLogin = DateTime.Now() '// Time Stamp
    
81.                         CurrUser.IsAdmin = CBool(reader("IsAdmin").ToString())
    
82.                     End While
    
83.                     Return True
    
84.                 Else
    
85.                     Return False
    
86.                 End If
    
87.             End Using
    
88.         End Using
    
89.     End Function
    
90. 
    
91.     '// ----------------------------------------------------------------------------------------------------
    
92.     '// ตั้งค่า Connection
    
93.     '// ----------------------------------------------------------------------------------------------------
    
94.     Private Sub btnConnection_Click(sender As System.Object, e As System.EventArgs) Handles btnConnection.Click
    
95.         frmConnection.ShowDialog()
    
96.     End Sub
    
97. 
    
98.     Private Sub btnExit_Click(sender As System.Object, e As System.EventArgs) Handles btnExit.Click
    
99.         Me.Close()
    
100.     End Sub
     
101. 
     
102.     Private Sub frmLogin_FormClosed(sender As Object, e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
     
103.         Me.Dispose()
     
104.         GC.SuppressFinalize(Me)
     
105.     End Sub
     
106. 
     
107.     Private Sub txtUsername_GotFocus(sender As Object, e As System.EventArgs) Handles txtUsername.GotFocus
     
108.         Call EnglishLanguage()
     
109.     End Sub
     
110. 
     
111.     Private Sub txtUsername_KeyPress(sender As Object, e As System.Windows.Forms.KeyPressEventArgs) Handles txtUsername.KeyPress
     
112.         If Asc(e.KeyChar) = 13 Then
     
113.             e.Handled = True
     
114.             SendKeys.Send("{TAB}")
     
115.         End If
     
116.     End Sub
     
117. 
     
118.     Private Sub txtPassword_KeyPress(sender As Object, e As System.Windows.Forms.KeyPressEventArgs) Handles txtPassword.KeyPress
     
119.         If Asc(e.KeyChar) = 13 Then
     
120.             e.Handled = True
     
121.             Call btnLogin_Click(sender, e)
     
122.         End If
     
123.     End Sub
     
124. 
     
125.     Private Sub txtPassword_GotFocus(sender As Object, e As System.EventArgs) Handles txtPassword.GotFocus
     
126.         Call EnglishLanguage()
     
127.     End Sub
     
128. 
     
129. End Class

คัดลอกไปที่คลิปบอร์ด

โค้ดในส่วนของการทำการเชื่อมต่อ MySQL Server ... frmConnection.vb ...

1. Imports MySql.Data.MySqlClient
   
2. Imports Microsoft.Win32
   
3. 
   
4. Public Class frmConnection
   
5.     Private ConnectionManager As New MySQLConnectionManager()
   
6. 
   
7.     '// ----------------------------------------------------------------------------------------------------
   
8.     '// S T A R T ... H E R E
   
9.     '// ----------------------------------------------------------------------------------------------------
   
10.     Private Sub frmConnection_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    
11.         '// อ่านค่า Connection String จาก Registry
    
12.         MySQLConnectionManager.LoadFromRegistry()
    
13.         '// โหลดค่าจาก ConnectionManager
    
14.         Call LoadSettings()
    
15.     End Sub
    
16. 
    
17.     Private Sub LoadSettings()
    
18.         '// ตรวจสอบว่า ConnectionManager มีค่าหรือไม่
    
19.         If ConnectionManager IsNot Nothing Then
    
20.             txtHost.Text = MySQLConnectionManager.Host
    
21.             txtDBName.Text = MySQLConnectionManager.DBName
    
22.             txtDBPort.Text = MySQLConnectionManager.DBPort
    
23.             txtDBUsername.Text = MySQLConnectionManager.DBUsername
    
24.             txtDBPassword.Text = MySQLConnectionManager.DBPassword
    
25.         Else
    
26.             MessageBox.Show("ConnectionManager is null.", "Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
    
27.         End If
    
28.     End Sub
    
29. 
    
30.     '// ----------------------------------------------------------------------------------------------------
    
31.     '// ทดสอบการเชื่อมต่อและทำการบันทึกข้อมูลลงใน Registry
    
32.     '// ----------------------------------------------------------------------------------------------------
    
33.     Private Sub btnConnection_Click(sender As Object, e As EventArgs) Handles btnConnect.Click
    
34.         '// บันทึกค่าใหม่
    
35.         MySQLConnectionManager.Host = txtHost.Text.Trim()
    
36.         MySQLConnectionManager.DBName = txtDBName.Text.Trim()
    
37.         MySQLConnectionManager.DBPort = txtDBPort.Text.Trim()
    
38.         MySQLConnectionManager.DBUsername = txtDBUsername.Text.Trim()
    
39.         MySQLConnectionManager.DBPassword = txtDBPassword.Text.Trim()
    
40.         If Not MySQLConnectionManager.TestConnection() Then
    
41.             MessageBox.Show("Connection Manager is not initialized.", "Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
    
42.             Return
    
43.         Else
    
44.             '// บันทึกลง Registry
    
45.             MySQLConnectionManager.SaveToRegistry()
    
46.             MessageBox.Show("บันทึกการตั้งค่าเรียบร้อยแล้ว", "สำเร็จ", MessageBoxButtons.OK, MessageBoxIcon.Information)
    
47.             Me.Close()
    
48.         End If
    
49.     End Sub
    
50. 
    
51.     Private Sub btnExit_Click(sender As System.Object, e As System.EventArgs) Handles btnExit.Click
    
52.         Me.Close()
    
53.     End Sub
    
54. 
    
55.     Private Sub TextBox_KeyPress(sender As Object, e As KeyPressEventArgs) Handles txtHost.KeyPress, txtDBName.KeyPress, txtDBPassword.KeyPress, txtDBUsername.KeyPress, txtDBPort.KeyPress
    
56.         '// ตรวจสอบว่าปุ่มที่กดคือ Enter
    
57.         If Asc(e.KeyChar) = Keys.Enter Then
    
58.             e.Handled = True '// ยกเลิกการประมวลผลปุ่ม Enter
    
59.             SendKeys.Send("{TAB}") '// ส่งคีย์ Tab เพื่อเปลี่ยนโฟกัสไปยัง Control ถัดไป
    
60.         End If
    
61.     End Sub
    
62. End Class

คัดลอกไปที่คลิปบอร์ด

โค้ดในส่วนของฟอร์มหลัก เพื่อแสดงผลข้อมูลตัวอย่างในตารางกริด ... frmMain.vb ...

1. Imports MySql.Data.MySqlClient
   
2. 
   
3. Public Class frmMain
   
4. 
   
5.     Private clsDB As MySQLDataBase
   
6. 
   
7.     Private Sub frmMain_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
   
8.         '// โหลดค่าการตั้งค่าการเชื่อมต่อจาก Registry
   
9.         MySQLConnectionManager.LoadFromRegistry()
   
10.         '// ตรวจสอบว่ามีการเชื่อมต่อสำเร็จแล้วหรือไม่
    
11.         If Not MySQLConnectionManager.IsConnected() Then
    
12.             MessageBox.Show("การเชื่อมต่อฐานข้อมูลยังไม่พร้อม กรุณาตรวจสอบการเชื่อมต่อ", "ข้อผิดพลาด", MessageBoxButtons.OK, MessageBoxIcon.Error)
    
13.             Return
    
14.         End If
    
15.         '// แสดงค่า Host, Database, และ Username ใน Statusbar
    
16.         staHost.Text = "Host : " & MySQLConnectionManager.Host & "        "
    
17.         staDatabase.Text = "Database : " & MySQLConnectionManager.DBName & "        "
    
18.         '// ใช้ CurrUser ภายในคลาส MySQLUserInfo
    
19.         staUsername.Text = "Username : " & CurrUser.Username & "        "
    
20. 
    
21.         '// สร้าง Instance ของ clsDataBaseMySQL โดยส่ง Connection String ไป
    
22.         clsDB = New MySQLDataBase(MySQLConnectionManager.GetConnectionString)
    
23.         '// ทดสอบการเชื่อมต่อฐานข้อมูลผ่านคลาส clsDB (หากต้องการทดสอบ)
    
24.         If Not clsDB.TestDBConnection() Then
    
25.             MessageBox.Show("ไม่สามารถเชื่อมต่อฐานข้อมูลได้", "ข้อผิดพลาด", MessageBoxButtons.OK, MessageBoxIcon.Error)
    
26.             Return
    
27.         End If
    
28. 
    
29.         '// ดึงข้อมูลจากฐานข้อมูล โดยมี Optional เป็น False (ไม่ต้องใส่ค่านี้ก็ได้) เพื่อให้แสดงผลออกมาทั้งหมด
    
30.         Dim DT As DataTable = GetDataTable()
    
31.         '// ตรวจสอบว่ามีข้อมูลหรือไม่
    
32.         If DT IsNot Nothing AndAlso DT.Rows.Count > 0 Then
    
33.             '// ผูกข้อมูลกับ DataGridView
    
34.             dgvData.DataSource = DT
    
35.             '// ตั้งค่าตารางกริด
    
36.             Call SetupDataGridView()
    
37.         Else
    
38.             '// ถ้าไม่มีข้อมูล ให้เคลียร์ DataSource และแถวทั้งหมด
    
39.             dgvData.DataSource = Nothing
    
40.             dgvData.Rows.Clear()
    
41.             MessageBox.Show("ไม่พบข้อมูลในฐานข้อมูล", "แจ้งเตือน", MessageBoxButtons.OK, MessageBoxIcon.Information)
    
42.         End If
    
43.         lblRecordCount.Text = "จำนวน : " & dgvData.RowCount & " รายการ"
    
44.     End Sub
    
45. 
    
46.     '// ----------------------------------------------------------------------------------------------------------
    
47.     '// blnSearch = True, Show that the search results.
    
48.     '// blnSearch is set to False, Show all records.
    
49.     '// ----------------------------------------------------------------------------------------------------------
    
50.     Private Function GetDataTable(Optional ByVal blnSearch As Boolean = False) As DataTable
    
51.         Dim strSQL As String = _
    
52.             " SELECT tblemployee.EmployeePK, tblemployee.EmployeeID, tblemployee.Fullname, tblemployee.HireDate, " & _
    
53.             " tblemployee.Salary, tblposition.PositionName, tbldepartment.DepartmentName " & _
    
54.             " FROM tblposition INNER JOIN (tbldepartment INNER JOIN tblemployee ON " & _
    
55.             " tbldepartment.DepartmentPK = tblemployee.DepartmentFK) ON tblposition.PositionPK = tblemployee.PositionFK "
    
56.         '// blnSearch = True ก็คือการค้นหาข้อมูล ตามที่คีย์ใน TxtSearch.Text
    
57.         If blnSearch Then
    
58.             strSQL = strSQL & _
    
59.                     " WHERE " & _
    
60.                     " (EmployeeID " & " Like '%" & txtSearch.Text & "%'" & " OR " & _
    
61.                     " Fullname " & " Like '%" & txtSearch.Text & "%'" & " OR " & _
    
62.                     " PositionName " & " Like '%" & txtSearch.Text & "%'" & " OR " & _
    
63.                     " DepartmentName " & " Like '%" & txtSearch.Text & "%'" & " OR " & _
    
64.                     " Mobile " & " Like '%" & txtSearch.Text & "%'" & " OR " & _
    
65.                     " Phone " & " Like '%" & txtSearch.Text & "%'" & " OR " & _
    
66.                     " eMail " & " Like '%" & txtSearch.Text & "%'" & " OR " & _
    
67.                     " LineID " & " Like '%" & txtSearch.Text & "%'" & " OR " & _
    
68.                     " FaceBookID " & " Like '%" & txtSearch.Text & "%'" & _
    
69.                     ") ORDER BY EmployeePK "
    
70. 
    
71.             '// แสดงผลทั้งหมด
    
72.         Else
    
73.             strSQL = strSQL & " ORDER BY EmployeePK "
    
74.         End If
    
75.         '// เรียกใช้งานไปยังคลาส MySQLDataBase.vb
    
76.         Return clsDB.RecordToScreen(strSQL)
    
77.     End Function
    
78. 
    
79.     '// ----------------------------------------------------------------------------------------------------
    
80.     '// การตั้งค่าให้กับตารางกริดในแบบการใช้โค้ด หรือ Run Time
    
81.     '// ----------------------------------------------------------------------------------------------------
    
82.     Private Sub SetupDataGridView()
    
83.         With dgvData
    
84.             '// ตั้งค่าพื้นฐานของ DataGridView
    
85.             .RowHeadersVisible = False
    
86.             .AllowUserToAddRows = False
    
87.             .AllowUserToDeleteRows = False
    
88.             .AllowUserToResizeRows = False
    
89.             .MultiSelect = False
    
90.             .SelectionMode = DataGridViewSelectionMode.FullRowSelect
    
91.             .ReadOnly = True
    
92.             .Font = New Font("Tahoma", 11, FontStyle.Regular)
    
93.             .RowTemplate.MinimumHeight = 27
    
94.             .RowTemplate.Height = 27
    
95.             .ColumnHeadersHeight = 32
    
96.             .AutoSizeColumnsMode = DataGridViewAutoSizeColumnsMode.Fill '// ปรับขนาดคอลัมน์ให้เหมาะสม
    
97.             .EnableHeadersVisualStyles = False  '// Accept color background changes.
    
98.             .AlternatingRowsDefaultCellStyle.BackColor = Color.AliceBlue
    
99.         End With
    
100.         '// ปรับแต่งการแสดงผล Header ของตารางกริด
     
101.         With dgvData.ColumnHeadersDefaultCellStyle
     
102.             .BackColor = Color.Navy
     
103.             .ForeColor = Color.Black '// Color.White
     
104.             .Font = New Font("Tahoma", 11, FontStyle.Bold)
     
105.         End With
     
106.         '//
     
107.         '// ปรับแต่งคอลัมน์ EmployeePK (ซ่อนคอลัมน์)
     
108.         With dgvData.Columns("EmployeePK")
     
109.             .HeaderText = "EmployeePK"
     
110.             .Visible = False '// ซ่อนคอลัมน์
     
111.         End With
     
112.         '// ปรับแต่งคอลัมน์ EmployeeID
     
113.         With dgvData.Columns("EmployeeID")
     
114.             .HeaderText = "รหัสพนักงาน"
     
115.             .ReadOnly = True
     
116.         End With
     
117.         '// ปรับแต่งคอลัมน์ Fullname
     
118.         With dgvData.Columns("Fullname")
     
119.             .HeaderText = "ชื่อ-นามสกุล"
     
120.             .ReadOnly = True
     
121.         End With
     
122.         '// ปรับแต่งคอลัมน์ PositionName
     
123.         With dgvData.Columns("PositionName")
     
124.             .HeaderText = "ตำแหน่ง"
     
125.             .ReadOnly = True
     
126.         End With
     
127.         '// ปรับแต่งคอลัมน์ DepartmentName
     
128.         With dgvData.Columns("DepartmentName")
     
129.             .HeaderText = "แผนก"
     
130.             .ReadOnly = True
     
131.         End With
     
132.         '// ปรับแต่งคอลัมน์ Salary
     
133.         With dgvData.Columns("Salary")
     
134.             .HeaderText = "เงินเดือน"
     
135.             .DefaultCellStyle.Format = "N2" '// จัดรูปแบบเป็นตัวเลขทศนิยม 2 ตำแหน่ง
     
136.             .HeaderCell.Style.Alignment = DataGridViewContentAlignment.MiddleRight
     
137.             .DefaultCellStyle.Alignment = DataGridViewContentAlignment.MiddleRight '// จัดชิดขวา
     
138.             .ReadOnly = True
     
139.         End With
     
140.         '// ปรับแต่งคอลัมน์ HireDate
     
141.         With dgvData.Columns("HireDate")
     
142.             .HeaderText = "วันที่เริ่มงาน"
     
143.             .DefaultCellStyle.Format = "dd/MM/yyyy" '// จัดรูปแบบวันที่
     
144.             .HeaderCell.Style.Alignment = DataGridViewContentAlignment.MiddleRight
     
145.             .DefaultCellStyle.Alignment = DataGridViewContentAlignment.MiddleRight '// จัดชิดขวา
     
146.             .ReadOnly = True
     
147.         End With
     
148.         For iCol = 0 To dgvData.Columns.Count - 1
     
149.             '// Calculates odd and even numbers. If any integer divide by 2, then answer 1 is odd number.
     
150.             If iCol Mod 2 = 1 Then
     
151.                 dgvData.Columns(iCol).HeaderCell.Style.BackColor = Color.Gold
     
152.                 '// Integer divide by 2, then answer 1 is Even number.
     
153.             Else
     
154.                 dgvData.Columns(iCol).HeaderCell.Style.BackColor = Color.LightGoldenrodYellow
     
155.             End If
     
156.         Next
     
157.     End Sub
     
158. 
     
159.     '// ----------------------------------------------------------------------------------------------------
     
160.     '// การแสดงผลข้อมูลออกมาทั้งหมด
     
161.     '// ----------------------------------------------------------------------------------------------------
     
162.     Private Sub btnRefresh_Click(sender As Object, e As System.EventArgs) Handles btnRefresh.Click
     
163.         '// แสดงผลข้อมูลทั้งหมด
     
164.         dgvData.DataSource = GetDataTable(False)
     
165.         lblRecordCount.Text = "จำนวน : " & dgvData.RowCount & " รายการ"
     
166.         txtSearch.Focus()
     
167.     End Sub
     
168. 
     
169.     Private Sub txtSearch_KeyPress(sender As Object, e As KeyPressEventArgs) Handles txtSearch.KeyPress
     
170.         '// ลบอักขระที่ไม่พึงประสงค์ออกจากช่องค้นหา เช่น ', %, *
     
171.         Call RemoveUndesirableCharacters()
     
172.         '// หากช่องค้นหาว่างเปล่า ให้ยกเลิกการทำงาน
     
173.         If String.IsNullOrWhiteSpace(txtSearch.Text) Then Exit Sub
     
174.         '// เมื่อกด Enter (ASCII Code = 13)
     
175.         If e.KeyChar = Chr(13) Then
     
176.             '// ปิดเสียง Beep เมื่อกด Enter
     
177.             e.Handled = True
     
178.             '// เรียกใช้งานฟังก์ชันค้นหาข้อมูล
     
179.             Call SearchAndDisplayData()
     
180.         End If
     
181.     End Sub
     
182. 
     
183.     '''// <summary>
     
184.     '''// ลบอักขระที่ไม่พึงประสงค์ออกจากช่องค้นหา
     
185.     '''// </summary>
     
186.     Private Sub RemoveUndesirableCharacters()
     
187.         txtSearch.Text = txtSearch.Text.Trim.Replace("'", "").Replace("%", "").Replace("*", "")
     
188.         txtSearch.SelectionStart = txtSearch.Text.Length '// ย้ายเคอร์เซอร์ไปท้ายข้อความ
     
189.     End Sub
     
190. 
     
191.     '''// <summary>
     
192.     '''// ค้นหาข้อมูลและแสดงผลใน DataGridView
     
193.     '''// </summary>
     
194.     Private Sub SearchAndDisplayData()
     
195.         '// ดึงข้อมูลจากฐานข้อมูลตามคำค้นหา
     
196.         dgvData.DataSource = GetDataTable(True)
     
197.         '// อัปเดตจำนวนรายการที่พบ
     
198.         lblRecordCount.Text = "จำนวน : " & dgvData.RowCount & " รายการ"
     
199.         '// ล้างข้อความในช่องค้นหา
     
200.         txtSearch.Clear()
     
201.     End Sub
     
202. 
     
203.     Private Sub frmMain_FormClosed(sender As Object, e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
     
204.         Me.Dispose()
     
205.         GC.SuppressFinalize(Me)
     
206.         Application.Exit()
     
207.     End Sub
     
208. 
     
209. End Class

คัดลอกไปที่คลิปบอร์ด

ส่วนของคลาส (Class) ในการติดต่อกับ MySQL Server ... MySQLConnectManager.vb ...

1. Imports Microsoft.Win32
   
2. Imports MySql.Data.MySqlClient
   
3. 
   
4. Public Class MySQLConnectionManager
   
5.     '// ตัวแปรสำหรับเก็บสถานะการเชื่อมต่อ
   
6.     Private Shared _isConnected As Boolean = False
   
7.     '// ----------------------------------------------------------------------------------------------------
   
8.     '// ประกาศตัวแปรสำหรับเก็บค่า Connection String
   
9.     Public Shared Host As String
   
10.     Public Shared DBName As String
    
11.     Public Shared DBPort As String
    
12.     Public Shared DBUsername As String
    
13.     Public Shared DBPassword As String
    
14.     '// พาธใน Registry ที่จะใช้เก็บข้อมูล
    
15.     Private Const RegistryPath As String = "SOFTWARE\VB and VBA Program Settings\MySQLConnection\ConfigDB"
    
16. 
    
17.     '// ค่า Default สำหรับ Connection String
    
18.     Private Const DefaultHost As String = "localhost"
    
19.     Private Const DefaultDBName As String = "payroll"
    
20.     Private Const DefaultDBPort As String = "3306"
    
21.     Private Const DefaultDBUsername As String = "USER"  '// เปลี่ยนด้วย
    
22.     '// ปกติไม่ควรนำรหัสผ่านมาเก็บไว้ หรือหากต้องการจะใช้จริงๆก็ควรจะเข้ารหัสเอาไว้ก่อนด้วย
    
23.     Private Const DefaultDBPassword As String = "PASSWORD"  '// เปลี่ยนด้วย
    
24. 
    
25.     '// ----------------------------------------------------------------------------------------------------
    
26.     '// เมธอดสำหรับบันทึกค่าลงใน Registry
    
27.     '// ----------------------------------------------------------------------------------------------------
    
28.     Public Shared Sub SaveToRegistry()
    
29.         Dim RegistryKey As RegistryKey = Registry.CurrentUser.CreateSubKey(RegistryPath)
    
30.         Try
    
31.             RegistryKey.SetValue("Host", Host)
    
32.             RegistryKey.SetValue("DBName", DBName)
    
33.             RegistryKey.SetValue("DBPort", DBPort)
    
34.             RegistryKey.SetValue("DBUsername", DBUsername)
    
35.             RegistryKey.SetValue("DBPassword", DBPassword)
    
36.         Finally
    
37.             RegistryKey.Close()
    
38.         End Try
    
39.     End Sub
    
40. 
    
41.     '// ----------------------------------------------------------------------------------------------------
    
42.     '// เมธอดสำหรับอ่านค่าจาก Registry
    
43.     '// ----------------------------------------------------------------------------------------------------
    
44.     Public Shared Sub LoadFromRegistry()
    
45.         Dim RegistryKey As RegistryKey = Registry.CurrentUser.OpenSubKey(RegistryPath)
    
46.         If RegistryKey IsNot Nothing Then
    
47.             Try
    
48.                 '// อ่านค่าจาก Registry (ถ้ามี)
    
49.                 Host = RegistryKey.GetValue("Host", DefaultHost).ToString()
    
50.                 DBName = RegistryKey.GetValue("DBName", DefaultDBName).ToString()
    
51.                 DBPort = RegistryKey.GetValue("DBPort", DefaultDBPort).ToString()
    
52.                 DBUsername = RegistryKey.GetValue("DBUsername", DefaultDBUsername).ToString()
    
53.                 DBPassword = RegistryKey.GetValue("DBPassword", DefaultDBPassword).ToString()
    
54.             Finally
    
55.                 RegistryKey.Close()
    
56.             End Try
    
57.         Else
    
58.             '// หากไม่พบคีย์ใน Registry ให้ใช้ค่า Default
    
59.             Host = DefaultHost
    
60.             DBName = DefaultDBName
    
61.             DBPort = DefaultDBPort
    
62.             DBUsername = DefaultDBUsername
    
63.             DBPassword = DefaultDBPassword
    
64.         End If
    
65.     End Sub
    
66. 
    
67.     '// ----------------------------------------------------------------------------------------------------
    
68.     '// เมธอดสำหรับการเชื่อมต่อ MySQL Server
    
69.     '// ----------------------------------------------------------------------------------------------------
    
70.     Public Shared Function GetConnectionString() As String
    
71.         '// สร้างเมธอดที่ประกอบสตริงจาก Dictionary หรือ List ของพารามิเตอร์
    
72.         Dim Parameters As New Dictionary(Of String, String) From {
    
73.             {"Server", Host},
    
74.             {"Database", DBName},
    
75.             {"Port", DBPort},
    
76.             {"User Id", DBUsername},
    
77.             {"Password", DBPassword},
    
78.             {"CharSet", "utf8"},
    
79.             {"Connect Timeout", "30"},
    
80.             {"Pooling", "True"},
    
81.             {"Persist Security Info", "True"},
    
82.             {"Connection Reset", "False"},
    
83.             {"Default Command Timeout", "300"}
    
84.         }
    
85.         '// สร้าง Connection String จาก Dictionary เช่น "Database", "payroll"
    
86.         Dim ConnectionString As String = String.Join(";", Parameters.Select(Function(p) p.Key & "=" & p.Value))
    
87.         Return ConnectionString
    
88.     End Function
    
89. 
    
90.     '// เมธอดสำหรับทดสอบการเชื่อมต่อ
    
91.     Public Shared Function TestConnection() As Boolean
    
92.         Using Conn As New MySqlConnection(GetConnectionString())
    
93.             Try
    
94.                 Conn.Open()
    
95.                 _isConnected = True '// ตั้งค่าสถานะการเชื่อมต่อสำเร็จ
    
96.                 Return True
    
97.             Catch ex As Exception
    
98.                 _isConnected = False '// ตั้งค่าสถานะการเชื่อมต่อล้มเหลว
    
99.                 Return False
    
100.             End Try
     
101.         End Using
     
102.     End Function
     
103. 
     
104.     '// เมธอดสำหรับรีเซ็ตสถานะการเชื่อมต่อ
     
105.     Public Shared Sub ResetConnectionState()
     
106.         _isConnected = False
     
107.     End Sub
     
108. 
     
109.     '// เมธอดสำหรับตรวจสอบสถานะการเชื่อมต่อ
     
110.     Public Shared Function IsConnected() As Boolean
     
111.         Return _isConnected
     
112.     End Function
     
113. 
     
114. End Class

คัดลอกไปที่คลิปบอร์ด

โค้ดในส่วนของคลาสที่จัดการกับตัวฐานข้อมูล ... MySQLDataBase.vb ...

1. Imports MySql.Data.MySqlClient
   
2. 
   
3. Public Class MySQLDataBase
   
4. 
   
5.     Private ReadOnly _ConnectionString As String
   
6. 
   
7.     '// Constructor สำหรับรับ Connection String
   
8.     Public Sub New(ConnectionString As String)
   
9.         _ConnectionString = ConnectionString
   
10.     End Sub
    
11. 
    
12.     '// ----------------------------------------------------------------------------------------------------
    
13.     '// ฟังค์ชั่นที่ใช้งานร่วมกันเพื่อทำการแสดงผลข้อมูลบนหน้าจอ
    
14.     '// หลักๆคือนำข้อมูลที่ได้จาก Sql มาแสดงผลในตารางกริด
    
15.     '// คืนค่ากลับด้วย DataTable
    
16.     '// ----------------------------------------------------------------------------------------------------
    
17.     Public Function RecordToScreen(ByVal Sql As String) As DataTable
    
18.         Dim dt As New DataTable()
    
19.         Using Conn As New MySqlConnection(_ConnectionString)
    
20.             Using cmd As New MySqlCommand(Sql, Conn)
    
21.                 Try
    
22.                     Conn.Open()
    
23.                     '// MySqlDataReader :
    
24.                     '// ใช้ cmd.ExecuteReader() เพื่อดึงข้อมูลจากฐานข้อมูลแบบ Row-by-Row
    
25.                     '// MySqlDataReader เป็น Forward-only และ Read-only
    
26.                     '// หมายความว่าเราสามารถอ่านข้อมูลได้ทีละแถวและไม่สามารถย้อนกลับไปยังแถวเดิมได้
    
27.                     Using reader As MySqlDataReader = cmd.ExecuteReader()
    
28.                         '// สร้างคอลัมน์ใน DataTable จากโครงสร้างของ DataReader
    
29.                         For i As Integer = 0 To reader.FieldCount - 1
    
30.                             dt.Columns.Add(reader.GetName(i), reader.GetFieldType(i))
    
31.                         Next
    
32.                         '// อ่านข้อมูลจาก DataReader และเพิ่มลงใน DataTable
    
33.                         While reader.Read()
    
34.                             Dim row As DataRow = dt.NewRow()
    
35.                             For i As Integer = 0 To reader.FieldCount - 1
    
36.                                 row(i) = reader(i)
    
37.                             Next
    
38.                             dt.Rows.Add(row)
    
39.                         End While
    
40.                     End Using
    
41.                 Catch ex As Exception
    
42.                     MessageBox.Show("เกิดข้อผิดพลาด: " & ex.Message, "ข้อผิดพลาด", MessageBoxButtons.OK, MessageBoxIcon.Error)
    
43.                     Return Nothing
    
44.                 End Try
    
45.             End Using
    
46.         End Using
    
47.         Return dt
    
48.     End Function
    
49. 
    
50.     '// --------------------------------------------------------------------------------
    
51.     '// เมธอดร่วมกันที่ใช้ในการ Insert/Update/Delete SQL Statement
    
52.     '// --------------------------------------------------------------------------------
    
53.     Public Function DoSQL(ByVal Sql As String) As Boolean
    
54.         DoSQL = False
    
55.         '// ใช้ Using สำหรับ MySqlConnection
    
56.         Using Conn As New MySqlConnection(_ConnectionString)
    
57.             Try
    
58.                 '// เปิดการเชื่อมต่อ
    
59.                 Conn.Open()
    
60.                 '// ใช้ Using สำหรับ MySqlCommand
    
61.                 Using SQLCmd As New MySqlCommand(Sql, Conn)
    
62.                     SQLCmd.CommandType = CommandType.Text
    
63.                     SQLCmd.ExecuteNonQuery()
    
64.                 End Using '// SQLCmd จะถูก Dispose โดยอัตโนมัติที่นี่
    
65.                 '// การอัปเดตสำเร็จ
    
66.                 DoSQL = True
    
67.             Catch ex As Exception
    
68.                 '// จัดการข้อผิดพลาด
    
69.                 MessageBox.Show( _
    
70.                     "Error Update DoSQL: " & _
    
71.                     ex.Message, _
    
72.                     "Error", _
    
73.                     MessageBoxButtons.OK, MessageBoxIcon.Error)
    
74.             End Try
    
75.         End Using '// Conn จะถูกปิดโดยอัตโนมัติที่นี่
    
76.     End Function
    
77. 
    
78.     '// เมธอดสำหรับทดสอบการเชื่อมต่อ
    
79.     Public Function TestDBConnection() As Boolean
    
80.         Using Conn As New MySqlConnection(_ConnectionString)
    
81.             Try
    
82.                 Conn.Open()
    
83.                 Return True
    
84.             Catch ex As Exception
    
85.                 Return False
    
86.             End Try
    
87.         End Using
    
88.     End Function
    
89. End Class

คัดลอกไปที่คลิปบอร์ด

โค้ดในส่วนของคลาสในการจัดการกับข้อมูลผู้ใช้ ... MySQLUserInfo.vb ...

1. '// ------------------------------------------------------------------
   
2. '// User-defined Class
   
3. Public Class MySQLUserInfo
   
4.     '// Primary Key of User
   
5.     Public Property UserPK As Integer
   
6.     '// Username or UserID
   
7.     Public Property Username As String
   
8.     '// Password
   
9.     Public Property Password As String
   
10.     '// Administrator is True
    
11.     Public Property IsAdmin As Boolean
    
12.     '// Completename
    
13.     Public Property CompleteName As String
    
14.     '// Time Stamp
    
15.     Public Property TimeLogin As Date
    
16. End Class

คัดลอกไปที่คลิปบอร์ด

โค้ดในส่วนของโมดูลการจัดการด้วยฟังค์ชั่นทั่วไป ... modFunction.vb ...

1. Module modFunction
   
2.     ' / --------------------------------------------------------------------------------
   
3.     ' / Get my project path
   
4.     ' / AppPath = C:\My Project\bin\debug
   
5.     ' / Replace "\bin\debug" with ""
   
6.     ' / Return : C:\My Project\
   
7.     Function MyPath(AppPath As String) As String
   
8.         '/ Return Value
   
9.         MyPath = AppPath.ToLower.Replace("\bin\debug", "").Replace("\bin\release", "").Replace("\bin\x86\debug", "")
   
10.         '// If not found folder then put the \ (BackSlash ASCII Code = 92) at the end.
    
11.         If Microsoft.VisualBasic.Right(MyPath, 1) <> Chr(92) Then MyPath = MyPath & Chr(92)
    
12.     End Function
    
13. 
    
14.     ' / Initialize English Language
    
15.     Public Sub EnglishLanguage()
    
16.         For Each Language As InputLanguage In InputLanguage.InstalledInputLanguages
    
17.             If Language.Culture.TwoLetterISOLanguageName.Contains("en") = True Then
    
18.                 InputLanguage.CurrentInputLanguage = Language
    
19.             End If
    
20.         Next
    
21.     End Sub
    
22. 
    
23.     ' / Initialize Thai Language
    
24.     Public Sub ThaiLanguage()
    
25.         For Each Language As InputLanguage In InputLanguage.InstalledInputLanguages
    
26.             If Language.Culture.TwoLetterISOLanguageName.Contains("th") = True Then
    
27.                 InputLanguage.CurrentInputLanguage = Language
    
28.             End If
    
29.         Next
    
30.     End Sub
    
31. 
    
32. End Module

คัดลอกไปที่คลิปบอร์ด

โค้ดในส่วนของโมดูลการประกาศตัวแปรแบบ Global ... modGlobalVariables.vb ... (ในโปรเจคนี้จะมองเห็นได้หมด) ...

1. Module modGlobalVariables
   
2.     '// ประกาศเป็น Global Variable สำหรับข้อมูลของผู้ใช้งาน
   
3.     Public CurrUser As New MySQLUserInfo
   
4. End Module

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดต้นฉบับ VB.NET (2010) ได้ที่นี่ ...