[VB6] แจกโค้ดการใช้งานตารางกริด SharpGrid UnBound Data Control ในแบบ Run Time

thongkorn

มารู้จักกับคำว่า Bound Data และ UnBound Data Control
- Bound Data Control คือ การผูก (Bound) ตารางข้อมูล (RecordSet) เข้ากับพวก Component หรือ Control ต่างๆ ผ่านทาง DataSource กรณีที่นำมาใช้แสดงผลลงในตารางกริด มันจะอ่านค่าฟิลด์ต่างๆ เพื่อแสดงผลในแต่ละหลัก เรียงตามลำดับจากการ Query ที่เราเขียนไว้ และ ต้องแสดงทุกๆฟิลด์ออกมาทั้งหมด (หากไม่ต้องการแสดงผล จะต้องทำการซ่อนหลักของตัวกริดเอง) มีข้อดี คือ ทำงานได้เร็ว มักนำไปแสดงผลข้อมูลอย่างเดียว (อ่านรายละเอียดและดาวน์โหลดโค้ดได้ที่นี่)


- UnBound Data Control ก็จะไม่มีการผูก (Unbound) ตารางข้อมูลใดๆเข้ากับ Component หรือ Control การนำไปใช้ในตารางกริด ไม่จำเป็นต้องแสดงผลออกมาทุกฟิลด์ และ จะเอาตัวไหนมาแสดงในหลักใดๆก่อนหลังก็ได้ มีข้อดี คือ ยืดหยุ่นมากกว่า และ มักใช้กับการแก้ไขข้อมูลของตารางกริดในแต่ละ Cell ได้นั่นเอง กรณีของ UnBound Data จะไม่ผูกแหล่งจ่าย หรือ DataSource เข้ากับตัว SharpGrid แต่จะอาศัยการวนลูป หรือการทำซ้ำแทน  

Download SharpGrid ActiveX/COM Grid Control (เฉพาะสมาชิกเท่านั้น) ...


เพิ่มเติมจากวิธีการ BoundData วิธีการในการเข้าถึงข้อมูลในแต่ละเซลล์ เราสามารถใช้ Method CellAt(แถว, หลัก) เพื่อการเข้าถึงข้อมูลได้อย่างรวดเร็ว ...

1. ' / -----------------------------------------------------------------------------------------------
   
2. ' / อ่านค่า Primary Key จากหลัก 0 ที่ถูกซ่อนเอาไว้ เพื่อนำไปใช้งานอย่างอื่นต่อไป
   
3. Private Sub SGGridEmployee_DblClick()
   
4. ' / -----------------------------------------------------------------------------------------------
   
5.     '// การเข้าถึงข้อมูลในแต่ละเซลล์ SharpGrid.CellAt(แถวที่เลือก, หลักที่ต้องการ)
   
6.     MsgBox "EmployeePK = " & SGGridEmployee.CellAt(SGGridEmployee.Row, 1) & vbCrLf & _
   
7.         "EmployeeName = " & SGGridEmployee.CellAt(SGGridEmployee.Row, 3)
   
8. End Sub

คัดลอกไปที่คลิปบอร์ด

มาดูโค้ดส่วนของฟอร์มหลัก ...

1. ' / -----------------------------------------------------------------------------------------------
   
2. ' / Developer : Mr.Surapon Yodsanga (Thongkorn Tubtimkrob)
   
3. ' / eMail : thongkorn@hotmail.com
   
4. ' / URL: http://www.g2gnet.com (Khon Kaen - Thailand)
   
5. ' / Facebook: https://www.facebook.com/g2gnet (For Thailand only)
   
6. ' / Facebook: https://www.facebook.com/commonindy (World Wide)
   
7. ' /
   
8. ' / Purpose : Sample to use SharpGrid ActiveX for UnBound Data Control.
   
9. ' / Microsoft Visual Basic 6.0 Service Pack 6 + MS Access 2003
   
10. ' / -----------------------------------------------------------------------------------------------
    
11. Option Explicit
    
12. 
    
13. ' / -----------------------------------------------------------------------------------------------
    
14. Private Sub Form_Load()
    
15. ' / -----------------------------------------------------------------------------------------------
    
16. '/ Trap Error
    
17. On Error GoTo ErrorHandler
    
18.     '// การตั้งฟอร์มไว้กึ่งกลางจอภาพในแบบ Run Time
    
