[VB6] แจกโค้ดการพิมพ์ใบแจ้งหนี้ออกกระดาษครึ่ง A4 ร่วมกับ FarPoint Spread เพื่อทำการแก้ไขข้อมูลได้

thongkorn

จากโค้ดตัวอย่างครั้งก่อน แจกโค้ดการพิมพ์ใบแจ้งหนี้ห้องพัก/อพาร์ทเมนท์ ออกกระดาษครึ่ง A4 เป็นการนำข้อมูลจาก Excel แบบแถวเดียวมาพิมพ์ แต่อาศัยการเลื่อนตำแหน่งหลัก ซึ่งปกติคนทั่วๆไปมักไม่ค่อยได้ใช้งานกันสักเท่าไหร่ (แต่แอดมินจำเป็นและบ่อยครั้งมาก 5555+) ... คราวนี้มาดูการป้อนข้อมูลในตารางคล้ายๆกับ Excel โดยกระทำผ่านทาง FarPoint Spread เพื่ออำนวยความสะดวกให้กับผู้ใช้ (End Users) ได้ดียิ่งขึ้น ซึ่งเราจะต้องมีการล็อค หรือเช็คค่าต่างๆในแต่ละเซลล์ให้ถูกต้องเสียก่อน จึงจะส่งออกไปพิมพ์รายงานแบบ Hard Copy ด้วย ActiveReports 2.0 ... บทความและโค้ดชุดนี้ จะเน้นไปที่การควบคุม FarPoint Spread เพราะส่วนการออกรายงาน และการใช้ Initial File (INI) ต่างก็เหมือนเดิมครับ แอดมินไม่พูดมาก เจ็บคอ 5555+ ...


หากท่านบังเอิญผ่านมาเจอเว็บไซต์แห่งนี้ ต้องดูรายละเอียดตามลิ้งค์ด้านล่างนี้ก่อนด้วยครับ
[VB6] แจกฟรีโค้ดการพิมพ์ใบแจ้งค่าใช้จ่าย แบบกระดาษครึ่ง A4 ด้วย FarPoint Spread และ ActiveReports 2.0
[VB6] การป้อนข้อมูลรายละเอียดการขายสินค้าเข้าสู่ตาราง FarPoint Spread


ดาวน์โหลด FarPoint Spread COM 8 (Update 8.0.21) (สำหรับสมาชิกเท่านั้น)


มาดูโค้ดในส่วนของฟอร์มหลัก ...

1. ' / --------------------------------------------------------------------------------
   
2. ' / Developer : Mr.Surapon Yodsanga (Thongkorn Tubtimkrob)
   
3. ' / eMail : thongkorn@hotmail.com
   
4. ' / URL: http://www.g2gnet.com (Khon Kaen - Thailand)
   
5. ' / Facebook: https://www.facebook.com/g2gnet (For Thailand)
   
6. ' / Facebook: https://www.facebook.com/commonindy (Worldwide)
   
7. ' / Purpose: Print bill on paper size A5.
   
8. ' / Microsoft Visual Basic 6.0 (SP1) + FarPoint Spread 8.0
   
9. ' /
   
10. ' / This is open source code under @CopyLeft by Thongkorn Tubtimkrob.
    
11. ' / You can modify and/or distribute without to inform the developer.
    
12. ' / --------------------------------------------------------------------------------
    
13. Option Explicit
    
14. Dim strCell1 As String
    
15. Dim strCell2 As String
    
16. 
    
17. Private Sub cmdPrint_Click()
    
18.     Dim rptPrint As Object
    
19.     '// ActiveReports Setup
    
20.     Set rptPrint = New arSlipA5
    
21.     Set Me.ARViewerSlip.object = rptPrint
    
22.     '// Zoom 90%
    
23.     ARViewerSlip.Zoom = 90
    
24. End Sub
    
25. 
    
26. Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
    
27.     Select Case KeyCode
    
28.         Case vbKeyF7:   Call cmdPrint_Click
    
29.         Case vbKeyF10:  Unload Me
    
30.     End Select
    
31. End Sub
    
32. 
    
33. Private Sub Form_Load()
    
34.     Me.Move (Screen.Width - Width) \ 2, (Screen.Height - Height) \ 2
    
35.     txtFirstName.Text = "นางสาวฮานามิ"
    
36.     txtLastName.Text = "อิชิตันกรีนที"
    
