[VB6] การป้อนข้อมูลรายละเอียดการขายสินค้าเข้าสู่ตาราง FarPoint Spread

thongkorn

จากโปรแกรมการพิมพ์ใบเสร็จ ที่แอดมินได้ทำการแจกจ่ายให้ผู้ใช้งานทั่วไปได้ใช้งานฟรี (อ่านรายละเอียดและดาวน์โหลดได้ที่นี่) แอดมินใช้ Visual Basic 6 ในการพัฒนา โดยให้ FarPoint Spread ป้อนหรือรับข้อมูลรายละเอียดของสินค้าในแต่ละแถว ซึ่งวันนี้แอดมินจะมาถ่ายทอดความรู้ไว้เป็นวิทยาทานให้แก่ผู้ที่ยังไม่รู้ แต่ใฝ่รู้ทั้งหลายได้รับรู้กันครับ อย่างที่แอดมินได้เกริ่นนำไปในตอนที่แล้วว่า ลักษณะการใช้งานของ FarPoint มันเหมือนกับการใช้ตารางใน Excel โดยเราต้องรู้หลักและแถว เพื่อเข้าไปจัดการในแต่ละเซลล์ ซึ่งบทความนี้แอดมินยิ่งจะย้ำให้เห็นถึง วิธีการ UnBound Data หรือ ไม่มีแหล่งจ่ายข้อมูล (Data Source) มาให้ เราจะอาศัยการป้อนข้อมูลลงไปเท่านั้น (ตอนหน้าถึงจะโหลดข้อมูลเข้าอีกที เพื่อทำการพิมพ์รายงาน) ในบทความตอนนี้สิ่งที่ท่านจะได้เรียนรู้ก็คือ ...

- วิธีการตั้งค่าคุณสมบัติ (Properties) เพื่อให้รับค่าเฉพาะตัวเลขจำนวนเต็ม เลขทศนิยม หรือข้อมูลชนิดอื่นๆตามที่เราต้องการได้เท่านั้น (Validating Data)
- วิธีการนำข้อมูลในแต่ละเซลล์ที่กำหนดไว้ เพื่อมาคำนวณหาค่าตัวเลขผลรวม
- วิธีการเพิ่ม หรือ ลบแถว จากจุดที่ต้องการ

อนึ่ง แม้ว่า FarPoint Spread มันมี Designer ติดมาให้ด้วย เพื่อช่วยให้เราสามารถออกแบบตารางได้อย่างไม่ยากเย็น แต่แอดมินไม่นิยมใช้รูปแบบของ Design Time มากนัก เพราะมันยากต่อการจดจำ และขาดความยืดหยุ่นในความต้องการที่อาจจะเกิดการเปลี่ยนแปลง ดังนั้นบทความนี้แอดมินจะใช้การเขียนโค้ดแบบ Run Time ทั้งหมด รายละเอียดของการใช้ Designer ท่านต้องไปศึกษาเพิ่มเติมกันเอาเองนะครับ

ดาวน์โหลดชุดติดตั้ง FarPoint Spread ActiveX และ Update 8.0.21 ล่าสุดจากผู้ผลิต (เฉพาะสมาชิกเท่านั้น)


FarPoint Spread Designer ...


หน้าจอของการออกแบบ และการเรียกใช้ Component ...

โค้ดการตั้งค่าคุณสมบัติของ FarPoint Spread ในแบบ Run Time ...

1. ' / --------------------------------------------------------------------------------
   
2. ' / โปรแกรมย่อยที่กำหนดค่าคุณสมบัติ (Properties) ต่างๆ ให้กับ Spread
   
3. Sub SetupSpread()
   
4. ' / --------------------------------------------------------------------------------
   
5.     ' แสดงแถบแสงหรือไม่แสดง
   
6.     fpData.OperationMode = OperationModeNormal   ' เอาไว้ป้อนข้อมูล
   
7.     'fpData.OperationMode = OperationModeSingle    ' แถบ Selection
   
8.     'fpSpread.OperationMode = OperationModeRead     ' ไม่มีแถบ
   
9.     'fpSpread.OperationMode = OperationModeRow
   
10.    
    
11.     ' สามารถจัดเรียง หรือ Sort Order บนหัวคอลัมภ์ได้
    