19.     Me.Move (Screen.Width - Me.Width) \ 2, (Screen.Height - Me.Height) \ 2
    
20.     '// ทำการติดต่อกับฐานข้อมูลก่อน (modDataBase.bas)
    
21.     Call OpenDataBase
    
22.     '// เคลียร์ค่า TextBox
    
23.     txtSearch.Text = ""
    
24.    
    
25.     '// ตั้งค่าการแสดงผล SharpGrid
    
26.     Call InitSGGrid
    
27.     '// ส่งค่า False เพื่อแจ้งโปรแกรมย่อยว่าแสดงผลข้อมูลออกมาทั้งหมด
    
28.     Call SGGridEmployeeBound(False)
    
29.    
    
30. ExitProc:
    
31.     Exit Sub
    
32.    
    
33. ErrorHandler:
    
34.     MsgBox "Error : " & Err.Number & vbCrLf & Err.Description, vbOKOnly + vbExclamation, "รายงานความผิดพลาด"
    
35.     Resume ExitProc
    
36.     '
    
37. End Sub
    
38. 
    
39. ' / -----------------------------------------------------------------------------------------------
    
40. Sub InitSGGrid()
    
41. ' / -----------------------------------------------------------------------------------------------
    
42.     ' Initialize grid properties
    
43.     With SGGridEmployee
    
44.         '/ ++++++++++++++++++++++++++++++++++++++++
    
45.         '/ กำหนดการแสดงผล GroupHeader หรือไม่
    
46.         '/ False คือ ไม่ต้องแสดงผล
    
47.         .GroupByBoxVisible = False
    
48.         '/ True จะแสดงผล GroupHeader ซึ่งจะทำให้ผู้ใช้งานลาก Column ไปจัดกลุ่มได้
    
49.         '/ ++++++++++++++++++++++++++++++++++++++++
    
50.         
    
51.         .FitLastColumn = True
    
52.         .Appearance = sg3D
    
53.         .SpecialMode = sgModeListBox
    
54.         .CellsBorderVisible = True
    
55.         .AutoResize = sgAutoResizeColumns
    
56.         .GroupIndentation = 225
    
57.         
    
58.         .DefaultRowHeight = 390
    
59.         .RowHeightMin = 390
    
60.         .HeadingColCount = 1
    
61.         
    
62.         .HeadingGridLinesColor = vbBlack
    
63.         .HeadingGridLines = sgGridLineFlat
    
64.         
    
65.         '/ สลับสีแถว
    
66.         .EvenOddStyle = sgEvenOddRows
    
67.         .ColorOdd = &HEFEFE0
    
68.         
    
69.         .CellTips = sgCellTipsFloat
    
70.         .CellTipsDelay = 400
    
71.         .ScrollBarTips = sgScrollTipsVertical
    
72.         
    
73.         .CacheAllRecords = True
    
74.         .ColumnClickSort = True
    
75.         
    
76.         '/ การแสดงผลปกติทั่วไป
    
77.         With .Styles("Normal")
    
78.             .BkgStyle = sgCellBkgSolid
    
79.             .Font.Name = "Tahoma"
    
80.             .Font.Size = 8
    
81.             .Padding = 18
    
82.         End With
    
83.       
    
84.       '/ ส่วนหัวของ Header กรณีการแสดงผลทั่วไป
    
85.         With .Styles("Heading")
    
86.             .BackColor = RGB(0, 153, 255)
    
87.             .ForeColor = vbWhite
    
88.             .Font.Name = "Tahoma"
    
89.             .Font.Size = 9
    
90.             .Font.Bold = True
    
91.             .Padding = 75
    
92.         End With
    
93.         
    
94.         '/ ส่วนหัวของ GroupHeader กรณีมีการจัดกลุ่ม
    
95.         With .Styles("GroupHeader")
    
96.             .Font.Size = 9
    
97.             .Font.Bold = True
    
98.             .BackColor = RGB(241, 239, 226)
    
99.             .BkgStyle = sgCellBkgSolid
    
100.             .Padding = 30
     
101.             .BorderColor = RGB(241, 207, 0)
     
102.             .Borders = sgCellBorderBottom
     
103.             .BorderSize = 1
     
104.         End With
     
105.       
     
106.         '/ ส่วนของ GroupFooter กรณีมีการจัดกลุ่ม
     
