[VB.NET] การ Import Excel เข้ามาใน ListView ด้วย Interop Service

thongkorn

โพสต์ก่อนหน้าเป็นการ Import Excel เข้ามาใน Listview Control ด้วยการใช้ ADO.NET คือการมอง Sheet เป็นเหมือนกับตารางข้อมูล (DataTable) คราวนี้จะใช้ Interop Service หรือการใช้งาน COM (Component Object Model) ก็เป็นเทคโนโลยีรุ่นเก่า ก่อนที่จะมาเป็น Dot Net ในทุกวันนี้แหละครับ ดังนั้นแล้วในเครื่องเราจะต้องทำการติดตั้ง MS Excel เอาไว้ก่อนด้วย เพราะต้อง Add Reference COM เข้ามาช่วย โดยจะทำการอ่านข้อมูลจาก Sheet เข้ามาทีละหลักและทีละแถว แล้วทำการเก็บชุดข้อมูลไว้ใน DataTable เหมือนกับการใช้ ADO.NET ทุกอย่าง แม้ว่าการอ่านข้อมูลเข้ามาจะทำได้ช้ากว่า ADO.NET แต่มันมีข้อดีคือสามารถเลือกเซลล์ หรือช่วงข้อมูล (Range) ที่เราต้องการได้ ...




เลือก Add References ... เลือก COM (Component Object Model) ทั้งนี้ก็ขึ้นอยู่กับเวอร์ชั่นของ Excel ที่ติดตั้งในเครื่องของแต่ละคน ...

มาดูโค้ดฉบับเต็มกันเถอะ ...

1. Imports Excel = Microsoft.Office.Interop.Excel
   
2. 
   
3. Public Class frmWorkSheet2ListView
   
4. 
   
5.     Dim DS As DataSet = New DataSet()
   
6. 
   
7.     ' / --------------------------------------------------------------------------------
   
8.     ' / เลือกไฟล์ Excel
   
9.     ' / --------------------------------------------------------------------------------
   
10.     Private Sub btnOpenExcel_Click(sender As System.Object, e As System.EventArgs) Handles btnOpenExcel.Click
    
11.         '/ ประกาศใช้งาน Open File Dialog ในแบบ Run Time
    
12.         Dim dlgOpenFile As OpenFileDialog = New OpenFileDialog()
    
13. 
    
14.         '// ตั้งค่าการใช้งาน Open File Dialog
    
15.         With dlgOpenFile
    
16.             .InitialDirectory = MyPath(System.Windows.Forms.Application.StartupPath)
    
17.             .Title = "เลือกไฟล์ MS Excel"
    
18.             .Filter = "XLSX Files (*.xlsx)|*.xlsx|XLS Files (*.xls)|*xls"
    
19.             .FilterIndex = 1
    
20.             .RestoreDirectory = True
    
21.         End With
    
22.         '// หากเลือกปุ่ม OK หลังจากการ Browse ...
    
23.         If dlgOpenFile.ShowDialog() = DialogResult.OK Then
    
24.             txtFileName.Text = dlgOpenFile.FileName
    
25.             '//
    
26.             cmbSheetName.Items.Clear()
    
27.             ListView1.Columns.Clear()
    
28.             '// Create a new Excel application
    
29.             Dim excelApp As New Excel.Application()
    
30.             '// Open the Excel workbook
    
31.             Dim workbook As Excel.Workbook = excelApp.Workbooks.Open(txtFileName.Text)
    
32.             Try
    
33.                 '// เคลียร์ค่า Table/Query ของเดิมใน DataSet ก่อนใช้งานใหม่
    
34.                 '// หรือหากให้เพิ่มตารางข้อมูล/คิวรี่ จากไฟล์อื่น ก็ตัดบรรทัดนี้ทิ้งออกไป
    
35.                 DS = New DataSet()
    
36.                 '// Loop through each worksheet in the workbook
    
37.                 For Each worksheet As Excel.Worksheet In workbook.Sheets
    
38.                     '// Create a new DataTable for each worksheet.
    
39.                     Dim DT As New DataTable(worksheet.Name)
    
40.                     cmbSheetName.Items.Add(worksheet.Name)
    
41.                     '// Add columns to the DataTable.
    
42.                     For col As Integer = 1 To worksheet.UsedRange.Columns.Count
    
43.                         DT.Columns.Add(DirectCast(worksheet.Cells(1, col), Excel.Range).Value2.ToString())
    
44.                     Next
    
45.                     '// Loop through the rows and columns in the worksheet.
    
46.                     For row As Integer = 2 To worksheet.UsedRange.Rows.Count
    
47.                         Dim dataRow = DT.NewRow()
    
48.                         For col As Integer = 1 To worksheet.UsedRange.Columns.Count
    
49.                             dataRow(col - 1) = DirectCast(worksheet.Cells(row, col), Excel.Range).Value2
    
50.                         Next
    
51.                         DT.Rows.Add(dataRow)
    
52.                     Next
    
53.                     '// Add the DataTable to the DataSet.
    
54.                     DS.Tables.Add(DT)
    
55.                 Next
    
56.             Catch ex As Exception
    
57.                 '// Handle any exceptions that may occur during the process.
    
58.                 MessageBox.Show("An error occurred: " & ex.Message)
    
59.             Finally
    