12.     fpData.UserColAction = UserColActionSortNoIndicator ' = UserColActionSort
    
13.    
    
14.     ' ปรับหน่วยวัด
    
15.     'fpData.UnitType = UnitTypeNormal
    
16.     'fpData.UnitType = UnitTypeTwips
    
17.     'fpData.UnitType = UnitTypeVGABase
    
18.    
    
19.     ' การปรับความสูงของแถวทุกๆแถว (ค่า -1 หมายถึงทุกแถวครับ)
    
20.     fpData.RowHeight(-1) = 18    ' หน่วยวัด Point
    
21.     fpData.Appearance = Appearance3D
    
22.     fpData.AppearanceStyle = AppearanceStyleEnhanced ' = AppearanceStyleVisualStyles
    
23.    
    
24.     ' เวลากด F2 เพื่อแก้ไขข้อมูลในแต่ละเซลล ์ให้เลือกข้อมูลทั้งหมด หรือสามารถเริ่มคีย์ค่าใหม่ได้ทันที
    
25.     fpData.EditModeReplace = True
    
26.     fpData.CellType = CellTypeEdit
    
27.    
    
28.     ' การกำหนด Column แบบ Run Time
    
29.     With fpData
    
30.         ' หลักแรก คือ หลักที่ 0 ... จะเป็นการแสดงหมายเลขแถว เพื่ออ้างอิงในลักษณะ Excel เช่น
    
31.         .SetText 1, 0, "รหัสสินค้า"
    
32.         .SetText 2, 0, "รายละเอียด"
    
33.         .SetText 3, 0, "หน่วยละ"
    
34.         .SetText 4, 0, "จำนวน"
    
35.         .SetText 5, 0, "รวมจำนวนเงิน"
    
36.         .SetText 6, 0, " "
    
37.         .SetText 7, 0, " "
    
38.         
    
39.         ' จำนวนหลักทั้งหมด
    
40.         .MaxCols = 7
    
41.         ' เป็นแถวว่าง 1 แถว
    
42.         .MaxRows = 1
    
43.         
    
44.         ' กำหนดคุณสมบัติต่างๆของแต่ละหลักแบบ Run Time
    
45.         ' ID หรือ รหัสสินค้า
    
46.         .Col = 1
    
47.         .TypeTextWordWrap = True
    
48.         .TypeVAlign = TypeVAlignCenter
    
49.         ' จำกัดความยาวในเซลล์ หากเวลาที่เราใช้กับฐานข้อมูล จะได้ไม่มีปัญหาในการจัดเก็บที่กำหนดจากฟิลด์ข้อมูล
    
50.         .TypeMaxEditLen = 50
    
51.         
    
52.         ' Description
    
53.         .Col = 2
    
54.         .TypeTextWordWrap = True
    
55.         .TypeVAlign = TypeVAlignCenter
    
56.         .TypeMaxEditLen = 175
    
57.         
    
58.         ' หน่วยละ
    
59.         .Col = 3
    
60.         ' การจัดตำแหน่งแนวนอน
    
61.         .TypeHAlign = TypeHAlignRight
    
62.         ' การจัดตำแหน่งแนวตั้ง
    
63.         .TypeVAlign = TypeVAlignCenter
    
64.         ' กำหนดการป้อนค่าตัวเลขจำนวนเงินเท่านั้น (หรือหากต้องการให้เป็นเลขจำนวนเต็มก็กำหนด CellTypeNumber แทน)
    
65.         .CellType = CellTypeCurrency
    
66.         ' ตามหลังจุศนิยม
    
67.         .TypeNumberDecPlaces = 2
    
68.         ' ไม้แสดงสัญลักษณ์ตัวเงิน
    
69.         .TypeCurrencyShowSymbol = False
    
70.         ' ค่าต่ำสุด
    
71.         .TypeCurrencyMin = 1
    
72.         
    
73.         ' จำนวน
    
74.         .Col = 4
    
75.         ' การจัดตำแหน่งแนวนอน
    
76.         .TypeHAlign = TypeHAlignRight
    
77.         ' การจัดตำแหน่งแนวตั้ง
    
78.         .TypeVAlign = TypeVAlignCenter
    
