[VB.NET] โค้ดการใช้ Line Messaging API ด้วยการส่งไฟล์รูปภาพไปเก็บไว้ที่ Cloudinary ก่อนส่งต่อไปที่ LINE

thongkorn

*** จะต้องติดตั้ง CloudinaryDotNet เข้าไปใหม่ก่อนด้วย เพราะโค้ดต้นฉบับไม่ได้แนบไฟล์ DLL ไปด้วย ***
*** การติดตั้ง CloudinaryDotNet จะติดตั้ง NewTonSoft มาให้อัตโนมัติ ***

การใช้ Nuget เพื่อทำการติดตั้ง CloudinaryDotNet ... (เป็นที่เก็บไฟล์ Media ต่างๆ)

สมัครใช้งาน Cloudinary.com ได้ที่นี่ ...

คลิปวิดีโอในการสมัครใช้งาน Line Official Account เพื่อรับค่า Channel Access Token และ UserID (สำคัญ)

คลิปวิดีโอประกอบการอธิบายในโค้ดชุดนี้ ...

มาดูโค้ดฉบับเต็มกันเถอะ ... อย่าลืมใส่ค่าต่างๆก่อนที่จะรันโปรแกรมด้วย ...

1. '// สมัครการใช้งาน Line Messaging API ที่
   
2. '// https://manager.line.biz/
   
3. '// https://developers.line.biz/en/
   
4. '// จากนั้น สร้าง Channel ใน Line Messaging API
   
5. '// รับ Channel Access Token และ User ID จากหน้า Line Console
   
6. 
   
7. '// ติดตั้ง Library Newtonsoft.Json เพื่อช่วยจัดการ JSON
   
8. '// ใน NuGet Package Manager Console ใช้คำสั่ง:
   
9. '// Install-Package Newtonsoft.Json
   
10. '// .Net Framework 4.5
    
11. 
    
12. '// .Net SDK & Cloudinary Document
    
13. '// https://cloudinary.com/documentation/dotnet_integration
    
14. '// Sign Up
    
15. '// https://www.cloudinary.com
    
16. 
    
17. Imports System.IO
    
18. Imports CloudinaryDotNet
    
19. Imports CloudinaryDotNet.Actions
    
20. Imports System.Net.Http
    
21. Imports System.Net.Http.Headers
    
22. Imports Newtonsoft.Json
    
23. Imports System.Text
    
24. 
    
25. Public Class frmLineAPICloudinary
    
26.     '// ------------------------------------------------------------------------------------------------
    
27.     '// เก็บตำแหน่งและชื่อไฟล์ภาพต้นฉบับที่ต้องการอัพโหลด
    
28.     Dim PictureUploadPath As String = String.Empty
    
29.     '// แยกชื่อไฟล์+นามสกุล ออกจากโฟลเดอร์
    
30.     Dim UploadFileName As String = ""
    
31.     '// Default path.
    
32.     Dim PictureDefaultPath As String = MyPath(Application.StartupPath) & "Images"
    
33. 
    
34.     '// Cloudinary Configuration
    
35.     Private Const CLOUD_NAME As String = "CLOUD_NAME"
    
36.     Private Const API_KEY As String = "API_KEY"
    
37.     Private Const API_SECRET As String = "API_SECRET"
    
38.     '// กำหนดโฟลเดอร์ที่เก็บไฟล์บน Cloudinary
    
39.     Private Const CLOUD_FOLDER As String = "LineAPI"    '// สามารถเปลี่ยนชื่อโฟลเดอร์ได้ใหม่เลย
    
40. 
    
41.     '// Line Bot Config
    
42.     Private Const LINE_ACCESS_TOKEN As String = ""
    
43.     Private Const USER_ID As String = ""
    
44.     '// ------------------------------------------------------------------------------------------------
    
45. 
    
46.     Private Sub frmLineAPICloudinary_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    
47.         txtMessage.Text = "ทดสอบการทำงานของ Line Messaging API ด้วยการส่งข้อความและรูปภาพ"
    
48.     End Sub
    
49. 
    
50.     '// ------------------------------------------------------------------------------------------------
    
51.     '// ส่งข้อความและรูปภาพไปยัง LINE
    