37.     txtMonth.Text = "สิงหาคม 2561"
    
38.     txtRoomNo.Text = "A111"
    
39.     ' ตั้งค่าเริ่มต้นให้กับ Spread
    
40.     Call SetupSpread
    
41.     Call DemoData
    
42.     '// โฟกัสไปยังเซลล์ที่ต้องการ
    
43.     fp.SetActiveCell 4, 1
    
44. End Sub
    
45. 
    
46. ' ==========================================================
    
47. ' โปรแกรมย่อยที่กำหนดค่าคุณสมบัติ (Properties) ต่างๆ ให้กับ Spread
    
48. Sub SetupSpread()
    
49. ' ==========================================================
    
50.     ' แสดงแถบแสงหรือไม่แสดง
    
51.     fp.OperationMode = OperationModeNormal
    
52.     'fp.OperationMode = OperationModeSingle    ' แถบ Selection
    
53.     'fp.OperationMode = OperationModeRead     ' ไม่มีแถบ
    
54.     'fp.OperationMode = OperationModeRow
    
55.    
    
56.     ' สามารถจัดเรียง หรือ Sort Order บนหัวคอลัมภ์ได้
    
57.     fp.UserColAction = UserColActionSort
    
58.    
    
59.     ' ปรับหน่วยวัด
    
60.     'fp.UnitType = UnitTypeNormal
    
61.     'fp.UnitType = UnitTypeTwips
    
62.     'fp.UnitType = UnitTypeVGABase ' ค่าตั้งต้น (Default) วัดหน่วย Pixel แบบใน .NET ใช้
    
63.     ' การปรับความสูงของแถวทุกๆแถว (ค่า -1 หมายถึงทุกแถวครับ)
    
64.     fp.RowHeight(-1) = 20 '390
    
65.     'fp.Appearance = AppearanceFlat ' = Appearance3D
    
66.     fp.AppearanceStyle = AppearanceStyleEnhanced
    
67.    
    
68.     ' เวลากด F2 เพื่อแก้ไขข้อมูลในแต่ละเซลล ์ให้เลือกข้อมูลทั้งหมด หรือสามารถเริ่มคีย์ค่าใหม่ได้ทันที
    
69.     fp.EditModeReplace = True
    
70.     'fp.GridSolid = True
    
71.    
    
72.     ' กำหนดให้หลักสุงสุดจำนวน 5 หลัก
    
73.     fp.MaxCols = 5
    
74.     fp.MaxRows = 9
    
75.     ' กรณีของการ UnBound Control ต้องมาปรับรูปแบบก่อนครับ
    
76.     With fp
    
77.         ' ปรับความกว้างของแต่ละหลักโดยอัตโนมัติ ... แล้วค่อยปรับทีละหลักอีกก็ได้
    
78.         '.DAutoSizeCols = DAutoSizeColsBest
    
79.         ' หลักแรก คือ หลักที่ 0 ... จะเป็นการแสดงหมายเลขแถว เพื่ออ้างอิงในลักษณะ Excel เช่น
    
80.         ' A10 ก็คือหลัก A แถวที่ 10 ... ในกรณีที่เรามองแบบ Excel
    
81.         '.ColWidth(1) = 0
    
82.         .SetText 0, 0, "รายการชำระเงิน"
    
83.         .SetText 1, 0, "PK" '/ Reserve
    
84.         .SetText 2, 0, "หน่วยเริ่มต้น"
    
85.         .SetText 3, 0, "หน่วยสุดท้าย"
    
86.         .SetText 4, 0, "ราคาต่อหน่วย"
    
87.         .SetText 5, 0, "รวมจำนวนเงิน"
    
88.         ' Set Width
    
89.         .ColWidth(0) = 22
    
90.         .ColWidth(1) = 0
    
91.         .ColWidth(2) = 17
    
92.         .ColWidth(3) = 17
    
93.         .ColWidth(4) = 17
    
94.         .ColWidth(5) = 17
    
95.         ' กำหนดคุณสมบัติต่างๆของแต่ละหลักแบบ Run Time
    
96.         .Col = 0
    
97.         .TypeVAlign = TypeVAlignCenter
    
98.         .TypeHAlign = TypeHAlignLeft
    
99.         '//
    
100.         .Col = 1
     
101.         .Lock = True
     
102.         .ColWidth(1) = 0
     
103.         .UserResizeCol = UserResizeOff
     
