[VB.NET] โค้ดตัวอย่างของการนำชุดข้อมูลหลายชุดทั้ง Table หรือ Query ใส่ไว้ใน DataSet ตัวเดียว

thongkorn

โค้ดตัวอย่างซึ่งแอดมินคิดว่าน่าจะเพิ่มความเข้าใจได้ดีขึ้นระหว่างคำว่า DataSet กับ DataTable เพราะว่าเราสามารถนำชุดข้อมูลหลายชุดทั้ง Table หรือ Query ใส่ไว้ใน DataSet เพียงตัวเดียวได้ ส่วน DataTable จะใส่ได้เพียงทีละ 1 Table หรือ 1 Query เท่านั้น ...


มาดูโค้ดฉบับเต็มกันเถอะ ...

1. Public Class frmMultipleDataSet
   
2.     Private Conn As New OleDbConnection
   
3.     '// Data Path
   
4.     Private strPathData As String = MyPath(Application.StartupPath) & "Data"
   
5.     Dim MyDataSet As New DataSet()
   
6. 
   
7.     ' / ------------------------------------------------------------------------------------
   
8.     ' / S T A R T ... H E R E
   
9.     ' / ------------------------------------------------------------------------------------
   
10.     Private Sub frmMultipleDataSet_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
    
11.         Call ConnectDataBase()  '// Connect Northwind.accdb DataBase.
    
12.         Call InitialDataGridView()  '// Initialized DataGridView one time for DataSet.
    
13.         '//
    
14.         Dim Tables(4) As String '// (Indexs 0 - 4 of 5 Tables)
    
15.         Tables(0) = "customers" : Tables(1) = "employees" : Tables(2) = "products" : Tables(3) = "suppliers" : Tables(4) = "orders"
    
16.         MyDataSet = GetDataSet(Tables)
    
17.         '// Tables in DataSet.
    
18.         With cmbDataSet
    
19.             .Items.Add("Customers")
    
20.             .Items.Add("Employees")
    
21.             .Items.Add("Products")
    
22.             .Items.Add("Suppliers")
    
23.             .Items.Add("Orders")
    
24.             .Items.Add("Sample Query")
    
25.         End With
    
26.         cmbDataSet.SelectedIndex = 0
    
27.         '// DataTable.
    
28.         With cmbDataTable
    
29.             .Items.Add("Customers")
    
30.             .Items.Add("Employees")
    
31.             .Items.Add("Products")
    
32.             .Items.Add("Suppliers")
    
33.             .Items.Add("Orders")
    
34.             .Items.Add("Sample Query")
    
35.         End With
    
36.         cmbDataTable.SelectedIndex = 0
    
37.     End Sub
    
38. 
    
39.     ' / ------------------------------------------------------------------------------------
    
40.     '// Multiple Tables/Query in DataSet.
    
41.     ' / ------------------------------------------------------------------------------------
    
42.     Private Function GetDataSet(ByRef Tables() As String) As System.Data.DataSet
    
43.         If Conn.State = ConnectionState.Closed Then Conn.Open()
    
44.         Dim Cmd As New OleDbCommand()
    
45.         Cmd.Connection = Conn
    
46.         Cmd.CommandType = System.Data.CommandType.Text
    
47.         Dim DA As OleDbDataAdapter = New OleDbDataAdapter(Cmd)
    
48.         Dim DS As DataSet = New DataSet()
    
49.         '// Fill data from many tables or queries into DataSet object.
    
50.         For intCount As Byte = 0 To Tables.GetUpperBound(0)
    
51.             Cmd.CommandText = "SELECT * FROM " & Tables(intCount)
    
52.             DA.Fill(DS, Tables(intCount))
    
53.         Next
    
54.         '// Add new sample query. (6 Tables in 1 DataSet)
    
55.         Dim sql As String = _
    
56.             " SELECT Orders.OrderID, Customers.CustomerID, Customers.CompanyName, Orders.OrderDate, " & _
    
57.             " Products.ProductName, [Order Details].Quantity, Products.UnitPrice " & _
    
58.             " FROM Products INNER JOIN (Customers INNER JOIN (Orders INNER JOIN [Order Details] ON " & _
    
59.             " Orders.OrderID = [Order Details].OrderID) ON Customers.CustomerID = Orders.CustomerID) ON " & _
    
60.             " Products.ProductID = [Order Details].ProductID"
    
61.         Cmd.CommandText = sql
    
