[VB6] การเชื่อมต่อคอมพิวเตอร์กับ RFID ภาค 3 (ติดต่อกับฐานข้อมูล)

thongkorn

หากท่านพึ่งเข้ามาอ่านในภาค 3 ทันที หากยังไม่เข้าใจหลักการการทำงานของ RFID (Radio Frequency IDentification) ก็ควรกลับไปยังจุดเริ่มต้นก่อนนะครับ โดยที่สามารถอ่านรายละเอียดต่างๆได้ตามลิ้งค์เหล่านี้ ... การเชื่อมต่อคอมพิวเตอร์กับ RFID ภาค 1 (ทฤษฎี และ รูปแบบข้อมูล) ... การเชื่อมต่อคอมพิวเตอร์กับ RFID ภาค 2 (ปฏิบัติแบบไม่ต้องมีอุปกรณ์ก็ได้) ...

และแน่นอนว่าแอดมินจะไม่ขอกล่าวถึงการเชื่อมต่อฐานข้อมูล MS Access ด้วย VB6 เพราะเคยเขียนโค้ดแจกจ่ายไปเยอะแยะแล้ว ท่านสามารถหาอ่านได้ที่แหล่งต้นฉบับที่แอดมินโพสต์เอาไว้ ... คลิ๊กไปอ่านบทความเก่าได้ที่นี่ ...





หลักการการทำงาน ... แอดมินจำลองการป้อนค่าข้อมูลจำนวน 16 หลัก (ไบต์) เช่น x1234567890ABxxx โดยที่ค่า x จะแทนค่าส่วนหัวท้ายของชุดข้อมูล โค้ดโปรแกรมจะทำการแยกมันออกมาให้ได้เฉพาะ Data จำนวน 12 หลักเท่านั้น เมื่อได้ค่า TAG ID มาครบ 12 หลัก ก็จะทำการตรวจสอบกับฐานข้อมูลว่ามีข้อมูลอยู่หรือไม่ หากไม่มีก็จบ แต่ถ้าหากมีก็จะแสดง TAG ID และรูปภาพออกมาแสดงผล ... จบ ...


การเรียกใช้งาน Microsoft ActiveX Data Objects 2.8 Library เพื่อทำการติดต่อกับไฟล์ฐานข้อมูล



มาดูโค้ดฉบับเต็มกันเลย ...

1. Option Explicit
   
2. 
   
3. Private Sub Form_Load()
   
4.     Me.Move (Screen.Width - Width) \ 2, (Screen.Height - Height) \ 2
   
5.     ' / Connect DataBase
   
6.     Call OpenDataBase
   
7.    
   
8.     ' / ตั้งค่าเพื่อทดสอบ ID ขนาดข้อมูลความยาว 16 หลัก กรณีที่ไม่มีชุด RFID ทดสอบ
   
9.     ' / หรือ พิมพ์ชุดข้อมูลใน Notepad ก่อน แล้ว Copy ไปวางใส่ในช่อง TextBox ก็ได้ครับ
   
10.     txtTagID.Text = "x1234567890ABxxx"
    
11.    
    
12.     ' / กรณีมีชุดทดสอบ ต้องเคลียร์ค่าว่างเปล่าน่ะครับ
    
13.     ' / txtTagID.Text = ""
    
14.    
    
15.     ' / เริ่มต้นตั้งค่าพอร์ทก่อน หากผิดพลาดให้ออกไปจากโปรแกรม
    
16.     If Not InitializePort Then End
    
17.     ' /หรือ
    
18.     'Call InitializePort
    
19.    
    
20.     ' / เมื่อ 1000 millisecond = 1 second
    
21.     ' / ตั้งเวลา Timer ให้กระตุ้นการทำงานทุกๆ 100 millisecond.
    
22.     ' / นั่นก็คือ ทุกๆ 100 ms. จะมีการกระตุ้นการทำงานในส่วนการรับข้อมูล MSComm1_OnComm
    
23.     Timer1.Interval = 100
    
24.     ' / ตั้งรูปแบบ ListView
    
25.     With lvwData
    
26.         .ListItems.Clear
    
27.         .View = lvwReport
    
28.         ' / ตั้งค่า ListView แสดงผล
    
29.         .ColumnHeaders.Add 1, , "Item", 800
    
30.         .ColumnHeaders.Add 2, , "Tag ID", .Width \ 2 - 630
    
31.         .ColumnHeaders.Add 3, , "วันที่ - เวลา การอ่านข้อมูล", .Width \ 2 - 500
    
32.     End With
    
33. 
    
34. End Sub
    
35. 
    
36. ' / --------------------------------------------------------------------------------
    
37. ' / ตั้งค่าเริ่มต้นให้กับ Port ก่อน
    
38. Function InitializePort() As Boolean
    
39. ' / ผมทำเป็นฟังค์ชั่น (เสมอ) เพราะบางครั้งก่อนทำงานจริงต้องตรวจสอบความพร้อม ...
    