79.         ' กำหนดการป้อนค่าตัวเลขจำนวนเงินเท่านั้น (เลขทศนิยม)
    
80.         .CellType = CellTypeCurrency
    
81.         ' ตามหลังจุศนิยม
    
82.         .TypeNumberDecPlaces = 2
    
83.         ' ไม่แสดงสัญลักษณ์ตัวเงิน
    
84.         .TypeCurrencyShowSymbol = False
    
85.         .TypeCurrencyMin = 0
    
86.         
    
87.         ' รวมจำนวนเงิน
    
88.         .Col = 5
    
89.         ' ล็อคการคีย์ข้อมูล
    
90.         .Lock = True
    
91.         .TypeHAlign = TypeHAlignRight
    
92.         .TypeVAlign = TypeVAlignCenter
    
93.         .CellType = CellTypeCurrency
    
94.         .TypeCurrencyShowSymbol = False
    
95.         ' จุดทศนิยม 2 ตัว
    
96.         .TypeNumberDecPlaces = 2
    
97.         ' แสดงเครื่องหมายคอมม่า (,)
    
98.         .TypeCurrencyShowSep = True
    
99.         
    
100.         ' ปุ่มเพิ่มแถว
     
101.         .Col = 6
     
102.         .CellType = CellTypeButton
     
103.         .TypeButtonText = "เพิ่ม F3"
     
104.         .ColWidth(4) = 120
     
105.         .Lock = True
     
106.         .BlockMode = False
     
107.         ' ปุ่มลบแถว
     
108.         .Col = 7
     
109.         .CellType = CellTypeButton
     
110.         .TypeButtonText = "ลบ F5"
     
111.         .ColWidth(4) = 120
     
112.         .Lock = True
     
113.    
     
114.     End With
     
115.    
     
116. End Sub

คัดลอกไปที่คลิปบอร์ด

การ Validating Data สามารถทำได้ง่ายดายมาก เช่น กรณีต้องการรับค่าเลขจุดทศนิยมเท่านั้น เราก็กำหนด fpData.CellType = CellTypeCurrency ทำให้เกิดความสะดวกและรวดเร็วต่อการพัฒนาโปรแกรมของเรา


โค้ดตั้งค่าเริ่มต้นในแต่ละหลักให้กับ FarPoint Spread ...

1. ' / --------------------------------------------------------------------------------
   
2. ' / ข้อมูลทดสอบ
   
3. Sub SampleData()
   
4. ' / --------------------------------------------------------------------------------
   
5.     ' ใส่ข้อมูลทดสอบ
   
6.     With fpData
   
7.         .MaxRows = 1
   
8.         .Row = 1
   
9.         .Col = 1: .Text = ""    ' รหัสสินค้า
   
10.         .Col = 2: .Text = ""    ' ชื่อหรือรายละเอียดสินค้า
    
11.         .Col = 3: .Text = "0.00"    ' ราคาต่อหน่วย
    
12.         .Col = 4: .Text = "1"           ' จำนวน
    
13.         .Col = 5: .Text = "0.00"    ' ผลรวมราคา X จำนวน
    
14.         .ForeColor = &HFF0000
    
15.     End With
    
16.     ' ActiveCell ไปที่หลัก 2 (รายละเอียด) แถวปัจจุบัน
    
17.     fpData.SetActiveCell 2, fpData.ActiveRow
    
18.     '/ หาผลรวม
    
19.     Call CalTotalRow(1)
    
20. End Sub

คัดลอกไปที่คลิปบอร์ด

โค้ดเหตุการณ์ที่สำคัญในการใช้งาน FarPoint Spread ...

1. ' / --------------------------------------------------------------------------------
   
2. ' / เหตุการณ์ก่อนทำการแก้ไขข้อมูลในเซลล์
   
3. Private Sub fpData_BeforeEditMode( _
   
4.     ByVal Col As Long, _
   
5.     ByVal Row As Long, _
   
6.     ByVal UserAction As FPUSpreadADO.BeforeEditModeActionConstants, _
   
7.     CursorPos As Variant, Cancel As Variant _
   
8.     )
   
9. ' / --------------------------------------------------------------------------------
   
10.     ' / ค่าที่สำคัญคือ Col, Row
    
11.     ' รับค่าหลัก, แถว
    