60.                 '// Close and release resources
    
61.                 workbook.Close()
    
62.                 excelApp.Quit()
    
63.                 System.Runtime.InteropServices.Marshal.ReleaseComObject(workbook)
    
64.                 System.Runtime.InteropServices.Marshal.ReleaseComObject(excelApp)
    
65.             End Try
    
66.         End If
    
67.     End Sub
    
68. 
    
69.     ' / --------------------------------------------------------------------------------
    
70.     '// เลือก WorkSheet แล้วแสดงผลข้อมูลลงใน ListView
    
71.     ' / --------------------------------------------------------------------------------
    
72.     Private Sub cmbSheetName_SelectedIndexChanged(sender As System.Object, e As System.EventArgs) Handles cmbSheetName.SelectedIndexChanged
    
73.         With ListView1
    
74.             .Clear()
    
75.             .View = View.Details
    
76.             .GridLines = True
    
77.             .FullRowSelect = True
    
78.             .HideSelection = False
    
79.             .MultiSelect = False
    
80.         End With
    
81.         Try
    
82.             '/ Access the DataTable by its name.
    
83.             Dim DT As System.Data.DataTable = DS.Tables(cmbSheetName.Text)
    
84.             '/ Now you can work with the 'dataTable' as needed
    
85.             '/ For example, you can iterate through its rows and columns
    
86.             '// อ่านจำนวนหลักทั้งหมดเข้ามาก่อน
    
87.             For iCol = 0 To DT.Columns.Count - 1
    
88.                 ListView1.Columns.Add(DT.Columns(iCol).ColumnName)
    
89.                 '// ปรับระยะความกว้างใหม่
    
90.                 ListView1.Columns(iCol).Width = ListView1.Width \ (DT.Columns.Count - 1)
    
91.             Next
    
92.             '// อ่านข้อมูลในแต่ละแถว
    
93.             For sRow = 0 To DT.Rows.Count - 1
    
94.                 Dim LV As New ListViewItem
    
95.                 Dim dRow As DataRow = DT.Rows(sRow)
    
96.                 LV = ListView1.Items.Add(dRow.Item(0))  '// --> Primary Node
    
97.                 For iCol = 1 To DT.Columns.Count - 1
    
98.                     LV.SubItems.Add(dRow(iCol).ToString())
    
99.                 Next
    
100.             Next
     
101.             ListView1.AutoResizeColumns(ColumnHeaderAutoResizeStyle.HeaderSize)
     
102.         Catch ex As Exception
     
103.             MessageBox.Show(ex.Message)
     
104.         End Try
     
105.     End Sub
     
106. 
     
107.     ' / --------------------------------------------------------------------------------
     
108.     ' / เหตุการณ์ Double Click Mouse บน ListView เพื่อแสดงผลข้อมูลในแถวรายการที่เลือก
     
109.     ' / --------------------------------------------------------------------------------
     
110.     Private Sub ListView1_DoubleClick(sender As Object, e As System.EventArgs) Handles ListView1.DoubleClick
     
111.         MessageBox.Show( _
     
112.             "Column 0: " & ListView1.SelectedItems(0).Text & vbCrLf & _
     
113.             "Column 1: " & ListView1.SelectedItems.Item(0).SubItems(1).Text & vbCrLf & _
     
114.             "Column 2: " & ListView1.SelectedItems.Item(0).SubItems(2).Text & vbCrLf & _
     
115.             "Column 3: " & ListView1.SelectedItems.Item(0).SubItems(3).Text)
     
116.     End Sub
     
117. 
     
118.     Private Sub txtFileName_KeyPress(sender As Object, e As System.Windows.Forms.KeyPressEventArgs) Handles txtFileName.KeyPress
     
119.         e.Handled = True    '// Can't keypress.
     
120.     End Sub
     
121. 
     
122.     Private Sub btnExit_Click(sender As System.Object, e As System.EventArgs) Handles btnExit.Click
     
123.         Me.Close()
     
124.     End Sub
     
125. 
     
126.     Private Sub frmWorkSheet2ListView_FormClosed(sender As Object, e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
     
127.         Me.Dispose()
     
128.         GC.SuppressFinalize(Me)
     
129.         Application.Exit()
     
130.     End Sub
     
131. 
     
132. #Region "FUNCTION"
     
133.     ' / --------------------------------------------------------------------------------
     
134.     ' / Get my project path
     
135.     ' / AppPath = C:\My Project\bin\debug
     
136.     ' / Replace "\bin\debug" with ""
     
137.     ' / Return : C:\My Project\
     
138.     Public Function MyPath(ByVal AppPath As String) As String
     
139.         '/ MessageBox.Show(AppPath);
     
140.         MyPath = AppPath.ToLower.Replace("\bin\debug", "").Replace("\bin\release", "").Replace("\bin\x86\debug", "").Replace("\bin\x86\release", "")
     
141.         '// If not found folder then put the \ (BackSlash) or ASCII Code = 92 at the end.
     
142.         '/ Return Value
     
143.         If Microsoft.VisualBasic.Right(MyPath, 1) <> Chr(92) Then MyPath = MyPath & Chr(92)
     
144.     End Function
     
145. 
     
146. #End Region
     
147. 
     
148. End Class

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดต้นฉบับ VB.NET (2010) ได้ที่นี่ ...