104.         .UserResizeRow = UserResizeOff
     
105.         '
     
106.         .Col = 2
     
107.         .TypeTextWordWrap = True
     
108.         .TypeVAlign = TypeVAlignCenter
     
109.         .TypeHAlign = TypeHAlignRight
     
110.         ' กำหนดการป้อนค่าตัวเลขจำนวนเงินเท่านั้น
     
111.         .CellType = CellTypeNumber
     
112.         ' ตามหลังจุศนิยม
     
113.         .TypeNumberDecPlaces = 2
     
114.         .TypeNumberMin = 0
     
115.         ' ไม่แสดงสัญลักษณ์ตัวเงิน
     
116.         .TypeCurrencyShowSymbol = False
     
117.         .Lock = False
     
118.         
     
119.         .Col = 3
     
120.         .TypeHAlign = TypeHAlignRight
     
121.         .TypeVAlign = TypeVAlignCenter
     
122.         .CellType = CellTypeNumber
     
123.         .TypeNumberDecPlaces = 2
     
124.         .TypeNumberMin = 0
     
125.         .TypeCurrencyShowSymbol = False
     
126.         .Lock = False
     
127.         
     
128.         ' หน่วยละ
     
129.         .Col = 4
     
130.         .TypeHAlign = TypeHAlignRight
     
131.         .TypeVAlign = TypeVAlignCenter
     
132.         .CellType = CellTypeNumber
     
133.         .TypeNumberDecPlaces = 2
     
134.         .TypeCurrencyShowSymbol = False
     
135.         .TypeNumberShowSep = True
     
136.         .Lock = False
     
137.         ' รวมจำนวนเงิน
     
138.         .Col = 5
     
139.         .TypeHAlign = TypeHAlignRight
     
140.         .TypeVAlign = TypeVAlignCenter
     
141.         .CellType = CellTypeNumber
     
142.         .TypeNumberDecPlaces = 2
     
143.         .TypeNumberShowSep = True
     
144.         .TypeCurrencyShowSymbol = False
     
145.         .Lock = True
     
146.     End With
     
147.     ' Span Cell
     
148.     fp.AddCellSpan 2, 9, 5, 9
     
149.     fp.SetCellBorder 0, 1, -1, -1, 15, &H808080, CellBorderStyleSolid
     
150.    
     
151. End Sub
     
152. 
     
153. ' /--------------------------------------------------------------------------------------------------------
     
154. ' / ข้อมูลทดสอบ
     
155. Sub DemoData()
     
156. ' /--------------------------------------------------------------------------------------------------------
     
157.     ' ใส่ข้อมูลทดสอบ
     
158.     With fp
     
159.             .Row = 1
     
160.             .Col = 0: .Text = "ค่าห้องพัก"
     
161.             .Col = 1: .Text = 1
     
162.             .Col = 2: .Text = "0.00":   .Lock = True:   .BackColor = &HE0E0E0
     
163.             .Col = 3: .Text = "0.00":   .Lock = True:   .BackColor = &HE0E0E0
     
164.             .Col = 4: .Text = "2,800"
     
165.             .Col = 5: .Formula = "D1": .BackColor = &HC0FFFF
     
166.             .Row = 2
     
167.             .Col = 0: .Text = "ค่าน้ำประปา"
     
168.             .Col = 1: .Text = 2
     
169.             .Col = 2: .Text = "286.00"
     
170.             .Col = 3: .Text = "300.00"
     
171.             .Col = 4: .Text = "20.00"
     
172.             .Col = 5: .Formula = "(C2-B2) * D2": .BackColor = &HFFFFF0
     
173.             .Row = 3
     
174.             .Col = 0: .Text = "ค่าไฟฟ้า"
     
175.             .Col = 1: .Text = 3
     
176.             .Col = 2: .Text = "312.00"
     
177.             .Col = 3: .Text = "333.00"
     
178.             .Col = 4: .Text = "8.00"
     
179.             .Col = 5: .Formula = "(C3-B3) * D3": .BackColor = &HC0FFFF
     
180.             .Row = 4
     
181.             .Col = 0: .Text = "ค่าอินเทอร์เน็ต"
     
182.             .Col = 1: .Text = 4
     
183.             .Col = 2: .Text = "0.00":   .Lock = True:   .BackColor = &HE0E0E0
     
184.             .Col = 3: .Text = "0.00":   .Lock = True:   .BackColor = &HE0E0E0
     