107.         With .Styles("GroupFooter")
     
108.             .Font.Size = 9
     
109.             .Font.Name = "Tahoma"
     
110.             .ForeColor = vbBlue
     
111.             .BackColor = RGB(255, 255, 224)
     
112.             .BkgStyle = sgCellBkgSolid
     
113.             .Padding = 75
     
114.             .BorderColor = RGB(255, 207, 0)
     
115.             .Borders = sgCellBorderBottom
     
116.             .BorderSize = 50
     
117.             .TextAlignment = sgAlignLeftCenter
     
118.         End With
     
119.       
     
120.         With .Styles("Tip")
     
121.             .Font.Size = 10
     
122.             .Padding = 40
     
123.         End With
     
124.       
     
125.        '/ กำหนดสีให้แถบแสงที่เราเลือกแถว
     
126.         With .Styles("Selection")
     
127.             .BackColor = RGB(0, 170, 0)
     
128.             .ForeColor = vbWhite
     
129.             .BkgStyle = sgCellBkgSolid
     
130.         End With
     
131.       
     
132.       '/ กำหนดสีให้แถบแสง กรณีที่เราไม่ได้เลือกแถวนั้น
     
133.         With .Styles("InactiveSelection")
     
134.             .BackColor = RGB(0, 170, 0)
     
135.             .ForeColor = vbWhite
     
136.             .BkgStyle = sgCellBkgSolid
     
137.         End With
     
138.     End With
     
139. 
     
140. End Sub
     
141. 
     
142. ' / -----------------------------------------------------------------------------------------------
     
143. ' / อ่านค่า Primary Key จากหลัก 0 ที่ถูกซ่อนเอาไว้ เพื่อนำไปใช้งานอย่างอื่นต่อไป
     
144. Private Sub SGGridEmployee_DblClick()
     
145. ' / -----------------------------------------------------------------------------------------------
     
146.     '// การเข้าถึงข้อมูลในแต่ละเซลล์ SharpGrid.CellAt(แถวที่เลือก, หลักที่ต้องการ)
     
147.     MsgBox "EmployeePK = " & SGGridEmployee.CellAt(SGGridEmployee.Row, 1) & vbCrLf & _
     
148.         "EmployeeName = " & SGGridEmployee.CellAt(SGGridEmployee.Row, 3)
     
149. End Sub
     
150. 
     
151. ' / -----------------------------------------------------------------------------------------------
     
152. ' / ตัวแปร blnSearch เป็นออพชั่น หากไม่มีการส่งค่ามา ให้ถือว่ามันมีค่าเป็น FALSE
     
153. ' / หาก blnSearch = False เป็นการแสดงผลข้อมูลทั้งหมด โดยไม่ต้องทำการค้นหา
     
154. ' / หาก blnSearch = True เป็นการค้นหาข้อมูล ตามเงื่อนไขที่อยู่ใน TextBox
     
155. Sub SGGridEmployeeBound(Optional blnSearch As Boolean = False)
     
156. ' / -----------------------------------------------------------------------------------------------
     
157.     With SGGridEmployee
     
158.         '.Columns.RemoveAll False
     
159.         '/ +++++++++++++++++++++++++++++++++++++++++++++++
     
160.         '/ ต้องกำหนดจำนวนหลักให้กับ SharpGrid กรณีที่ใช้งานแบบ UnBound
     
161.         '/ หากไม่ต้องการกำหนดจำนวน เราสามารถใช้ Method Add Column แทน
     
162.         .DataColCount = 7
     
163.         '/ +++++++++++++++++++++++++++++++++++++++++++++++
     
164.         .DataRowCount = 0
     
165.         ' / หลัก 0 นี่คือหลักที่แสดงหมายเลขแถวครับ
     
166.         .Rows.At(0).Height = 420
     
167.         .ColumnClickSort = True
     
168.         .Columns(0).Width = 400
     
169.         .Columns(0).AllowSizing = False
     
170.         .Columns(0).Hidden = True
     
171.         .RowNumbering = False
     
172.     End With
     
173.    
     
174.     '/ สร้าง Instance ขึ้นมาใหม่ พร้อมตัดการเชื่อมต่อเดิมทิ้ง (หากลืม)
     
175.     Set RS = New ADODB.Recordset
     