12.     fpData.Col = Col: fpData.Row = Row
    
13.     ' ปกติเราจะเก็บค่าเดิมก่อนมีการเปลี่ยนแปลง เผื่อว่าต้องการคืนค่ากลับ เช่น
    
14.     'strDataCol = fpData.Value  '<-- strDataCol ต้องประกาศแบบ Public สำหรับให้ทุกโมดูลในฟอร์มนี้มองเห็น
    
15. End Sub
    
16. 
    
17. ' / --------------------------------------------------------------------------------
    
18. ' / เมื่อเกิดการคีย์ข้อมูลเข้าไปในแต่ละเซลล์
    
19. Private Sub fpData_Change(ByVal Col As Long, ByVal Row As Long)
    
20. ' / --------------------------------------------------------------------------------
    
21.     fpData.Row = Row
    
22.     ' เลือกหลักที่ต้องการให้ตรวจสอบ
    
23.     Select Case fpData.ActiveCol
    
24.         ' ราคาต่อหน่วย
    
25.         Case 3:
    
26.             ' จำนวน
    
27.             fpData.Col = 4
    
28.             ' หากไม่ป้อนจำนวนตัวเลขใดๆ ก็กำหนดให้เป็น 1
    
29.             If fpData.Value = "" Then fpData.Value = "1.00"
    
30.    
    
31.         ' จำนวน
    
32.         Case 4:
    
33.             ' หน่วยละ
    
34.             fpData.Col = 3
    
35.             If fpData.Value = "" Then fpData.Value = "0.00"
    
36.    
    
37.     End Select
    
38.     '/ หาผลรวมใหม่
    
39.     Call CalTotalRow(fpData.ActiveRow)
    
40. End Sub
    
41. 
    
42. ' / --------------------------------------------------------------------------------
    
43. ' / โปรแกรมย่อยคำนวณหาราคา x จำนวน ในทุกๆแถวของตารางกริด (FarPoint)
    
44. ' / หากเกิดค่าเปลี่ยนแปลงในหลักที่ 3 และหลักที่ 4 จะมาคำนวณผลต่างๆที่นี่
    
45. Sub CalTotalRow(ByVal sRow As Long)
    
46. ' / --------------------------------------------------------------------------------
    
47.    
    
48.     Dim UnitPrice As Currency
    
49.     Dim Amount As Double
    
50.     Dim i As Byte
    
51.     Dim sGrandTotal As Currency
    
52.    
    
53.     With fpData
    
54.         ' รับค่าแถวปัจจุบัน
    
55.         .Row = sRow
    
56.         ' เก็บค่าในหลักที่ 3 ไว้ในตัวแปร (หน่วยละ)
    
57.         .Col = 3
    
58.         ' .Text คือข้อมูลในเซลล์นั้นๆ เช่น จากหลักที่ 3 และแถวตามตัวแปร sRow ที่ถูกส่งมาจากเหตุการณ์ fpData_Change
    
59.         If .Text <> "" Then
    
60.             UnitPrice = Format(.Text, "0.00")
    
61.         Else
    
62.             UnitPrice = "0.00"
    
63.         End If
    
64.         
    
65.         ' เก็บค่าในหลักที่ 4 ไว้ในตัวแปร (จำนวน)
    
66.         .Col = 4
    
67.         If .Text <> "" Then
    
68.             Amount = Val(.Text)
    
69.         Else
    
70.             Amount = "0.00"
    
71.         End If
    
72.         
    
73.         ' นำค่าในหลักที่ 3 (ราคาต่อหน่วย) คูณกับหลักที่ 4 (จำนวนสินค้า) ผลลัพธ์เก็บในหลักที่ 5 (จำนวนเงิน)
    
74.         .Col = 5
    
75.         .Text = Format(UnitPrice * Amount, "#,##0.00")
    
76.         ' รวมจำนวนเงินทั้งหมด ตั้งแต่แถวที่ 1 ไปถึงแถวสุดท้ายของ Spread (FarPoint)
    
77.         For i = 1 To .DataRowCnt ' .MaxRows
    
78.             ' ไล่ไปทีละแถว
    
79.             .Row = i
    
80.             ' หลัก 5 คือผลรวม
    
