[VB.NET] โค้ดการพิมพ์สลิปใบเสร็จรับเงินขนาดหน้ากว้าง 3 นิ้ว ด้วย PrintDocument

thongkorn

หน้าจอการแสดงผลรายการ ก่อนทำการ Preview ...


หน้าจอการใช้งาน Print Preview Dialog ...

PrintDocument เป็นคลาสใน .NET Framework (ภายใต้ System.Drawing.Printing) ที่ใช้สำหรับกำหนดเนื้อหาที่จะพิมพ์ลงบนกระดาษ โดยไม่ได้ควบคุมเครื่องพิมพ์โดยตรง แต่ส่งคำสั่งผ่านระบบ Windows Printer Spooler

หลักการทำงาน:
- สร้างออบเจ็กต์ PrintDocument
- กำหนด Event Handler สำหรับเหตุการณ์ PrintPage (ชื่อเหตุการณ์ PrintPageHandler)
- ใน PrintPageHandler ใช้ e.Graphics กับทุกสิ่งที่เราวาด เช่น ข้อความ (DrawString), เส้น (DrawLine), รูปภาพ (DrawImage) หรือ QR Code ก็จะถูกส่งไปยังเครื่องพิมพ์
- เรียก PrintDocument.Print() เพื่อส่งงานพิมพ์จริง หรือ PrintPreviewDialog เพื่อแสดงตัวอย่างก่อนพิมพ์

เพิ่มเติม: แอดมินเพิ่มเติมการแสดงผลใน Print Preview Dialog เพื่อให้ทำการขยายหน้าจอการแสดงผลของกระดาษให้เป็นแบบอัตโนมัติ ตามขนาดหน้าจอของฟอร์ม

ข้อมูลเพิ่มเติมเกี่ยวกับเครื่องพิมพ์สลิป
การตัดกระดาษจะขึ้นอยู่กับการตั้งค่าใน Properties ที่เครื่องพิมพ์สลิปใน Windows ได้ด้วย หากข้อมูลหมดเครื่องพิมพ์จะตัดกระดาษให้อัตโนมัติเองครับ

สูตรคำนวณหาความกว้างของหน้ากระดาษ: (เราต้องใช้หน่วย Pixel)
ขนาดความกว้างของกระดาษมีหน่วย Pixel = Inch × DPI (DPI มีค่าประมาณ 100 = 1 Inch = 100 Pixel)
ดังนั้นหากต้องการขนาดหน้ากว้าง (Width) = 3 นิ้ว (Inch)
Pixel = 3 x 100 = 300 Pixel

มาดูโค้ดฉบับเต็มกันเถอะ ...

1. Public Class frmPrintDoc3Inch
   
2.     '// สูตรคำนวณ:
   
3.     '// ขนาดความกว้างของกระดาษมีหน่วย Pixel = Inch × DPI (DPI มีค่าประมาณ 100 = 1 Inch = 100 Pixel)
   
4.     '// MaxWidth = 3 (นิ้ว) x 100 DPI (Dot Per Inch) = 300 Pixel
   
5.     '// กำหนดความกว้างของกระดาษ: กว้าง 295 Pixel (ลดค่าลงมาเล็กน้อย)
   
6.     Private Const MaxWidth = 295
   
7.     '// กำหนดระยะห่างระหว่างบรรทัด (หน่วยเป็นพิกเซลหรือจุดในการวาดบนกระดาษ)
   
8.     Private Const LineSpacing = 14
   
9. 
   