176.    '/ blnSearch = True คือการค้นหาข้อมูล
     
177.     If blnSearch Then
     
178.         '// Bound Data จะแสดงผลโดยจัดเรียงข้อมูลตามฟิลด์ ที่อยู่ใน Query
     
179.         '// หากฟิลด์ใดที่เราไม่ต้องการให้แสดงผล ต้องไปตั้งค่าหลักนั้นใน SharpGrid ให้ Hidden = True
     
180.         Statement = _
     
181.             " SELECT tblEmployee.EmployeePK, tblEmployee.EmployeeID, tblEmployee.EmployeeName, tblPosition.PositionName, " & _
     
182.             " tblDepartment.DepartmentName, tblEmployee.DateStart, tblEmployee.Salary " & _
     
183.             " FROM (tblEmployee INNER JOIN tblDepartment ON tblEmployee.DepartmentFK = tblDepartment.DepartmentPK) INNER JOIN " & _
     
184.             " tblPosition ON tblEmployee.PositionFK = tblPosition.PositionPK " & _
     
185.             " WHERE " & _
     
186.             " ([EmployeeID] " & " Like '%" & Trim(txtSearch.Text) & "%'" & " OR " & _
     
187.             " [EmployeeName] " & " Like '%" & Trim(txtSearch.Text) & "%'" & " OR " & _
     
188.             " [PositionName] " & " Like '%" & Trim(txtSearch.Text) & "%'" & " OR " & _
     
189.             " [DepartmentName] " & " Like '%" & Trim(txtSearch.Text) & "%'" & ")" & _
     
190.             " ORDER BY EmployeeID, EmployeeName "
     
191.    
     
192.     '// blnSearch = False คือ แสดงผลทั้งหมด
     
193.     Else
     
194.         Statement = _
     
195.             " SELECT tblEmployee.EmployeePK, tblEmployee.EmployeeID, tblEmployee.EmployeeName, tblPosition.PositionName, " & _
     
196.             " tblDepartment.DepartmentName, tblEmployee.DateStart, tblEmployee.Salary " & _
     
197.             " FROM (tblEmployee INNER JOIN tblDepartment ON tblEmployee.DepartmentFK = tblDepartment.DepartmentPK) INNER JOIN " & _
     
198.             " tblPosition ON tblEmployee.PositionFK = tblPosition.PositionPK " & _
     
199.             " ORDER BY DepartmentName, EmployeeID "
     
200.     End If
     
201.    
     
202.     ' ============ IMPORTANT ==========
     
203.     ' / ระบุให้ทำงานในโหมด UNBOUND DATA
     
204.     SGGridEmployee.DataMode = sgUnbound
     
205.     ' ==================================
     
206.     RS.CursorLocation = adUseClient
     
207.     '// adOpenForwardOnly และ adLockReadOnly เป็นการอ่านข้อมูลเดินหน้าอย่างเดียว จะมีความเร็วในการนำข้อมูลมาแสดงผล
     
208.     RS.Open Statement, ConnDB, adOpenForwardOnly, adLockReadOnly, adCmdText
     
209.    
     
210.     '/ =============== ผูกเข้ากับตาราง RecordSet ================
     
211.     '/ BOUND DATA
     
212.     '/ เหมือนการกำหนด DataSource ใน VB.NET
     
213.     'Set SGGridEmployee.DataSource = RS
     
214.     '/ ====================================================
     
215.     '/ แสดงจำนวนรายการ
     
216.     SGGridEmployee.DataRowCount = RS.RecordCount
     
217.     If RS.RecordCount >= 0 Then
     
218.         lblSearch.Caption = "[จำนวน : " & RS.RecordCount & " รายการ.]"
     
219.     Else
     
220.         lblSearch.Caption = "[จำนวน : 0" & " รายการ.]"
     
221.     End If
     
222.    
     
223.     '// จัดรูปแบบหลักใหม่
     
224.     Call SetupSGGrid
     
225.    
     
226.     '// ++++++++++++++++++ UNBOUND DATA +++++++++++++++++++
     
227.     '// การ UnBound ก็คือการทำ Loop หรือการทำซ้ำ (Repetitive) นั่นเอง
     
228.     '// โดยที่เราเลือกมาเฉพาะบางฟิลด์ก็ได้ ไม่จำเป็นต้องนำมาจากการ Query ทั้งหมด
     