40. ' / ของพอร์ทที่ใช้งานด้วย หาก Return ค่ากลับเป็น False ก็ต้องหยุดการทำงานไว้ก่อน
    
41. ' / --------------------------------------------------------------------------------
    
42. On Error GoTo ErrHandler
    
43.    
    
44.     With MSComm1
    
45.         ' / ทดสอบก่อนว่า Port เปิดใช้งานหรือไม่ หากเปิดไว้ก็ให้ปิด Port ก่อน
    
46.         If .PortOpen Then .PortOpen = False
    
47.         
    
48.         ' / ตั้งค่า Port ที่ต้องการ
    
49.         .CommPort = 1
    
50.         
    
51.         ' / ตั้งค่า Baud Rate, Parity, Data Bits, Stop Bits (Standard)
    
52.         .Settings = "9600,N,8,1"
    
53.         
    
54.         ' / ตั้งสถานะในการ Hand Shaking ของ DTR and RTS (การตรวจสอบความถูกต้องการรับ - ส่ง)
    
55.         '.DTREnable = True
    
56.         '.RTSEnable = True
    
57.         ' / ========================================
    
58.         ' / สั่งให้ Enabled เหตุการณ์ในการรับข้อมูลทุกๆ Character
    
59.         .RThreshold = 1
    
60.         ' / ========================================
    
61.         ' / Disable เมื่อส่ง Characters
    
62.         '.SThreshold = 0
    
63.         
    
64.         ' / เปิด Port
    
65.         .PortOpen = True
    
66.         InitializePort = True
    
67.    
    
68.     End With
    
69. 
    
70. ExitProc::
    
71.     Exit Function
    
72.    
    
73. ErrHandler:
    
74.     MsgBox Err.Number & " : " & Err.Description
    
75.     InitializePort = False
    
76.    
    
77. End Function
    
78. 
    
79. ' / --------------------------------------------------------------------------------
    
80. ' / เหตุการณ์เกิดการรับข้อมูลเข้ามาผ่านทาง Serial Port - COM ในลักษณะของ Interrupt
    
81. Private Sub MSComm1_OnComm()
    
82. ' / --------------------------------------------------------------------------------
    
83.    
    
84.     With MSComm1
    
85.         ' / ทดสอบเกิดเหตุการณ์เข้ามาของข้อมูล (Received)
    
86.         Select Case .CommEvent
    
87.             Case comEvReceive   ' หรือ มีค่าเท่ากับ 2
    
88.                
    
89.                 ' / แสดงข้อมูล เมื่อมีการรับข้อมูลเข้ามา
    
90.                 txtTagID.Text = txtTagID.Text & MSComm1.Input
    
91.    
    
92.         End Select
    
93.         
    
94.     End With
    
95. 
    
96. End Sub
    
97. 
    
98. ' / --------------------------------------------------------------------------------
    
99. ' / การนำมาใช้ใน Timer เพราะจังหวะของการอ่านมันคงที่กว่าครับ
    
100. Private Sub Timer1_Timer()
     
101. ' / --------------------------------------------------------------------------------
     
102.     ' ตัวแปรรับค่า Tag ID จาก TextBox
     
103.     Dim TagID As String
     
104.    
     
105.     ' ประกาศตัวแปรสำหรับ ListItem ที่ต้องใช้งานใน ListView
     
106.     Dim LV As ListItem
     
107.    
     
108.     ' ดัก Error กรณีการอ่านผิดพลาด จะทำให้อ่านข้อมูลเข้ามาไม่ครบ ก็ให้จบออกไปก่อน
     
109.     'If Len(txtTagID.Text) < 16 Then
     
110.     '    txtTagID.Text = ""
     
111.     '    Exit Sub
     
112.     'End If
     
113.    
     
114.     ' เริ่มต้นนำข้อมูลไปแสดงลงใน ListView
     
115.     If Len(txtTagID.Text) > 0 And Len(txtTagID.Text) = 16 Then
     
116.         
     
117.         TagID = txtTagID.Text
     
118.         
     
119.         ' / ตรวจสอบค่า Tag ID จากตารางข้อมูล
     
120.         Set RS = New Recordset
     
121.         Statement = "SELECT * FROM tblContact WHERE RFID = " & "'" & Mid$(Trim(TagID), 2, Len(TagID) - 4) & "'"
     
122.         RS.CursorLocation = adUseClient
     
123.         ' / กำหนดให้อ่านเดินหน้าอย่างเดียว
     
124.         RS.Open Statement, ConnDB, adOpenForwardOnly, adLockReadOnly, adCmdText
     
125.         ' / หากพบข้อมูล Tag ID
     
126.         If RS.RecordCount > 0 Then
     
127.             '/ ตรวจสอบว่ามีการเก็บตำแหน่งภาพหรือไม่
     
128.             '/ กรณีนี้ ไม่มีข้อมูล
     
129.             If IsNull(RS("PictureName")) Or Trim(RS("PictureName")) = "" Then
     
130.                 '/ นำภาพอะไรก็ได้ มาแสดงให้ผู้ใช้งานเห็นว่าข้อมูลนี้ไม่มีการจัดเก็บภาพไว้
     
