[VB6] การค้นหาคำ และการจำกัดความยาว (MaxLength) ใน ComboBox Control

thongkorn

ลองกด s

ทดสอบเรียกใช้ฟังค์ชั่น Call MaxComboBox(Combo1, 10, KeyAscii)

โดยธรรมชาติของ Visual Basic 6 หรือ VB6 จะไม่คุณสมบัติ (Properties) หรือ Method โดยตรงใดๆในการค้นหาคำ หรือจำกัดความยาว (MaxLength) ในการป้อนข้อมูลลงไปใน ComboBox แต่ทว่าด้วยขีดความสามารถของ VB6 ที่มันถูกซ่อนเร้นเอาไว้ ด้วยการดึงพลังออกมาจาก Windows API (Application Programming Interface) ก็จะช่วยทำให้งานที่เป็นไปไม่ได้ ให้เป็นไปได้ ...

1. '// หากไปประกาศใน Module ต้องแก้ไขให้เป็นตัวแปรแบบ Public
   
2. Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" ( _
   
3.     ByVal hwnd As Long, _
   
4.     ByVal wMsg As Long, _
   
5.     ByVal wParam As Long, _
   
6.     lParam As Any _
   
7.     ) As Long
   
8.    
   
9. Private Const CB_FINDSTRING = &H14C
   
10. Private Const CB_ERR = (-1)

คัดลอกไปที่คลิปบอร์ด

การประกาศใช้ฟังค์ชั่น SendMessage ที่อยู่ใน Library และการประกาศตัวแปรแบบคงที่ (Constant)

มาดูโค้ดฉบับเต็ม ... อย่าลืมกำหนดตอน Design Time ให้ ComboBox มีคุณสมบัติ Style = 0 - DropDown Combo

1. ' / -----------------------------------------------------------------------------------------------
   
2. ' / Developer : Mr.Surapon Yodsanga (Thongkorn Tubtimkrob)
   
3. ' / eMail : thongkorn@hotmail.com
   
4. ' / URL: http://www.g2gnet.com (Khon Kaen - Thailand)
   
5. ' / Facebook: https://www.facebook.com/g2gnet (For Thailand)
   
6. ' / Facebook: https://www.facebook.com/commonindy (Worldwide)
   
7. ' /
   
8. ' / Purpose: Search data and limit length input on ComboBox.
   
9. ' / Microsoft Visual Basic 6.0 Service Pack 6
   
10. ' /
    
11. ' / This is open source code under @CopyLeft by Thongkorn Tubtimkrob.
    
12. ' / You can modify and/or distribute without to inform the developer.
    
13. ' / -----------------------------------------------------------------------------------------------
    
14. Option Explicit
    
15. 
    
16. '// หากไปประกาศใน Module ต้องแก้ไขให้เป็นตัวแปรแบบ Public
    
17. Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" ( _
    
18.     ByVal hwnd As Long, _
    
19.     ByVal wMsg As Long, _
    
20.     ByVal wParam As Long, _
    
21.     lParam As Any _
    
22.     ) As Long
    
23.    
    
24. Private Const CB_FINDSTRING = &H14C
    
25. Private Const CB_ERR = (-1)
    
26. 
    
27. Private Sub Combo1_KeyPress(KeyAscii As Integer)
    
28.         '/ ไปโปรแกรมย่อยในการค้นหาคำใน ComboBox โดยส่งค่าไป 2 ตัว
    
29.         '/ ชื่อของ ComboBox และ KeyAscii ที่กดลงไป
    
30.         Call SearchComboBox(Combo1, KeyAscii)
    
31.         
    
32.         '/ จำกัดความยาวของการพิมพ์คำใน ComboBox
    
33.         Call MaxComboBox(Combo1, 10, KeyAscii)
    
34. End Sub
    
35. 
    
36. Private Sub Form_Load()
    
37.     With Combo1
    
38.         .AddItem "Fruit"
    
39.         .AddItem "Vetgetable"
    
40.         .AddItem "Soft Drink"
    
41.         .AddItem "Meat"
    
42.         .AddItem "Water"
    
43.         .AddItem "Snacks"
    
44.     End With
    
45.     Me.Combo1.ListIndex = 0
    
46. End Sub
    
47. 
    
48. ' / -----------------------------------------------------------------------------------------------
    
49. ' / โปรแกรมย่อยที่ช่วยจำกัดความยาวข้อมูลสำหรับ ComboBox
    
50. Private Sub MaxComboBox(cmb As ComboBox, MaxChar As Integer, KeyAscii As Integer)
    
51.      If Len(cmb.Text) >= MaxChar Then '// ถ้าหากมีความยาวมากกว่า หรือ เท่ากับที่ได้ตั้งไว้
    
52.          If KeyAscii <> vbKeyBack Then '// เป็นการกดคีย์ Back Space หรือไม่
    
53.               KeyAscii = 0 '// ไม่ใช่ให้ถือว่าไม่ได้กดคีย์ใดๆเลย
    
54.          End If
    
55.     End If
    
56. End Sub
    
57. 
    
58. ' / -----------------------------------------------------------------------------------------------
    
59. ' / โปรแกรมย่อยในการค้นหาคำในรายการของ ComboBox
    
60. Private Sub SearchComboBox(cmb As ComboBox, KeyAscii As Integer)
    
61.     Dim strKey As String, iRet As Long, LenKey As Long
    
62.     cmb.SelText = ""
    
63.     strKey = cmb.Text & Chr$(KeyAscii)
    
64.     iRet = SendMessage(cmb.hwnd, CB_FINDSTRING, -1, ByVal strKey)
    
65.     If iRet <> CB_ERR Then
    
66.         LenKey = Len(strKey)
    
67.         cmb.Text = cmb.List(iRet)
    
68.         cmb.ListIndex = iRet
    
69.         KeyAscii = 0
    
70.         cmb.SelStart = LenKey
    
71.         cmb.SelLength = Len(cmb.Text) - LenKey
    
72.     End If
    
73. 
    
74. End Sub

คัดลอกไปที่คลิปบอร์ด

sarikaplan

อ. จะสามารถใช้กับ Control "DataCombo" ได้หรือไม่?
ถ้าได้ อ. เสนอ Code VB6 ให้ดูได้หรือเปล่าครับ
นับถือ
ขอบคุณ