52.     '// ------------------------------------------------------------------------------------------------
    
53.     Private Sub btnSendMessage_Click(sender As Object, e As EventArgs) Handles btnSendMessage.Click
    
54.         '// ตรวจสอบว่าทั้งข้อความและภาพว่างหรือไม่
    
55.         If String.IsNullOrWhiteSpace(txtMessage.Text.Trim) AndAlso String.IsNullOrWhiteSpace(PictureUploadPath) Then
    
56.             MessageBox.Show("กรุณาใส่ข้อความหรือเลือกภาพก่อนส่ง", "คำเตือน", MessageBoxButtons.OK, MessageBoxIcon.Warning)
    
57.             Return
    
58.         Else
    
59.             '// ทำการส่งข้อความและไฟล์ภาพไปใน Line Bot
    
60.             Call UploadImageAndSendToLine(PictureUploadPath, txtMessage.Text)
    
61.         End If
    
62.         '// Clear
    
63.         UploadFileName = ""
    
64.         PictureUploadPath = String.Empty
    
65.         picData.Image = Image.FromFile(PictureDefaultPath & "NoImage.gif")
    
66.     End Sub
    
67. 
    
68.     '// ------------------------------------------------------------------------------------------------
    
69.     '// คำสั่ง Async ใช้เพื่อระบุว่าฟังก์ชันหรือเมธอดสามารถดำเนินการแบบ Asynchronous
    
70.     '// หรือเป็นทำงานแบบไม่รอให้เสร็จสมบูรณ์ก่อนที่จะไปทำคำสั่งถัดไปได้
    
71.     '// โดยปกติจะใช้ร่วมกับคำสั่ง Await เพื่อเรียกใช้งานที่ใช้เวลานาน
    
72.     '// เช่น การร้องขอข้อมูลจาก API, อ่าน/เขียนไฟล์, หรือรอเครือข่าย โดยไม่บล็อกส่วนที่เหลือของแอพพลิเคชัน
    
73.     '// ------------------------------------------------------------------------------------------------
    
74.     Public Async Function UploadImageAndSendToLine(ByVal imagePath As String, ByVal message As String) As Task
    
75.         Dim account = New Account(CLOUD_NAME, API_KEY, API_SECRET)
    
76.         Dim cloudinary = New Cloudinary(account)
    
77.         Dim uploadResult As ImageUploadResult = Nothing
    
78.         Dim publicId As String = Nothing
    
79.         Dim imageUrl As String = String.Empty
    
80.         Try
    
81.             '// 1. Upload Image to Cloudinary
    
82.             If Not String.IsNullOrEmpty(imagePath) AndAlso IO.File.Exists(imagePath) Then
    
83.                 Dim uploadParams = New ImageUploadParams() With {
    
84.                     .File = New FileDescription(imagePath),
    
85.                     .Folder = CLOUD_FOLDER '// Line API folder on Cloudinary.
    
86.                 }
    
87.                 uploadResult = cloudinary.Upload(uploadParams)
    
88.                 imageUrl = uploadResult.SecureUrl.ToString()
    
89.                 publicId = uploadResult.PublicId
    
90.             End If
    
91. 
    
92.             '// 2. Send to LINE Messaging API
    
93.             Using client As New HttpClient()
    
94.                 client.DefaultRequestHeaders.Authorization = New AuthenticationHeaderValue("Bearer", LINE_ACCESS_TOKEN)
    
95.                 '// เตรียมรายการข้อความ สร้าง Payload ตามรูปแบบที่ Line API ต้องการ
    
96.                 '// Payload คือเนื้อหาข้อมูลที่ส่งไปยัง Line Server ผ่าน API เช่น การส่งข้อความ, การส่งรูปภาพ หรือการสร้าง Flex Message
    
97.                 '// ประกาศตัวแปร messages เป็นแบบ List(Of Object) จากนั้นค่อยนำไปแปลงให้อยู่ในรูปแบบ JSON Format
    
98.                 Dim messages = New List(Of Object)
    
99.                 '// ตรวจสอบว่ามีข้อความ
    
100.                 If Not String.IsNullOrEmpty(message) Then
     