10.     Private Sub frmPrintDoc3Inch_KeyDown(sender As Object, e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
    
11.         Select Case e.KeyCode
    
12.             Case Keys.F8
    
13.                 Call btnPrintPreview_Click(sender, e)
    
14.             Case Keys.F10
    
15.                 Call btnExit_Click(sender, e)
    
16.         End Select
    
17.     End Sub
    
18. 
    
19.     Private Sub PrintDoc3Inch_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    
20.         Me.KeyPreview = True  '// สามารถกดปุ่มฟังค์ชั่นลงบนฟอร์มได้
    
21.         '// กำหนดข้อมูลในส่วนหัวบิล
    
22.         txtShopName.Text = "ทองก้อนมินิมาร์ท"
    
23.         txtAddress1.Text = "142 ม.11 หมู่บ้านฉัตรทอง ถ.กลางเมือง"
    
24.         txtAddress2.Text = "ต.เมืองเก่า อ.เมืองขอนแก่น จ.ขอนแก่น 40000"
    
25.         txtTaxID.Text = "1234567890XXX"
    
26.         txtHeaderBill.Text = "ใบเสร็จรับเงิน/ใบกำกับภาษีอย่างย่อ"
    
27.         txtInvoiceID.Text = "CASH-" & RandomInvoiceID()
    
28.         dtpInvoiceDate.Value = Now()
    
29. 
    
30.         '// สร้างข้อมูลตัวอย่าง 10 รายการ
    
31.         Call LoadSampleData()
    
32.         '// ตั้งค่าเริ่มต้นให้กับ DataGridView
    
33.         Call SetupDataGridView(dgvData)
    
34.     End Sub
    
35. 
    
36.     '// ข้อมูลตัวอย่าง
    
37.     Private Sub LoadSampleData()
    
38.         Dim DT As DataTable = New DataTable()
    
39.         With DT.Columns
    
40.             .Add("รายการ", GetType(String))
    
41.             .Add("ราคา/หน่วย", GetType(Double))
    
42.             .Add("จำนวน", GetType(Integer))
    
43.             .Add("รวม", GetType(Double))
    
44.         End With
    
45.         Dim Items As String() = {
    
46.             "กาแฟเย็น", "ชาเขียว", "เบเกอรี่", "ขนมปัง", "มันทอดกรอบหอมสดๆใหม่ๆ",
    
47.             "น้ำอัดลม", "น้ำผลไม้", "ไข่เจียว", "ข้าวผัด", "ผักสด"
    
48.         }
    
49.         Dim Prices As Double() = {40, 35, 50, 30, 45, 20, 30, 40, 60, 20}
    
50.         Dim Qty As Integer() = {1, 2, 1, 1, 1, 1, 1, 1, 1, 2}
    
51. 
    
52.         For i As Integer = 0 To 9
    
53.             Dim SubTotal As Double = Prices(i) * Qty(i)
    
54.             DT.Rows.Add(Items(i), Prices(i), Qty(i), SubTotal)
    
55.         Next
    
56.         dgvData.DataSource = DT
    
57.     End Sub
    
58. 
    
59.     '// สุ่มเลขที่ใบเสร็จให้อยู่ในรูปแบบปี พ.ศ. 2 หลักสุดท้าย + จำนวนตัวเลข 5 หลัก
    
60.     Function RandomInvoiceID() As String
    
61.         '// ปกติ DateTime.Now.Year ที่ได้มาจาก .NET เป็นปี ค.ศ. (AD) อยู่แล้ว (แต่อยากเอาแบบให้ชัวร์ๆล่ะกัน)
    
62.         '// อ่านปีปัจจุบัน (เป็น ค.ศ.)
    
63.         Dim YearAD As Integer = DateTime.Now.Year
    
64.         '// เช็คปีก่อนให้แน่ใจ
    
65.         Dim YearBE As Integer
    
66.         If YearAD < 2500 Then
    
67.             '// กรณีเป็น ค.ศ. (เช่น 2025) → บวก 543
    
68.             YearBE = YearAD + 543
    
69.         Else
    
70.             '// กรณีเป็น พ.ศ. อยู่แล้ว
    
71.             YearBE = YearAD
    
72.         End If
    
73.         '// เอา 2 หลักท้าย
    
74.         Dim YearTwoDigit As String = (YearBE Mod 100).ToString("00")
    
75.         '// สุ่มเลข 5 หลัก
    
76.         Dim rnd As New Random()
    
77.         Dim RandomDigits As String = rnd.Next(0, 100000).ToString("D5")
    
78.         '// รวมกัน
    
79.         Return YearTwoDigit & RandomDigits
    
80.     End Function
    
81. 
    
82.     '// ------------------------------------------------------------------------------------------------------------------------------------
    
83.     '// ตั้งค่าขนาดกระดาษก่อนทำการ Preview
    
84.     '// ------------------------------------------------------------------------------------------------------------------------------------
    
85.     Private Sub btnPrintPreview_Click(sender As Object, e As EventArgs) Handles btnPrintPreview.Click
    
86.         '// ประกาศใช้งานแบบ Run Time ทำให้ไม่ต้องไปลาก Control มาวางไว้บนฟอร์มตอน Design Time
    
87.         Dim PrintDoc As New PrintDocument()
    
88.         Dim PrintPreview As PrintPreviewDialog
    
89. 
    
90.         '// คำนวณจำนวนแถวจริงใน DataGridView (ไม่นับแถวว่างสุดท้าย)
    
91.         Dim ItemCount As Integer = dgvData.Rows.Cast(Of DataGridViewRow)().Count(Function(r) Not r.IsNewRow)
    
92.         Dim BaseHeight As Integer = 60 '// ความสูงพื้นฐานที่ใช้แน่นอนเสมอ (ส่วนหัวบิลมีชื่อร้าน วันที่ และอื่นๆ)
    
93.         Dim ContentHeight As Integer = (ItemCount + 6) * LineSpacing    '// ความสูงที่ใช้เฉพาะ ส่วนเนื้อหา (รายการสินค้า + ส่วนท้าย)
    
94.         Dim TotalHeight As Integer = BaseHeight + ContentHeight '// รวมส่วนหัว (BaseHeight) และเนื้อหา (ContentHeight)
    
95. 
    
96.         '// กำหนดขนาดกระดาษ: กว้าง 295 Pixel (MaxWidth คือค่าคงที่ ที่ประกาศอยู่ด้านบน), สูงตามคำนวณ
    
97.         Dim PaperSize As New PaperSize("Custom3Inch", MaxWidth, TotalHeight)
    
98.         PrintDoc.DefaultPageSettings.PaperSize = PaperSize
    
99.         PrintDoc.DefaultPageSettings.Margins = New Margins(10, 10, 10, 10)
    
100. 
     
101.         '// Add Event Handler เพื่อกำหนดการพิมพ์ค่าต่างๆลงไปในกระดาษทั้งหมด
     
102.         AddHandler PrintDoc.PrintPage, AddressOf PrintPageHandler
     
103. 
     
104.         '// -------------------------- PrintPreviewDialog --------------------------
     
105.         PrintPreview = New PrintPreviewDialog() '// PrintPreviewDialog เป็น Form สำเร็จรูปของ .NET ที่ใช้แสดงตัวอย่างเอกสารที่จะถูกพิมพ์
     
106.         PrintPreview.Document = PrintDoc    '// กำหนดว่าเอกสารที่จะพรีวิว คือ PrintDoc
     
107. 
     
108.         '// ให้กระดาษ Fit กับหน้าจอฟอร์มพอดี (ปรับซูมอัตโนมัติ)
     
109.         Dim ppControl As PrintPreviewControl = TryCast(PrintPreview.Controls(1), PrintPreviewControl)
     
110.         If ppControl IsNot Nothing Then ppControl.AutoZoom = True
     
111. 
     
112.         '// ---------------- ปรับขนาดฟอร์มที่ Preview = ค่า % ของขนาดหน้าจอ ----------------
     
113.         Dim ScreenBounds As Rectangle = Screen.PrimaryScreen.Bounds
     
114.         Dim PreviewWidth As Integer = CInt(ScreenBounds.Width * 0.7)    '// กว้าง 70%
     
115.         Dim PreviewHeight As Integer = CInt(ScreenBounds.Height * 0.9)  '// สูง 90%
     
116. 
     
117.         '// --------------------------  กำหนดตำแหน่งให้อยู่กึ่งกลาง --------------------------
     
118.         Dim x As Integer = (ScreenBounds.Width - PreviewWidth) \ 2
     
119.         Dim y As Integer = (ScreenBounds.Height - PreviewHeight) \ 2
     
120. 
     
121.         PrintPreview.StartPosition = FormStartPosition.Manual
     
122.         PrintPreview.Location = New Point(x, y) '// ระบุพิกัดตำแหน่งมุมซ้ายบนของฟอร์มบนหน้าจอ
     
123.         PrintPreview.Size = New Size(PreviewWidth, PreviewHeight)   '// กำหนดขนาดของ PrintPreviewDialog
     
124. 
     
125.         '// กำหนดเครื่องพิมพ์ล่วงหน้า เมื่อเวลาไปกดไอคอนเครื่องพิมพ์ของ Print Preview Dialog
     
126.         '// เพราะหากไม่กำหนดเอาไว้ มันจะส่งไปออกเครื่องพิมพ์ที่เป็น Default Printer แทน
     
127.         '// *************** อย่าลืมแก้ไข PrinterName ด้วย ***************
     
128.         PrintDoc.PrinterSettings.PrinterName = "POS-80"
     
129.         If Not PrintDoc.PrinterSettings.IsValid Then
     
130.             MessageBox.Show("ไม่พบเครื่องพิมพ์ชื่อ POS-80", "Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
     
131.             Exit Sub
     
132.         End If
     
133. 
     
134.         '// เปิดหน้าจอฟอร์มแสดงผล
     
135.         PrintPreview.ShowDialog()
     
136.     End Sub
     
137. 
     
138.     '// ------------------------------------------------------------------------------------------------------------------------------------
     
139.     '// ส่วนของการนำข้อมูลมาพิมพ์
     
140.     '// ------------------------------------------------------------------------------------------------------------------------------------
     
141.     Private Sub PrintPageHandler(sender As Object, e As PrintPageEventArgs)
     
142.         '// กำหนดขนาดของฟอนต์ของแต่ละส่วนที่จะนำมาพิมพ์
     
143.         Dim FontHeader As Font = New Font("Tahoma", 9, FontStyle.Bold)
     
144.         Dim FontNormal As Font = New Font("Tahoma", 8)
     
145.         Dim FontTotal As Font = New Font("Tahoma", 9, FontStyle.Bold)
     
146.         Dim Brush As Brush = Brushes.Black
     
147.         '// Initialize Position
     
148.         Dim StartX As Integer = 10
     
149.         Dim StartY As Integer = 10
     
150. 
     
151.         '// -------------------------- จัดข้อความให้อยู่กึ่งกลาง --------------------------
     
152.         Dim CenterFormat As New StringFormat()
     
153.         CenterFormat.Alignment = StringAlignment.Center
     
154.         '// MaxWidth คือค่าคงที่ = 295 (ขนาดของกระดาษหน้ากว้าง 3 นิ้ว)
     
155.         Dim CenterX As Single = MaxWidth / 2
     
156. 
     
157.         '// การพิมพ์ส่วนหัวบิล
     
158.         '// สังเกตค่า (LineSpacing * เลขจำนวนเต็ม) ... ตัวเลขจำนวนเต็มที่เพิ่มขึ้นไปทีละ 1 นั่นคือการเลื่อนบรรทัดขึ้นไปเรื่อยๆ
     
159.         e.Graphics.DrawString(txtShopName.Text, FontHeader, Brush, CenterX, StartY, CenterFormat)
     
160.         e.Graphics.DrawString(txtAddress1.Text, FontNormal, Brush, CenterX, StartY + LineSpacing, CenterFormat)
     
161.         e.Graphics.DrawString(txtAddress2.Text, FontNormal, Brush, CenterX, StartY + LineSpacing * 2, CenterFormat)
     
162.         e.Graphics.DrawString("เลขประจำตัวผู้เสียภาษี " & txtTaxID.Text, FontNormal, Brush, CenterX, StartY + LineSpacing * 3, CenterFormat)
     
163.         e.Graphics.DrawString(txtHeaderBill.Text, FontNormal, Brush, CenterX, StartY + LineSpacing * 4, CenterFormat)
     
164.         e.Graphics.DrawString("เลขที่ใบเสร็จ: " & txtInvoiceID.Text, FontNormal, Brush, CenterX, StartY + LineSpacing * 5, CenterFormat)
     
165.         '// จัดรูปแบบวันที่:
     
166.         Dim InvDateTime As DateTime = dtpInvoiceDate.Value
     
167.         Dim ThaiDate As String = InvDateTime.ToString("dd MMMM yyyy HH:mm", New CultureInfo("th-TH"))
     
168.         e.Graphics.DrawString("วันที่: " & ThaiDate, FontNormal, Brush, CenterX, StartY + LineSpacing * 6, CenterFormat)
     
169. 
     
170.         '// วาดเส้นแบ่ง
     
171.         DrawLine(e.Graphics, StartX, StartY + LineSpacing * 7, 280, StartY + LineSpacing * 7)
     
172. 
     
173.         '// หัวตาราง
     
174.         e.Graphics.DrawString("รายการ", FontNormal, Brush, StartX, StartY + LineSpacing * 7)
     
175.         e.Graphics.DrawString("ราคา", FontNormal, Brush, 120, StartY + LineSpacing * 7)
     
176.         e.Graphics.DrawString("จำนวน", FontNormal, Brush, 190, StartY + LineSpacing * 7, CenterFormat) '// การจัดข้อความกึ่งกลาง
     
177.         e.Graphics.DrawString("รวม", FontNormal, Brush, 220, StartY + LineSpacing * 7)
     
178. 
     
179.         '// วาดเส้นใต้หัวตาราง
     
180.         DrawLine(e.Graphics, StartX, StartY + LineSpacing * 8, 280, StartY + LineSpacing * 8)
     
181. 
     
182.         '// พิมพ์รายการสินค้า ราคา จำนวน และผลรวมราคา แสดงผลลงไปในแต่ละแถว
     
183.         Dim yPosition As Integer = StartY + LineSpacing * 8
     
184.         Dim TotalAmount As Double = 0
     
185.         For Each row As DataGridViewRow In dgvData.Rows
     
186.             If Not row.IsNewRow Then
     
187.                 Dim ItemName As String = row.Cells(0).Value.ToString()
     
188.                 Dim price As Double = Convert.ToDouble(row.Cells(1).Value)
     
189.                 Dim qty As Integer = Convert.ToInt32(row.Cells(2).Value)
     
190.                 Dim SubTotal As Double = price * qty
     
191.                 '// หากชื่อสินค้าเกิน 15 ตัวอักษร ให้ตัดคำที่เกินออกไป
     
192.                 Dim name As String = If(ItemName.Length > 15, ItemName.Substring(0, 15), ItemName)
     
193.                 '//
     
194.                 e.Graphics.DrawString(name, FontNormal, Brush, StartX, yPosition)
     
195.                 e.Graphics.DrawString(price.ToString("N2"), FontNormal, Brush, 120, yPosition)
     
196.                 e.Graphics.DrawString(qty.ToString("N0"), FontNormal, Brush, 190, yPosition, CenterFormat) '// การจัดข้อความกึ่งกลาง
     
197.                 e.Graphics.DrawString(SubTotal.ToString("N2"), FontNormal, Brush, 220, yPosition)
     
198.                 '//
     
199.                 TotalAmount += SubTotal
     
200.                 yPosition += LineSpacing
     
201.             End If
     
202.         Next
     
203. 
     
204.         '// วาดเส้นแยก
     
205.         DrawLine(e.Graphics, StartX, yPosition, 280, yPosition)
     
206. 
     
207.         '// รวมยอด (ชิดกับเส้นเลย)
     
208.         e.Graphics.DrawString("รวมจำนวนเงิน: ", FontNormal, Brush, StartX, yPosition + 2)
     
209.         e.Graphics.DrawString(TotalAmount.ToString("N2"), FontTotal, Brush, 220, yPosition + 2)
     
210.         '// สิ้นสุด
     
211.         e.HasMorePages = False
     
212.     End Sub
     
213. 
     
214.     '/ ------------------------------------------------------------------------------------------------------------------------------------
     
215.     '/ วาดเส้นแยก
     
216.     Private Sub DrawLine(g As Graphics, x1 As Integer, y1 As Integer, x2 As Integer, y2 As Integer)
     
217.         Using pen As New Pen(Color.Black, 0.5)
     
218.             g.DrawLine(pen, x1, y1, x2, y2)
     
219.         End Using
     
220.     End Sub
     
221. 
     
222.     Private Sub btnExit_Click(sender As System.Object, e As System.EventArgs) Handles btnExit.Click
     
223.         Me.Close()
     
224.     End Sub
     
225. 
     
226.     Private Sub frmPrintDoc3Inch_FormClosed(sender As Object, e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
     
227.         Me.Dispose()
     
228.         GC.SuppressFinalize(Me)
     
229.         Application.Exit()
     
230.     End Sub
     
231. 
     
232. #Region "SETUP DATAGRIDVIEW"
     
233.     Sub SetupDataGridView(DGV As DataGridView)
     
234.         '// จัดการรูปแบบและควบคุม DataGridView
     
235.         With DGV
     
236.             .RowHeadersVisible = False
     
237.             .AllowUserToAddRows = False
     
238.             .AllowUserToDeleteRows = False
     
239.             .AllowUserToResizeRows = False
     
240.             .MultiSelect = False
     
241.             .SelectionMode = DataGridViewSelectionMode.FullRowSelect
     
242.             .ReadOnly = True
     
243.             '// Data rows
     
244.             .Font = New Font("Tahoma", 10)
     
245.             .RowTemplate.MinimumHeight = 27
     
246.             .RowTemplate.Height = 27
     
247.             '// Autosize Column
     
248.             .AutoSizeColumnsMode = DataGridViewAutoSizeColumnsMode.Fill
     
249.             '// Header
     
250.             With .ColumnHeadersDefaultCellStyle
     
251.                 .BackColor = Color.RoyalBlue
     
252.                 .ForeColor = Color.White
     
253.                 .Font = New Font(.Font, FontStyle.Bold)
     
254.             End With
     
255.             .ColumnHeadersHeightSizeMode = DataGridViewColumnHeadersHeightSizeMode.DisableResizing
     
256.             .ColumnHeadersHeight = 36
     
257.             '/ Accept changes to the header's background color.
     
258.             .EnableHeadersVisualStyles = False
     
259.             '// Even-Odd Color of Rows.
     
260.             .AlternatingRowsDefaultCellStyle.BackColor = Color.Beige
     
261.             '// Even-Odd Color of Columns.
     
262.             For iCol As Integer = 0 To .Columns.Count - 1
     
263.                 '// If any integer Mod by 2 and gets the answer is 0 so even number, 1 is an odd number.
     
264.                 If iCol Mod 2 = 1 Then
     
265.                     .Columns(iCol).HeaderCell.Style.BackColor = Color.DarkBlue
     
266.                 Else
     
267.                     .Columns(iCol).HeaderCell.Style.BackColor = Color.SeaGreen
     
268.                 End If
     
269.             Next
     
270.         End With
     
271.     End Sub
     
272. #End Region
     
273. 
     
274. End Class

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดต้นฉบับ VB.NET (2010) ได้ที่นี่ ...