81.             .Col = 5
    
82.             If Trim(.Text) <> "" Then sGrandTotal = CDbl(.Text) + sGrandTotal
    
83.         Next
    
84.         
    
85.         ' แสดงจำนวนเงินทั้งหมด
    
86.         txtGrandTotal.Text = Format(sGrandTotal, "#,##0.00")
    
87.         
    
88.         ' เรื่องของภาษี
    
89.         Select Case cmbTaxType.ListIndex
    
90.             '/ ไม่คิดภาษี
    
91.             Case 0:
    
92.                 txtVat.Text = "0.00"
    
93.                 ' รวมเป็นจำนวนเงินทั้งสิ้น
    
94.                 txtNetTotal.Text = Format(CDbl(txtGrandTotal.Text) + CDbl(txtVat.Text), "#,##0.00")
    
95.             
    
96.             ' รวมภาษีใน
    
97.             Case 1:
    
98.                 Dim VatTemp As Currency
    
99.                 VatTemp = (100 * Val(TAXRATE)) / (100 + Val(TAXRATE))
    
100.                 ' คิดภาษี
     
101.                 txtVat.Text = Format(CCur(txtGrandTotal.Text) * VatTemp / 100, "#,##0.00")
     
102.                 txtGrandTotal.Text = Format(sGrandTotal - CCur(txtVat.Text), "#,##0.00")
     
103.                 ' รวมเป็นจำนวนเงินทั้งสิ้น
     
104.                 txtNetTotal.Text = Format(CDbl(txtGrandTotal.Text) + CDbl(txtVat.Text), "#,##0.00")
     
105.             
     
106.             ' ภาษีนอก
     
107.             Case 2:
     
108.                 ' คิดภาษี
     
109.                 txtVat.Text = Format(CCur(txtGrandTotal.Text) * Val(TAXRATE) / 100, "#,##0.00")
     
110.                 ' รวมเป็นจำนวนเงินทั้งสิ้น
     
111.                 txtNetTotal.Text = Format(CCur(txtGrandTotal.Text) + CDbl(txtVat.Text), "#,##0.00")
     
112.         End Select
     
113.    
     
114.     End With
     
115.    
     
116. End Sub
     
117. 
     
118. ' / --------------------------------------------------------------------------------
     
119. ' / เกิดเหตุการณ์นำเมาส์ไปคลิ๊กในเซลล์
     
120. Private Sub fpData_Click(ByVal Col As Long, ByVal Row As Long)
     
121. ' / --------------------------------------------------------------------------------
     
122.     ' หากคลิ๊กเลือกที่ Header
     
123.     If Row = 0 Then Exit Sub
     
124.     '
     
125.     Dim sRow As Integer
     
126.     ' เลือกหลักที่ต้องการตรวจสอบ
     
127.     Select Case Col
     
128.         ' แสดงว่าคลิ๊กเพื่อเพิ่มแถว
     
129.         Case 6
     
130.             fpData.Col = 2
     
131.             ' ตรวจสอบก่อนว่าในแถวนั้นๆ (sRow) มีการป้อนรายละเอียดของสินค้าหรือไม่
     
132.             sRow = CheckDataColumn(fpData.Col, False)
     
133.             If sRow > 0 Then
     
134.                 MsgBox "กรุณาป้อนรายละเอียดก่อนเพิ่มแถวใหม่ด้วย.", vbOKOnly + vbInformation, "รายงานสถานะ"
     
135.                 ' ActiveCell
     
136.                 fpData.SetActiveCell 2, sRow
     
137.                 Exit Sub
     
138.             End If
     
139.             
     
140.             '/ หน่วยละ
     
141.             fpData.Col = 3
     
142.             ' ตรวจสอบก่อนว่าในแถวนั้นๆ (sRow) มีการป้อนราคาของสินค้าหรือไม่
     
143.             sRow = CheckDataColumn(fpData.Col, True)
     
144.             If sRow > 0 Then
     
145.                 MsgBox "กรุณาป้อนราคาต่อหน่วยก่อนเพิ่มแถวใหม่ด้วย.", vbOKOnly + vbInformation, "รายงานสถานะ"
     
146.                 ' ActiveCell บังคับให้โฟกัสไปอยู่ในเซลล์ที่ต้องใส่ราคาก่อน
     