101.                     messages.Add(New With {.type = "text", .text = message})
     
102.                 End If
     
103.                 '// ตรวจสอบว่ามี URL รูปภาพ
     
104.                 If Not String.IsNullOrEmpty(imageUrl) Then
     
105.                     messages.Add(New With {
     
106.                         .type = "image",
     
107.                         .originalContentUrl = imageUrl,
     
108.                         .previewImageUrl = imageUrl
     
109.                     })
     
110.                 End If
     
111.                 Dim payload = New With {
     
112.                     .to = USER_ID,
     
113.                     .messages = messages.ToArray()
     
114.                 }
     
115.                 '// สำหรับวิดีโอ
     
116.                 'If Not String.IsNullOrEmpty(videoUrl) AndAlso Not String.IsNullOrEmpty(videoPreviewUrl) Then
     
117.                 'messages.Add(New With {
     
118.                 'Key .type = "video",
     
119.                 'Key .originalContentUrl = videoUrl,
     
120.                 'Key .previewImageUrl = videoPreviewUrl
     
121.                 '})
     
122.                 'End If
     
123. 
     
124.                 '// แปลงเป็น JSON แล้วส่ง
     
125.                 Dim json = JsonConvert.SerializeObject(payload, Formatting.Indented)
     
126.                 '// ตัวอย่าง:
     
127.                 '// {
     
128.                 '//  "to": "USER_ID",
     
129.                 '//  "messages": [
     
130.                 '//     {
     
131.                 '//       "type": "text",
     
132.                 '//       "text": "สวัสดีครับ! นี่คือข้อความจาก Line Messaging API"
     
133.                 '//     },
     
134.                 '//     {
     
135.                 '//       "type": "image",
     
136.                 '//       "originalContentUrl": "https://example.com/image.jpg",
     
137.                 '//       "previewImageUrl": "https://example.com/image_preview.jpg" (หรือใช้ชื่อไฟล์ภาพ Content ตัวเดียวกันได้เลย)
     
138.                 '//     }
     
139.                 '//   ]
     
140.                 '// }
     
141.                 Dim content = New StringContent(json, Encoding.UTF8, "application/json")
     
142.                 Dim response = Await client.PostAsync("https://api.line.me/v2/bot/message/push", content)
     
143.                 Dim result = Await response.Content.ReadAsStringAsync()
     
144.                 If Not response.IsSuccessStatusCode Then
     