229.     Dim Rec As Long
     
230.     '// ที่เลือก FOR ก็เพราะว่ามันมีค่าเริ่มต้น - สิ้นสุด และมีการนับเพิ่ม (หรือลด) แบบคงที่
     
231.     '// ลองแก้ไขโดยใช้ Do While หรือ Do Until แทนครับผม
     
232.     For Rec = 1 To SGGridEmployee.DataRowCount
     
233.         With SGGridEmployee
     
234.             .CellAt(Rec, 1) = RS("EmployeePK")
     
235.             ' / การใส่ "" ไว้ด้านหน้าฟิลด์ข้อมูลแบบ String เพื่อป้องกัน Error หากมีค่าเป็น Null
     
236.             .CellAt(Rec, 2).Value = "" & RS("EmployeeID")
     
237.             .CellAt(Rec, 3).Value = "" & RS("EmployeeName")
     
238.             .CellAt(Rec, 4) = "" & RS("PositionName")
     
239.             .CellAt(Rec, 5) = "" & RS("DepartmentName")
     
240.             .CellAt(Rec, 6) = "" & Format(RS("DateStart"), "dd/MM/yyyy")
     
241.             .CellAt(Rec, 7) = Format(RS("Salary"), "#,##0.00")
     
242.         End With
     
243.         RS.MoveNext
     
244.     Next
     
245. 
     
246.     ' / Always must be disconnect RecordSet
     
247.     RS.Close:   Set RS = Nothing
     
248. End Sub
     
249. 
     
250. ' / -----------------------------------------------------------------------------------------------
     
251. ' / การตั้งค่าหลักต่างๆ ต้องให้ตรงกันกับฟิลด์ข้อมูลในการ Query จากโปรแกรมย่อย SGGridEmployeeBound
     
252. Private Sub SetupSGGrid()
     
253. ' / -----------------------------------------------------------------------------------------------
     
254.     '/ การกำหนดโหมด Bound Data ทำให้เกิดการนับจำนวนหลักเอาไว้ให้เรียบร้อย
     
255.     ' ================ Setup SGGrid ====================
     
256.     With SGGridEmployee
     
257.         '// Start Columns 1 โดยใช้ค่า Index ที่เรียงมาจาก Query
     
258.         With .Columns(1)
     
259.             '/ แสดงผลหัวข้อหลัก
     
260.             .Caption = "EmployeePK"
     
261.             '/ ความกว้างเป็น 0
     
262.             .Width = 0
     
263.             '/ ไม่ยอมให้ปรับขนาดความกว้างของหลัก
     
264.             .AllowSizing = False
     
265.             '/ เอาไปซ่อนจากสายตาผู้ใช้ไปเลย กรณีที่เราไม่ต้องการให้หลักนี้มีการแสดงผลให้ผู้ใช้งานเห็น
     
266.             .Hidden = True
     
267.         End With
     
268.         ' 2
     
269.         With .Columns(2)
     
270.             .Caption = "รหัสพนักงาน"
     
271.             '/ ตั้งค่าการแสดงตำแหน่งของข้อมูล
     
272.             .Style.TextAlignment = sgAlignLeftCenter
     
273.             .HeadingStyle.TextAlignment = sgAlignLeftCenter
     
274.             .AllowSizing = True
     
275.         End With
     
276.         ' 3
     
277.         With .Columns(3)
     
278.             .Caption = "ชื่อ - นามสกุล"
     
279.             .Style.TextAlignment = sgAlignLeftCenter
     
280.             .HeadingStyle.TextAlignment = sgAlignLeftCenter
     
281.             .AllowSizing = True
     
282.         End With
     
283.         ' 4
     
284.         With .Columns(4)
     
285.             .Caption = "ตำแหน่ง"
     
286.             .Style.TextAlignment = sgAlignLeftCenter
     
287.             .HeadingStyle.TextAlignment = sgAlignLeftCenter
     
288.             .AllowSizing = True
     
289.         End With
     
290.         ' 5
     
291.         With .Columns(5)
     
292.             .Caption = "แผนก"
     
293.             .Style.TextAlignment = sgAlignLeftCenter
     
294.             .HeadingStyle.TextAlignment = sgAlignLeftCenter
     
295.             .AllowSizing = True
     
296.         End With
     
297.         ' 6
     