147.                 fpData.SetActiveCell 3, sRow
     
148.                 Exit Sub
     
149.             End If
     
150.             
     
151.             ' เมื่อตรวจสอบถูกต้องหมด ก็กำหนดแถวสูงสุด ไว้ล่วงหน้าขึ้นไปอีก 1 เพื่อทำรายการเพิ่มแถวใหม่เข้าไป
     
152.             fpData.MaxRows = fpData.MaxRows + 1
     
153.             ' เพิ่มรายการแถว ถัดจากแถวที่มันอยู่ (ActiveRow)
     
154.             fpData.InsertRows fpData.ActiveRow + 1, 1
     
155.             ' ใส่ค่าใหม่ลงไป
     
156.             With fpData
     
157.                 .Row = .ActiveRow + 1
     
158.                 ' ProductID
     
159.                 .Col = 1
     
160.                 .Value = ""
     
161.                 ' Description
     
162.                 .Col = 2
     
163.                 .Value = ""
     
164.                 ' หน่วยละ
     
165.                 .Col = 3
     
166.                 .Value = "0.00"
     
167.                 ' จำนวน
     
168.                 .Col = 4
     
169.                 .Value = "1.00"
     
170.                 ' รวม
     
171.                 .Col = 5
     
172.                 .Value = "0.00"
     
173.                 .ForeColor = &HFF0000
     
174.             End With
     
175.             ' ActiveCell ไปที่หลัก 2 (รายละเอียด) แถวปัจจุบัน + 1
     
176.             fpData.SetActiveCell 2, fpData.ActiveRow + 1
     
177.         
     
178.         ' ลบแถว
     
179.         Case 7:
     
180.             ' ดักเอ้อเหรอ (Error) กรณีที่ไม่มีแถวข้อมูลอยู่เลย
     
181.             If fpData.MaxRows = 1 Then Exit Sub
     
182.             ' ลบแถวปัจจุบันที่มันอยู่ออกไปก่อน
     
183.             fpData.DeleteRows fpData.ActiveRow, 1
     
184.             ' กำหนดแถวสูงสุด โดยลดค่าลง 1
     
185.             fpData.MaxRows = fpData.MaxRows - 1
     
186.             '/ คำนวณผลรวมใหม่
     
187.             Call CalTotalRow(fpData.ActiveRow)
     
188.     End Select
     
189. 
     
190. End Sub
     
191. 
     
192. ' / --------------------------------------------------------------------------------
     
193. ' / ตรวจสอบการป้อนข้อมูลในตารางกริด FarPoint
     
194. Function CheckDataColumn(Col As Long, blnNumber As Boolean) As Integer
     
195. ' / --------------------------------------------------------------------------------
     
196.     CheckDataColumn = 0
     
197.     Dim sRow As Integer
     
198.     fpData.Col = Col
     
199.     For sRow = 1 To fpData.DataRowCnt
     
200.         fpData.Row = sRow
     
201.         ' Check ว่าค่าที่ส่งมาเป็นตัวเลขหรือไม่
     
202.         If blnNumber Then
     
203.             If CDbl(fpData.Text) <= 0# Then
     
204.                 CheckDataColumn = sRow
     
205.                 Exit Function
     
206.             End If
     
207.         ' เป็นตัวอักษร
     
208.         Else
     
209.             If fpData.Text = "" Then
     
210.                 CheckDataColumn = sRow
     
211.                 Exit Function
     
212.             End If
     
213.         End If
     
214.     Next
     
215. End Function

คัดลอกไปที่คลิปบอร์ด

โค้ดที่เหลือของโปรเจค ... (เผื่อท่านขี้เกียจสมัครสมาชิกเข้ามาแสวงหาความรู้)

1. Option Explicit
   
2. 
   
3. ' ค่าคงที่อัตราภาษี 7%
   
4. Const TAXRATE As Byte = 7
   
5. 
   
6. ' / --------------------------------------------------------------------------------
   
7. ' / คำนวณหาภาษี
   
8. Private Sub cmbTaxType_Click()
   
9. ' / --------------------------------------------------------------------------------
   
10.     If fpData.DataRowCnt > 0 Then Call CalTotalRow(1)
    