62.         DA.Fill(DS, "SampleQuery")  '// Also give the new data table a name.
    
63.         '//
    
64.         Conn.Close()
    
65.         Return DS
    
66.     End Function
    
67. 
    
68.     ' / ------------------------------------------------------------------------------------
    
69.     ' / Select Table/Query in DataSet.
    
70.     ' / ------------------------------------------------------------------------------------
    
71.     Private Sub cmbDataSet_SelectedIndexChanged(sender As System.Object, e As System.EventArgs) Handles cmbDataSet.SelectedIndexChanged
    
72.         Select Case cmbDataSet.SelectedIndex
    
73.             Case 0
    
74.                 dgvData.DataSource = MyDataSet.Tables("customers").DefaultView
    
75.             Case 1
    
76.                 dgvData.DataSource = MyDataSet.Tables("employees").DefaultView
    
77.             Case 2
    
78.                 dgvData.DataSource = MyDataSet.Tables("products").DefaultView
    
79.             Case 3
    
80.                 dgvData.DataSource = MyDataSet.Tables("suppliers").DefaultView
    
81.             Case 4
    
82.                 dgvData.DataSource = MyDataSet.Tables("orders").DefaultView
    
83.             Case 5
    
84.                 dgvData.DataSource = MyDataSet.Tables("SampleQuery").DefaultView
    
85.         End Select
    
86.     End Sub
    
87. 
    
88.     ' / ------------------------------------------------------------------------------------
    
89.     ' / Sample for DataSet to DataTable.
    
90.     ' / ------------------------------------------------------------------------------------
    
91.     Private Sub btnDataSetToDataTable_Click(sender As System.Object, e As System.EventArgs) Handles btnDataSetToDataTable.Click
    
92.         '// DataTable can contain only 1 table.
    
93.         Dim DT As New DataTable
    
94.         Select Case cmbDataTable.SelectedIndex
    
95.             Case 0
    
96.                 DT = MyDataSet.Tables(0)
    
97.                 dgvData.DataSource = DT
    
98.             Case 1
    
99.                 DT = MyDataSet.Tables(1)
    
100.                 dgvData.DataSource = DT
     
101.             Case 2
     
102.                 DT = MyDataSet.Tables(2)
     
103.                 dgvData.DataSource = DT
     
104.             Case 3
     
105.                 DT = MyDataSet.Tables(3)
     
106.                 dgvData.DataSource = DT
     
107.             Case 4
     
108.                 DT = MyDataSet.Tables(4)
     
109.                 dgvData.DataSource = DT
     
110. 
     
111.                 '// Query.
     
112.             Case 5
     
113.                 'DT = MyDataSet.Tables(5)
     
114.                 '// Or use the name of Table.
     
115.                 DT = MyDataSet.Tables("SampleQuery")
     
116.                 '//
     
117.                 If dgvData.Rows.Count > 0 Then dgvData.DataSource = Nothing
     
118.                 '// If there is a column named Total, delete it from the DataTable.
     
119.                 If DT.Columns.Contains("Total") Then DT.Columns.Remove("Total")
     
120.                 '// Add a new column to calculate the sum of the Quantity X UnitPrice.
     
121.                 DT.Columns.Add("Total", GetType(Double))
     
122.                 DT.Columns("Total").Expression = "[Quantity] * [UnitPrice]"
     
123.                 '// An example of how to customize the display of DataGridView with DataTable.
     
124.                 dgvData.DataSource = DT
     
125.                 With dgvData
     
126.                     .Columns(0).HeaderText = "Order ID"
     
127.                     .Columns(1).HeaderText = "Customer ID"
     
128.                     .Columns(2).HeaderText = "Company Name"
     
129.                     .Columns(3).HeaderText = "Order Date"
     
130.                     .Columns(4).HeaderText = "Product Name"
     
131.                     .Columns(5).HeaderText = "Quantity"
     
132.                     With .Columns(6)
     
133.                         .HeaderText = "Unit Price"
     
134.                         .DefaultCellStyle.Format = "0.00"
     
135.                         .HeaderCell.Style.Alignment = DataGridViewContentAlignment.MiddleRight
     
136.                         .DefaultCellStyle.Alignment = DataGridViewContentAlignment.MiddleRight
     
137.                     End With
     
138.                     '// Columns(7) and Columns("Total") is the same.
     
139.                     .Columns(7).HeaderText = "Total"
     