185.             .Col = 4: .Text = "100.00"
     
186.             .Col = 5: .Formula = "D4": .BackColor = &HFFFFF0
     
187.             .Row = 5
     
188.             .Col = 0: .Text = "ค่าเคเบิ้ลทีวี"
     
189.             .Col = 1: .Text = 5
     
190.             .Col = 2: .Text = "0.00":   .Lock = True:   .BackColor = &HE0E0E0
     
191.             .Col = 3: .Text = "0.00":   .Lock = True:   .BackColor = &HE0E0E0
     
192.             .Col = 4: .Text = "0.00"
     
193.             .Col = 5: .Formula = "D5": .BackColor = &HC0FFFF
     
194.             '
     
195.             .Row = 6
     
196.             .Col = 0: .Text = "ค่าเก็บขยะ"
     
197.             .Col = 1: .Text = 6
     
198.             .Col = 2: .Text = "0.00":   .Lock = True:   .BackColor = &HE0E0E0
     
199.             .Col = 3: .Text = "0.00":   .Lock = True:   .BackColor = &HE0E0E0
     
200.             .Col = 4: .Text = "0.00"
     
201.             .Col = 5: .Formula = "D6": .BackColor = &HFFFFF0
     
202.             '
     
203.             .Row = 7
     
204.             .Col = 0: .Text = "ค่าปรับล่าช้า"
     
205.             .Col = 1: .Text = 7
     
206.             .Col = 2: .Text = "0.00":   .Lock = True:   .BackColor = &HE0E0E0
     
207.             .Col = 3: .Text = "0.00":   .Lock = True:   .BackColor = &HE0E0E0
     
208.             .Col = 4: .Text = "0.00"
     
209.             .Col = 5: .Formula = "D7": .BackColor = &HC0FFFF
     
210.             '
     
211.             .Row = 8
     
212.             .Col = 0: .Text = "อื่นๆ"
     
213.             .Col = 1: .Text = 8
     
214.             .Col = 2: .Text = "0.00":   .Lock = True:   .BackColor = &HE0E0E0
     
215.             .Col = 3: .Text = "0.00":   .Lock = True:   .BackColor = &HE0E0E0
     
216.             .Col = 4: .Text = "-0.00"
     
217.             .Col = 5: .Formula = "D8": .BackColor = &HFFFFF0
     
218.             
     
219.             ' COLUMN E
     
220.             .Row = 9
     
221.             .Col = 0: .Text = "รวมจำนวนเงินทั้งสิ้น"
     
222.             .Col = 1: .Text = 9
     
223.             .Col = 2: .Formula = "SUM(E1:E8)"
     
224.             .BackColor = &HFFEFEF
     
225.             .Lock = True
     
226.             .FontBold = True
     
227.             .ForeColor = vbBlue
     
228.             .RowHeight(9) = 24
     
229.             .TypeNumberDecPlaces = 2
     
230.             .TypeNumberShowSep = True
     
231.             .TypeHAlign = TypeHAlignRight
     
232.             .TypeVAlign = TypeVAlignCenter
     
233.     End With
     
234.    
     
235. End Sub
     
236. 
     
237. Private Sub Form_Resize()
     
238.     On Error Resume Next
     
239.     If Me.Height < 11475 Then
     
240.         Me.Height = 11475
     
241.         Exit Sub
     
242.     End If
     
243.     '
     
244.     If Me.Width < 11550 Then '9950 Then
     
245.         Me.Width = 11550
     
246.         Exit Sub
     
247.     End If
     
248.     '//
     
249.     cmdExit.Left = Me.ScaleWidth - cmdExit.Width - 75
     
250.     cmdPrint.Left = cmdExit.Left - cmdExit.Width - 60
     
251.     fraFP.Move 15, 870
     
252.     fraFP.Width = Me.ScaleWidth - 30
     
253.     fraFP.Height = fp.Top - fraPrint.Top
     
254.     fp.Width = fraFP.Width - 75
     
255.     '//
     
256.     fraPrint.Width = Me.ScaleWidth - 15
     
257.     fraPrint.Height = Me.ScaleHeight - fraFP.Height - fraFP.Top
     
258.     ARViewerSlip.Move 15, 120, fraPrint.Width - 60, fraPrint.Height - 180
     
259. End Sub
     
260. 
     
261. Private Sub Form_Unload(Cancel As Integer)
     