298.         With .Columns(6)
     
299.             .Caption = "วันที่เริ่มทำงาน"
     
300.             .Style.TextAlignment = sgAlignRightCenter
     
301.             .HeadingStyle.TextAlignment = sgAlignRightCenter
     
302.             .Style.Format = "dd/mm/yyyy"
     
303.             .AllowSizing = True
     
304.         End With
     
305.         ' 7
     
306.         With .Columns(7)
     
307.             .Caption = "เงินเดือน"
     
308.             .Style.TextAlignment = sgAlignRightCenter
     
309.             .HeadingStyle.TextAlignment = sgAlignRightCenter
     
310.             .DataType = sgtCurrency
     
311.             .Style.Format = "#,##0.00"
     
312.             .AllowSizing = False
     
313.         End With
     
314.         '
     
315.     End With
     
316. End Sub
     
317. 
     
318. ' / -----------------------------------------------------------------------------------------------
     
319. ' / กดปุ่ม Refresh เพื่อทำการแสดงผลข้อมูลทั้งหมด
     
320. Private Sub cmdRefresh_Click()
     
321. ' / -----------------------------------------------------------------------------------------------
     
322.     Call SGGridEmployeeBound(False)
     
323.     With SGGridEmployee
     
324.         .LeftCol = 0
     
325.         .SetFocus
     
326.         Sendkeys "{RIGHT}"
     
327.     End With
     
328.     txtSearch.Text = ""
     
329. End Sub
     
330. 
     
331. ' / -----------------------------------------------------------------------------------------------
     
332. ' / เมื่อคลิ๊กที่ปุ่มค้นหา
     
333. Private Sub cmdSearch_Click()
     
334. ' / -----------------------------------------------------------------------------------------------
     
335.    
     
336.     ' / ตัดคำสงวน (Reserved Word) ที่มีปัญหากับฐานข้อมูลออกไป
     
337.     txtSearch.Text = Replace(txtSearch.Text, "'", "")
     
338.     txtSearch.Text = Replace(txtSearch.Text, "%", "")
     
339.     txtSearch.Text = Replace(txtSearch.Text, "*", "")
     
340.     If Trim(txtSearch.Text) = "" Or Len(txtSearch.Text) = 0 Then Exit Sub
     
341.    
     
342.     '/ ทำการค้นหาข้อมูล
     
343.     Call SGGridEmployeeBound(True)
     
344.    
     
345. End Sub
     
346. 
     
347. Private Sub txtSearch_KeyDown(KeyCode As Integer, Shift As Integer)
     
348.     If KeyCode = vbKeyDown Then Sendkeys "{TAB}"
     
349.     If KeyCode = vbKeyUp Then Sendkeys "+{TAB}"
     
350. End Sub
     
351. 
     
352. Private Sub txtSearch_KeyPress(KeyAscii As Integer)
     
353.     '// เกิดการกด Enter (ASCII Code มีค่าเท่ากับ 13 ฐาน 10)
     
354.     If KeyAscii = 13 Then
     
355.         Call cmdSearch_Click
     
356.         '// ปิดเสียงด้วยการกำหนดให้ KeyAscii = 0 หรือไม่มีการกดคีย์ใดๆ
     
357.         KeyAscii = 0
     
358.     End If
     
359. End Sub
     
360. 
     
361. Private Sub cmdRefresh_KeyDown(KeyCode As Integer, Shift As Integer)
     
362.     If KeyCode = vbKeyDown Or KeyCode = vbKeyRight Then Sendkeys "{TAB}"
     
363.     If KeyCode = vbKeyUp Or KeyCode = vbKeyLeft Then Sendkeys "+{TAB}"
     
364. End Sub
     
365. 
     
366. Private Sub Form_Resize()
     
367.     If Me.ScaleWidth < 120 Or Me.ScaleHeight < 120 Then Exit Sub
     
368.     fraData.Height = Me.ScaleHeight - 60
     
369.     fraData.Move 15, 0, Me.ScaleWidth - 15
     
370.     SGGridEmployee.Move 15, 615, fraData.Width - (SGGridEmployee.Left) - 15, fraData.Height - 690
     
371. End Sub
     
372. 
     
373. Private Sub Form_Unload(Cancel As Integer)
     
374. On Error Resume Next
     