140.                     .Columns("Total").DefaultCellStyle.Format = "N2"
     
141.                     .Columns(7).HeaderCell.Style.Alignment = DataGridViewContentAlignment.MiddleRight
     
142.                     .Columns("Total").DefaultCellStyle.Alignment = DataGridViewContentAlignment.MiddleRight
     
143.                 End With
     
144.         End Select
     
145.     End Sub
     
146. 
     
147.     ' / ------------------------------------------------------------------------------------
     
148.     Sub InitialDataGridView()
     
149.         With dgvData
     
150.             .RowHeadersVisible = False
     
151.             .AllowUserToAddRows = False
     
152.             .AllowUserToDeleteRows = False
     
153.             .AllowUserToResizeRows = False
     
154.             .MultiSelect = False
     
155.             .SelectionMode = DataGridViewSelectionMode.FullRowSelect
     
156.             .ReadOnly = True
     
157.             ' Autosize Column Mode.
     
158.             .AutoSizeColumnsMode = DataGridViewAutoSizeColumnsMode.Fill
     
159.             .RowTemplate.DefaultCellStyle.Font = New Font("Tahoma", 11, FontStyle.Regular)
     
160.             .RowTemplate.Height = 32
     
161.             '// Set ColumnHeadersHeightSizeMode before adjusting row heights.
     
162.             .ColumnHeadersHeightSizeMode = DataGridViewColumnHeadersHeightSizeMode.EnableResizing
     
163.             .ColumnHeadersHeight = 28
     
164.             '// Set EnableHeadersVisualStyles = False to accept background color changes.
     
165.             .EnableHeadersVisualStyles = False
     
166.             '// Even-Odd Color
     
167.             .AlternatingRowsDefaultCellStyle.BackColor = Color.LightYellow ' .AliceBlue
     
168.             '// Example of adjusting Header Style.
     
169.             With .ColumnHeadersDefaultCellStyle
     
170.                 .BackColor = Color.Orange
     
171.                 .ForeColor = Color.Black
     
172.                 .Font = New Font("Tahoma", 11, FontStyle.Bold)
     
173.             End With
     
174.         End With
     
175.     End Sub
     
176. 
     
177.     Private Sub btnExit_Click(sender As System.Object, e As System.EventArgs) Handles btnExit.Click
     
178.         Me.Close()
     
179.     End Sub
     
180. 
     
181.     Private Sub frmMultipleDataSet_FormClosed(sender As Object, e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
     
182.         Conn.Close()
     
183.         Me.Dispose()
     
184.         GC.SuppressFinalize(Me)
     
185.         Application.Exit()
     
186.     End Sub
     
187. 
     
188. #Region "FUNCTION"
     
189.     ' / --------------------------------------------------------------------------------
     
190.     ' / Get my project path
     
191.     ' / AppPath = C:\My Project\bin\debug
     
192.     ' / Replace "\bin\debug" with ""
     
193.     ' / Return : C:\My Project\
     
194.     Function MyPath(AppPath As String) As String
     
195.         '/ Return Value
     
196.         MyPath = AppPath.ToLower.Replace("\bin\debug", "").Replace("\bin\release", "").Replace("\bin\x86\debug", "")
     
197.         '// If not found folder then put the \ (BackSlash) at the end.
     
198.         If Microsoft.VisualBasic.Right(MyPath, 1) <> Chr(92) Then MyPath = MyPath & Chr(92)
     
199.     End Function
     
200. #End Region
     
201. 
     
202. #Region "CONNECTDATABASE"
     
203.     Public Function ConnectDataBase() As Boolean
     
204.         Dim strConn As String = _
     
205.                 "Provider = Microsoft.ACE.OLEDB.12.0; Data Source = " & strPathData & "Northwind.accdb"
     
206.         Try
     
207.             Conn = New OleDb.OleDbConnection(strConn)
     
208.             '// Create Connection
     
209.             Conn.ConnectionString = strConn
     
210.             Conn.Open()
     
211.             '// Return
     
212.             Return True
     
213.         Catch ex As Exception
     
214.             MessageBox.Show(ex.Message)
     
215.             Conn = Nothing
     
216.             Return False
     
217.             'End
     
218.         End Try
     
219.     End Function
     
220. 
     
221. #End Region
     
222. End Class

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดต้นฉบับ VB.NET (2010) ได้ที่นี่ ...

juachan

ขอบคุณครับ อาจารย์