262.     '// ลบไฟล์ขยะ (Temporary) ก่อนปิดโปรแกรม
     
263.     If Dir$(App.Path & "\*.tmp") <> "" Then Kill App.Path & "\*.tmp"
     
264.     Set frmFPG = Nothing
     
265.     End
     
266. End Sub
     
267. 
     
268. ' / --------------------------------------------------------------------------------
     
269. '// ก่อนทำการแก้ไข
     
270. Private Sub fp_BeforeEditMode(ByVal Col As Long, ByVal Row As Long, ByVal UserAction As FPUSpreadADO.BeforeEditModeActionConstants, CursorPos As Variant, Cancel As Variant)
     
271.     ' / ค่าที่สำคัญคือ Col, Row
     
272.     ' / รับค่าหลัก, แถว
     
273.     fp.Col = Col: fp.Row = Row
     
274.     '// เก็บค่าเดิมของหลัก 2 และหลัก 3 เอาไว้เปรียบเทียบมากกว่า/น้อยกว่า
     
275.     Select Case Col
     
276.         Case 2
     
277.             strCell1 = CDbl(fp.Value)
     
278.             '// เพิ่มหลักไปรับค่าเดิมในหลัก 3
     
279.             fp.Col = Col + 1
     
280.             strCell2 = CDbl(fp.Value)
     
281.         Case 3
     
282.             '// ถอยหลักกลับไปรับค่าเดิมในหลัก 2
     
283.             fp.Col = Col - 1
     
284.             strCell1 = CDbl(fp.Value)
     
285.             fp.Col = Col
     
286.             strCell2 = CDbl(fp.Value)
     
287.     End Select
     
288. End Sub
     
289. 
     
290. ' / --------------------------------------------------------------------------------
     
291. '// เมื่อแก้ไขข้อมูลในเซลล์แล้วกด Enter ต้องทำการทดสอบค่าเริ่มต้นและค่าสิ้นสุด
     
292. Private Sub fp_EditMode(ByVal Col As Long, ByVal Row As Long, ByVal Mode As Integer, ByVal ChangeMade As Boolean)
     
293.     fp.Col = Col: fp.Row = Row
     
294.     ' ดักจับค่าว่างก่อน หากไม่มีก็ออกจากโปรแกรมย่อยไป
     
295.     If IsNull(fp.Value) Or Trim(fp.Value) = "" Then Exit Sub
     
296.     ' Mode 0 คือ Edit Mode
     
297.     Select Case Mode
     
298.         Case 0:
     
299.             Select Case Col
     
300.                     '// หลัก 2 จะมากกว่าหลัก 3 ไม่ได้ หากใช่ให้แจ้งเตือนพร้อมกับคืนค่าเดิม
     
301.                 Case 2:
     
302.                     If CDbl(fp.Value) > CDbl(strCell2) Then
     
303.                         MsgBox "อย่ามากกว่าหน่วยสุดท้ายซิ เดี๋ยวโดนตบจูบซ่ะหรอก", vbOKOnly + vbInformation, "รายงานความผิดพลาด"
     
304.                         fp.Value = CDbl(strCell1)
     
305.                     End If
     
306.                
     
307.                 Case 3:
     
308.                     '// หลัก 3 จะน้อยกว่าหลัก 2 ไม่ได้ หากใช่ให้แจ้งเตือนพร้อมกับคืนค่าเดิม
     
309.                     If CDbl(fp.Value) < CDbl(strCell1) Then
     
310.                         MsgBox "อย่าน้อยว่าหน่วยเริ่มต้นซิ เดี๋ยวโดนตบจูบซ่ะหรอก", vbOKOnly + vbInformation, "รายงานความผิดพลาด"
     
311.                         fp.Value = CDbl(strCell2)
     
312.                     End If
     
313.             End Select
     
314.     End Select
     
315. End Sub
     
316. 
     
317. Private Sub cmdExit_Click()
     
318.     Unload Me
     
319. End Sub
     
320. 
     
321. Private Sub mnuFileExit_Click()
     
322.     Unload Me
     
323. End Sub
     
324. 
     
325. Private Sub mnuFileSetup_Click()
     
326.     frmSetup.Show vbModal
     
327. End Sub

คัดลอกไปที่คลิปบอร์ด

โค้ดในส่วนของการพิมพ์รายงานด้วย ActiveReports 2.0

1. ' / --------------------------------------------------------------------------------
   