375.     If Dir$(App.Path & "\*.tmp") <> "" Then Kill App.Path & "\*.tmp"
     
376.     '/ ปิดการเชื่อมต่อกับฐานข้อมูล
     
377.     Call CloseDataBase
     
378.     End
     
379. End Sub

คัดลอกไปที่คลิปบอร์ด

มาดูโค้ดในส่วนของโมดูลหากิน (modDataBase.bas)

1. ' / -----------------------------------------------------------------------------------------------
   
2. ' / Developer : Mr.Surapon Yodsanga (Thongkorn Tubtimkrob)
   
3. ' / eMail : thongkorn@hotmail.com
   
4. ' / URL: http://www.g2gnet.com (Khon Kaen - Thailand)
   
5. ' / Facebook: https://www.facebook.com/g2gnet (For Thailand only)
   
6. ' / Facebook: https://www.facebook.com/commonindy (World Wide)
   
7. ' /
   
8. ' / Purpose : Function to connect the MS Access DataBase.
   
9. ' / Microsoft Visual Basic 6.0 Service Pack 6 + MS Access 2003
   
10. ' / -----------------------------------------------------------------------------------------------
    
11. Option Explicit
    
12. 
    
13. '// ก่อนใช้งานต้องเลือก MDAC 2.8 มาจาก Project --> Refernces ก่อน
    
14. Global ConnDB As New ADODB.Connection
    
15. Global RS As New ADODB.Recordset    ' / RecordSet หลัก
    
16. Global DS As New ADODB.Recordset    ' / RecordSet สำรอง
    
17. Global RstData As New ADODB.Recordset   ' / ใช้ในการพิมพ์รายงาน
    
18. Global Statement As String
    
19. Global SQLStmt As String
    
20. 
    
21. ' / -----------------------------------------------------------------------------------------------
    
22. Public Sub OpenDataBase()
    
23. On Error GoTo Err_Handler
    
24.     Dim DB_File As String
    
25.     DB_File = App.Path
    
26.     If Right$(DB_File, 1) <> "" Then DB_File = DB_File & ""
    
27.     DB_File = DB_File & "DataBase.MDB"
    
28.     ' Open a connection.
    
29.     Set ConnDB = New ADODB.Connection
    
30.     ConnDB.ConnectionString = _
    
31.         "Provider=Microsoft.Jet.OLEDB.4.0;" & _
    
32.         "Data Source=" & DB_File & ";" & _
    
33.         "Persist Security Info=False"
    
34.         '" Jet OLEDB:Database Password=" & "password" & ";" '& _
    
35.         '" Engine Type=5;"
    
36.     ConnDB.Open
    
37.     Exit Sub
    
38. Err_Handler:
    
39.     MsgBox "Open Database Error : " & vbCrLf & Err.Number & " " & Err.Description
    
40.     End
    
41. End Sub
    
42. 
    
43. Public Sub CloseDataBase()
    
44.     ' ตรวจสอบว่ามีการเชื่อมโยง - Connect ข้อมูลหรือไม่
    
45.     If ConnDB.State = adStateOpen Then
    
46.         ConnDB.Close
    
47.         Set ConnDB = Nothing
    
48.     End If
    
49. End Sub
    
50. 
    
51. ' / -----------------------------------------------------------------------------------------------
    
52. ' / ฟังค์ชั่นแก้ไขในการ SendKeys ซึ่งใน Windows 8+ 64 บิท จะมีปัญหา
    
53. Public Sub Sendkeys(Text As String, Optional Wait As Boolean = False)
    
54.     Dim WshShell As Object
    
55.     Set WshShell = CreateObject("Wscript.shell")
    
56.     WshShell.Sendkeys Text, Wait
    
57.     Set WshShell = Nothing
    
58. End Sub

คัดลอกไปที่คลิปบอร์ด

Conclusion: ก็คงจะเห็นได้ชัดเจนว่า ทั้งแบบ Bound หรือ UnBound ต่างก็แสดงผลได้เหมือนกัน แต่วิธีการ UnBound Data เหมาะสมกับการนำข้อมูลมาเพื่อทำการแก้ไขในตัวตารางกริด หากเปรียบเทียบกับ VB.NET ก็คงเหมือนกับการใช้งาน Data Reader นั่นเอง


ดาวน์โหลดโค้ดต้นฉบับ VB6 + SharpGrid ได้ที่นี่