11. End Sub
    
12. 
    
13. ' / --------------------------------------------------------------------------------
    
14. Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
    
15. ' / --------------------------------------------------------------------------------
    
16.     Select Case KeyCode
    
17.         
    
18.         Case vbKeyF1: 'MsgBox "No help now."
    
19.         Case vbKeyF3: Call fpData_Click(6, fpData.ActiveRow)
    
20.         Case vbKeyF5: Call fpData_Click(7, fpData.ActiveRow)
    
21.         Case vbKeyF10: Unload Me
    
22.    
    
23.    End Select
    
24. End Sub
    
25. 
    
26. ' / --------------------------------------------------------------------------------
    
27. Private Sub Form_Load()
    
28. ' / --------------------------------------------------------------------------------
    
29.     Me.Move (Screen.Width - Width) \ 2, (Screen.Height - Height) \ 2
    
30.     txtGrandTotal.Text = "0.00"
    
31.     txtVat.Text = "0.00"
    
32.     txtNetTotal.Text = "0.00"
    
33.     With cmbTaxType
    
34.         .AddItem "ไม่คิดภาษี"
    
35.         .AddItem "รวมภาษีใน"
    
36.         .AddItem "แยกภาษีนอก"
    
37.     End With
    
38.     cmbTaxType.ListIndex = 0
    
39.     lblSummary(1).Caption = "คิดภาษี " & TAXRATE & " %"
    
40.     ' จัดระเบียบ Spread แบบ Run Time
    
41.     Call SetupSpread
    
42.     Call SampleData
    
43. End Sub
    
44. 
    
45. ' / --------------------------------------------------------------------------------
    
46. Private Sub Form_Resize()
    
47. ' / --------------------------------------------------------------------------------
    
48.     On Error Resume Next
    
49.     '//
    
50.     fraFP.Move 0, 60
    
51.     fraFP.Width = Me.ScaleWidth - 30
    
52.    
    
53.     txtGrandTotal.Left = fraFP.Width - txtGrandTotal.Width - 300
    
54.     txtVat.Left = txtGrandTotal.Left
    
55.     txtNetTotal.Left = txtGrandTotal.Left
    
56.     '//
    
57.     lblSummary(0).Left = txtGrandTotal.Left - lblSummary(0).Width - 90
    
58.     cmbTaxType.Left = txtVat.Left - cmbTaxType.Width - 90
    
59.     lblSummary(1).Left = cmbTaxType.Left - lblSummary(1).Width - 90
    
60.     lblSummary(2).Left = txtNetTotal.Left - lblSummary(2).Width - 90
    
61.     '/
    
62.     ' ตั้งค่าการขยายของ FarPoint ซึ่งต้องตั้งค่าตามหน่วย Twip ก่อน
    
63.     fpData.Width = fraFP.Width - 60
    
64.     With fpData
    
65.         .UnitType = UnitTypeTwips
    
66.         .RowHeight(-1) = 365
    
67.         .ColWidth(1) = .Width \ 6 - 300
    
68.         .ColWidth(2) = .Width \ 6 + 1600
    
69.         .ColWidth(3) = .Width \ 6 - 600
    
70.         .ColWidth(4) = .Width \ 6 - 800
    
71.         .ColWidth(5) = .Width \ 6 - 500
    
72.         .ColWidth(6) = 800
    
73.         .ColWidth(7) = 800
    
74.     End With
    
75. End Sub
    
76. 
    
77. ' / --------------------------------------------------------------------------------
    
78. Private Sub Form_Unload(Cancel As Integer)
    
79. ' / --------------------------------------------------------------------------------
    
80.     ' ลบไฟล์ Temporary ออกให้หมด
    
81.     If Dir$(App.Path & "\*.tmp") <> "" Then Kill App.Path & "\*.tmp"
    
82.     '//
    
83.     Set frmFarPointData = Nothing
    
84.     End
    
85. End Sub

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดต้นฉบับเต็ม VB6 ได้ที่นี่ ...

wut62

ขอบคุณครับ อาจารย์

MrDen

ขอบพระคุณอย่างสูงครับ อาจารย์  แข็งแรง++ ร่ำรวย ++ ครับ.

prawpun

ขอบคุณมากคะอาจารย์