2. ' / Developer : Mr.Surapon Yodsanga (Thongkorn Tubtimkrob)
   
3. ' / eMail : thongkorn@hotmail.com
   
4. ' / URL: http://www.g2gnet.com (Khon Kaen - Thailand)
   
5. ' / Facebook: https://www.facebook.com/g2gnet (For Thailand)
   
6. ' / Facebook: https://www.facebook.com/commonindy (Worldwide)
   
7. ' / Purpose: Print bill on paper size A5.
   
8. ' / Microsoft Visual Basic 6.0 (SP1) + FarPoint Spread 8.0
   
9. ' /
   
10. ' / This is open source code under @CopyLeft by Thongkorn Tubtimkrob.
    
11. ' / You can modify and/or distribute without to inform the developer.
    
12. ' / --------------------------------------------------------------------------------
    
13. Option Explicit
    
14. Dim ItemNo As Integer
    
15. 
    
16. Dim GrandTotal As Double
    
17. 
    
18. ' / --------------------------------------------------------------------------------
    
19. ' / ส่วนการอ่านข้อมูลเข้ามาพิมพ์ ด้วยการนับจำนวนแถวใน FarPoint Spread
    
20. Private Sub ActiveReport_FetchData(EOF As Boolean)
    
21.     ItemNo = ItemNo + 1
    
22.     ' ตรวจสอบจำนวนการพิมพ์ทั้งหมด อ้างถึง frmFPG.fp.DataRowCnt - 1
    
23.     If ItemNo > frmFPG.fp.DataRowCnt - 1 Then
    
24.         EOF = True
    
25.         Exit Sub
    
26.     Else
    
27.         EOF = False
    
28.     End If
    
29. 
    
30. End Sub
    
31. 
    
32. ' / --------------------------------------------------------------------------------
    
33. ' / ส่วนเริ่มต้นการพิมพ์ทุกครั้ง
    
34. Private Sub ActiveReport_Initialize()
    
35.     PageSettings.Orientation = ddOPortrait
    
36.     '// ตั้งค่ากระดาษเอง
    
37.     PageSettings.PaperSize = 256
    
38.     '// หน่วยวัดเป็น Twip (1440 Twip = 1 Inch = 2.54 Cm.)
    
39.     PageSettings.LeftMargin = 500
    
40.     PageSettings.RightMargin = 60
    
41.     PageSettings.BottomMargin = 100
    
42.     PageSettings.TopMargin = 600
    
43.     ' ขนาดครึ่ง A4 และ ทำการแปลงหน่วยวัดเป็นเซนติเมตร เพื่อให้ง่ายในการวัดระยะ (1440 Twip = 1 Inch = 2.54 Cm.)
    
44.     PageSettings.PaperHeight = (14.5 * 1440 / 2.54)
    
45.     PageSettings.PaperWidth = (21 * 1440 / 2.54)
    
46.     '
    
47.     txtCname.Text = ""
    
48.     txtRoomNo.Text = ""
    
49.     txtDate.Text = ""
    
50.     txtDateMonth.Text = ""
    
51.     txtItem.Text = ""
    
52.     txtDesc.Text = ""
    
53.     txtQTY.Text = ""
    
54.     txtUnitPrice.Text = ""
    
55.     txtAmount.Text = ""
    
56.     txtGrandTotal.Text = 0
    
57.     '
    
58.     lblRemark1.Caption = ""
    
59.     lblRemark2.Caption = ""
    
60.     '// อ่านค่า INI File
    
61.     Dim strFileINI As String
    
62.     strFileINI = App.Path & "\Config.ini"
    
63.     '// เช็คว่ามีไฟล์ Config.ini อยู่หรือไม่???
    
64.     '// หากไม่มีก็ตั้งค่าเริ่มต้นให้ก่อน
    
65.     If Dir(strFileINI) = "" Then
    
66.         WriteIniValue strFileINI, "Config", "Owner", "ทองก้อน ฮาเร็ม อพาร์ทเมนท์ 2017"
    
67.         WriteIniValue strFileINI, "Config", "Address", "123/456 ถ.กลางเมือง ต.เมืองเก่า อ.เมือง จ.ขอนแก่น โทร.043-XXX-XXX"
    
68.         WriteIniValue strFileINI, "Config", "Remark1", "1. กรุณาชำระเงินภายในวันที่ 32 ของทุกเดือน"
    