131.                 Image1.Picture = LoadPicture(App.Path & "\Images" & "NoPicture.jpg")
     
132.                
     
133.             ' / นำตำแหน่งภาพมาทำการแสดงผล
     
134.             ' / แต่ปัญหามันจะเกิดขึ้นในวันข้างหน้า หากหาไฟล์ภาพที่ระบุไม่เจอ ทางแก้ก็คือเขียนโค้ดดัก Error
     
135.             Else
     
136.                 If Dir(App.Path & "\Images" & Trim(RS("PictureName"))) <> "" Then
     
137.                     Image1.Picture = LoadPicture(App.Path & "\Images" & RS("PictureName"))
     
138.                 Else
     
139.                     Image1.Picture = LoadPicture(App.Path & "\Images" & "NoPicture.jpg")
     
140.                 End If
     
141.             End If
     
142.             RS.Close:    Set RS = Nothing
     
143.             
     
144.             ' / เริ่มต้นนำข้อมูลไปแสดงผลลงใน ListView
     
145.             ' / ให้เกิดมีลำดับที่ สำหรับหลักแรก (Index = 0)
     
146.             Set LV = lvwData.ListItems.Add(, , lvwData.ListItems.Count + 1)
     
147.             
     
148.             ' รูปแบบที่ปรากฏใน TextBox ===> [1C006082946A[ <===
     
149.             ' แต่แท้จริงแล้ว ข้อมูลจะอยู่ในรูปแบบรหัส ASCII ดังนี้
     
150.             ' <02>1C006082946A<0D><0A><03>
     
151.             ' <02> บ่งบอกจุดเริ่มต้นของข้อมูล (STX - Start of Text)
     
152.             ' <0D> หรือ 13 (ฐาน 10) คือ กดปุ่ม Enter (Carriage Return)
     
153.             ' <0A> หรือ 10 (ฐาน 10) คือ Line Feed (ขึ้นบรรทัดใหม่)
     
154.             ' <03> บ่งบอกจุดสิ้นสุดของข้อมูล (ETX - End of Text)
     
155.             
     
156.             ' / ผมใช้วิธีการนับเริ่มจากหลักที่ 2 และนับไปตามความยาวของ TagID (16 ตัว) - 4
     
157.             LV.SubItems(1) = Mid$(TagID, 2, Len(TagID) - 4)
     
158.             
     
159.             ' / เก็บค่าวันที่ และ เวลา
     
160.             LV.SubItems(2) = Now()
     
161.             
     
162.             ' ===================== ตำแหน่งนี้ ==================
     
163.             ' ====== สามารถบันทึกลงฐานข้อมูลได้ หรือ สั่งให้อุปกรณ์ทำงาน ====
     
164.         
     
165.         '/ เมื่อไม่พบข้อมูล
     
166.         Else
     
167.             ' / เคลียร์ภาพ
     
168.             Set Image1 = Nothing
     
169.         
     
170.         End If
     
171.     End If
     
172.    
     
173.     ' เคลียร์ค่าการรับข้อมูล
     
174.     txtTagID.Text = ""
     
175. 
     
176. End Sub
     
177. 
     
178. Private Sub Form_Unload(Cancel As Integer)
     
179.     If MSComm1.PortOpen Then MSComm1.PortOpen = False
     
180.     Call CloseDataBase
     
181.     Set frmRFID = Nothing
     
182.     End
     
183. End Sub
     
184. 
     
185. Private Sub cmdClear_Click()
     
186.     lvwData.ListItems.Clear
     
187.     txtTagID.Text = ""
     
188.     txtTagID.SetFocus
     
189.     Set Image1.Picture = Nothing
     
190. End Sub
     
191. 
     
192. Private Sub cmdExit_Click()
     
193.     Unload Me
     
194. End Sub
     
195. 
     
196. Private Sub Form_Resize()
     
197.     On Error Resume Next
     
198.     If Me.WindowState = vbMinimized Then Exit Sub
     
199.     ' ความกว้าง
     
200.     If Me.Width < 8730 Then
     
201.         Me.Width = 8730
     
202.        Exit Sub
     
203.     End If
     
204.     ' ความสูง
     
205.     If Me.Height < 5865 Then
     
206.         Me.Height = 5865
     
207.         Exit Sub
     
208.     End If
     
209.     ' การคำนวณหาระยะการย่อ ขยายของฟอร์ม
     
210.     fraData.Move 0, 0, Me.ScaleWidth - cmdClear.Width - cmdExit.Width - 60, Me.ScaleHeight
     
211.     lvwData.Move 30, 870, fraData.Width - 60, fraData.Height - 930
     
212.     cmdClear.Move fraData.Width + 15, 90
     
213.     cmdExit.Move cmdClear.Left + cmdClear.Width + 30, 90
     
214.     Image1.Left = fraData.Width + 15
     
215. End Sub

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดต้นฉบับแบบเต็มได้ที่นี่ ...