145.                     MessageBox.Show("เกิดข้อผิดพลาด: " & response.StatusCode & vbCrLf & result, "Report Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
     
146.                 End If
     
147.                 '// หากต้องการแสดงข้อความแจ้งเตือน
     
148.                 'If response.IsSuccessStatusCode Then
     
149.                 'MessageBox.Show("ส่งข้อความและรูปภาพสำเร็จ!", "Complete", MessageBoxButtons.OK, MessageBoxIcon.Information)
     
150.                 'Else
     
151.                 'MessageBox.Show("เกิดข้อผิดพลาด: " & response.StatusCode & vbCrLf & responseBody, "Report Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
     
152.                 'End If
     
153.             End Using
     
154. 
     
155.         Catch ex As Exception
     
156.             MessageBox.Show("Error: " & ex.Message)
     
157. 
     
158.             '// 3: Delete Image From Cloudinary.
     
159.         Finally
     
160.             If Not String.IsNullOrEmpty(publicId) Then
     
161.                 Try
     
162.                     Dim deletionParams As New DeletionParams(publicId)
     
163.                     Dim deletionResult = Cloudinary.Destroy(deletionParams)
     
164.                     'If deletionResult.Result = "ok" Then
     
165.                     '    MessageBox.Show("ลบภาพจาก Cloudinary สำเร็จ", "Report Status", MessageBoxButtons.OK, MessageBoxIcon.Information)
     
166.                     'Else
     
167.                     '    MessageBox.Show("ลบภาพไม่สำเร็จ: " & deletionResult.Result, "Report Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
     
168.                     'End If
     
169.                 Catch ex1 As Exception
     
170.                     MessageBox.Show("ลบภาพไม่สำเร็จ: " & ex1.Message, "Report Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
     
171.                 End Try
     
172.             End If
     
173.         End Try
     
174.     End Function
     
175. 
     
176.     '// ------------------------------------------------------------------------------------------------
     
177.     '// เบราซ์หาไฟล์ภาพ
     
178.     '// ------------------------------------------------------------------------------------------------
     
179.     Private Sub btnBrowse_Click(sender As Object, e As EventArgs) Handles btnBrowse.Click
     
180.         Dim dlgImage As OpenFileDialog = New OpenFileDialog()
     
181.         '// Open File Dialog
     
182.         With dlgImage
     
183.             .InitialDirectory = PictureDefaultPath
     
184.             .Title = "Select Image File"
     
185.             .Filter = "Format (*.jpg;*.jpeg;*.png)|*.jpg;*.jpeg;*.png"
     
186.             .FilterIndex = 1
     
187.             .RestoreDirectory = True
     
188.         End With
     
189.         '// Select OK after Browse ...
     
190.         If dlgImage.ShowDialog() = DialogResult.OK Then
     
191.             '// ตรวจสอบก่อนว่าขนาดไฟล์เกิน 1 MB. หรือไม่ (Cloudinary น่าจะอัพโหลดได้สูงสุด 10 MB.)
     
192.             Dim info As New FileInfo(dlgImage.FileName)
     
193.             If (info.Length / 1024) > 1024 Then
     
194.                 MessageBox.Show("The image file you selected is of size " & Format((info.Length / 1024), "#,##0") & " KB. is too big more than 1,024 KB.", "Report Status", MessageBoxButtons.OK, MessageBoxIcon.Warning)
     
195.                 Exit Sub
     
196.             End If
     
197.             '// Put the current image file into PictureBox Control.
     
198.             picData.Image = Image.FromFile(dlgImage.FileName)
     
199.             '// เอาเฉพาะชื่อไฟล์และนามสกุลภาพ (Filename + Extension) เช่น thongkorn.png
     
200.             UploadFileName = dlgImage.SafeFileName
     
201.             '// เอาไฟล์ภาพมาเต็มพาธ เพื่อระบุต้นทางไฟล์ก่อนทำการอัพโหลด
     
202.             PictureUploadPath = dlgImage.FileName
     
203.         End If
     
204.     End Sub
     
205. 
     
206.     '// ------------------------------------------------------------------------------------------------
     
207.     Private Sub btnClear_Click(sender As Object, e As EventArgs) Handles btnClear.Click
     
208.         picData.Image = Image.FromFile(PictureDefaultPath & "NoImage.gif")
     
209.         UploadFileName = ""
     
210.         PictureUploadPath = String.Empty
     
211.     End Sub
     
212. 
     
213.     Private Sub btnExit_Click(sender As Object, e As EventArgs) Handles btnExit.Click
     
214.         Me.Close()
     
215.     End Sub
     
216. 
     
217.     Private Sub frmLineAPICloudinary_FormClosed(sender As Object, e As FormClosedEventArgs) Handles Me.FormClosed
     
218.         Me.Dispose()
     
219.         GC.SuppressFinalize(Me)
     
220.         Application.Exit()
     
221.     End Sub
     
222. 
     
223. #Region "FUNCTION"
     
224.     '// / --------------------------------------------------------------------------------
     
225.     '// / Get my project path
     
226.     '// / AppPath = C:\My Project\bin\debug
     
227.     '// / Replace "\bin\debug" with ""
     
228.     '// / Return : C:\My Project\
     
229.     Function MyPath(ByVal AppPath As String) As String
     
230.         '/ MessageBox.Show(AppPath);
     
231.         AppPath = AppPath.ToLower()
     
232.         '/ Return Value
     
233.         MyPath = AppPath.Replace("\bin\debug", "").Replace("\bin\release", "").Replace("\bin\x86\debug", "")
     
234.         '// If not found folder then put the \ (BackSlash) at the end.
     
235.         If Microsoft.VisualBasic.Right(MyPath, 1) <> Chr(92) Then MyPath = MyPath & Chr(92)
     
236.     End Function
     
237. #End Region
     
238. 
     
239. End Class

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดต้นฉบับ VB.NET & .Net Framework 4.5.2+ ได้ที่นี่ ...