69.         WriteIniValue strFileINI, "Config", "Remark2", "2. การเงินมีปัญหา ใส่ชุดนักศึกษามาหาป๋าทองก้อนได้ตลอด 24 ชั่วโมง"
    
70.     End If
    
71.     '// อ่านค่า Config ต่างๆเข้ามา
    
72.     txtOwner.Text = ReadIniValue(strFileINI, "Config", "Owner")
    
73.     txtAddress.Text = ReadIniValue(strFileINI, "Config", "Address")
    
74.     lblRemark1.Caption = ReadIniValue(strFileINI, "Config", "Remark1")
    
75.     lblRemark2.Caption = ReadIniValue(strFileINI, "Config", "Remark2")
    
76. End Sub
    
77. 
    
78. ' / --------------------------------------------------------------------------------
    
79. ' / ส่วนของการพิมพ์รายละเอียดแต่ละแถว
    
80. Private Sub Detail_Format()
    
81.     ' ตัวแปร ItemNo กลายเป็นแบบ Static
    
82.     txtItem.Text = ItemNo & "."
    
83.     ' Description หลัก 0
    
84.     frmFPG.fp.Col = 0: frmFPG.fp.Row = ItemNo
    
85.     txtDesc.Text = frmFPG.fp.Text
    
86.     ' จำนวนหน่วย  หลัก 2 และ 3
    
87.     Dim MeterStart As Double: Dim MeterEnd As Double: Dim Meter As Double
    
88.     frmFPG.fp.Col = 2
    
89.     MeterStart = frmFPG.fp.Text
    
90.     frmFPG.fp.Col = 3
    
91.     MeterEnd = frmFPG.fp.Text
    
92.     Meter = MeterEnd - MeterStart
    
93.     ' ค่าน้ำประปา
    
94.     If ItemNo = 2 Or ItemNo = 3 Then
    
95.         txtDesc.Text = txtDesc.Text & " (" & MeterEnd & " - " & MeterStart & " = " & Meter & " หน่วย)"
    
96.     End If
    
97.    
    
98.     frmFPG.fp.Col = 4
    
99.     If frmFPG.fp.Value <> 0 And (MeterStart = 0) And (MeterEnd = 0) Then
    
100.         txtQTY.Text = "1.00"
     
101.     Else
     
102.         txtQTY.Text = Format(Meter, "#,##0.00")
     
103.     End If
     
104.     ' ราคาต่อหน่วย
     
105.     frmFPG.fp.Col = 4
     
106.     txtUnitPrice.Text = Format(frmFPG.fp.Text, "#,##0.00")
     
107.     ' รวมเงิน
     
108.     frmFPG.fp.Col = 5
     
109.     txtAmount.Text = Format(frmFPG.fp.Text, "#,##0.00")
     
110.     ' หาจำนวนเงินรวม
     
111.     GrandTotal = Format(GrandTotal + CDbl(txtAmount.Text), "#,##0.00")
     
112.     '
     
113.     '// กระโดดไป FetchData เข้ามาใหม่ จนกว่าข้อมูลรายการจำนวนแถวจะนับได้ครบ ถือเป็นการสิ้นสุดการพิมพ์
     
114. End Sub
     
115. 
     
116. Private Sub GroupFooter1_Format()
     
117.     txtGrandTotal.Text = "รวมจำนวนเงินทั้งสิ้น: " & Format(GrandTotal, "#,##0.00") & ""
     
118. End Sub
     
119. 
     
120. Private Sub GroupHeader1_Format()
     
121.     '// อ้างอิงถึงค่าจาก TextBox ในฟอร์ม frmFPG
     
122.     txtCname.Text = frmFPG.txtFirstName & " " & frmFPG.txtLastName
     
123.     txtRoomNo.Text = frmFPG.txtRoomNo.Text
     
124.     txtDate.Text = Format(Now(), "dd/mm/yyyy") & " เวลา: " & Format(Now(), "HH:MM")
     
125.     txtDateMonth.Text = frmFPG.txtMonth.Text
     
126. End Sub
     
127. 
     
128. Private Sub ActiveReport_ReportEnd()
     
129.     Set arSlipA5 = Nothing
     
130.     Unload Me
     
131. End Sub

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดต้นฉบับ VB6 ได้ที่นี่ ...

m997

ขอบคุณครับท่านอาจารย์

prawpun

ขอบคุณมากคะ