[VB.NET] การทำให้เซลล์ของตารางกริดรับค่าตัวเลขจำนวนเต็ม หรือจำนวนเลขทศนิยมได้เฉพาะหลักที่ต้องการ

thongkorn · โพสต์ 2017-10-27 02:13:31

ในแต่ละเซลล์ของตารางกริด (DataGridView) มันมีคุณสมบัติเป็นเหมือนกับ TextBox นั่นคือเราจะคีย์ค่าอะไรลงไปก็ได้ ... ทีนี้จากภาพประกอบด้านบน สมมุติว่าหลัก 0 (Primary Key) และหลัก 2 (นับค่า Column Index นะครับ) เป็น Number จะต้องป้อนเลขจำนวนเต็มเท่านั้น หรือหลัก 3 Double Field สามารถป้อนเลขแบบจำนวนทศนิยมได้เท่านั้นจะทำอย่างไร??? ... ที่ต้องมีการล็อคค่าการกดคีย์ หรือ Validate Cell ก็เพราะเราจะต้องนำค่าที่อยู่ในเซลล์นั้นๆไปทำการคำนวณ หรือ บันทึกลงฐานข้อมูล หากป้อนค่าอินพุทผิด ไม่ตรงตามชนิดข้อมูลที่ต้องการ มันก็จะทำให้เกิดเอ้อเหรอ (Error) ได้นั่นเอง ดังนั้นเราจึงต้องป้องกันเอาไว้ก่อนยังไงล่ะครับทั่นผู้ชม ...

ปัญหาสำหรับการป้อนตัวเลขจำนวนเต็มลงไปในเซลล์ของตารางกริด ก็คือ จะต้องล็อคไม่ให้กดค่าตัวอักษร หรืออักษรพิเศษลงไปได้ หากแก้ปัญหาข้อนี้ผ่าน ก็ไปต่อหลักที่ 3 ได้ แต่ทว่าการป้อนข้อมูลในหลักที่ 3 นี้ จะต้องสามารถคีย์เครื่องหมายจุดทศนิยมลงไปได้ แต่จะต้องใส่ได้เพียงจุดเดียวเท่านั้น ...

' / --------------------------------------------------------------------------------
Private Sub dgvData_EditingControlShowing(sender As Object, e As System.Windows.Forms.DataGridViewEditingControlShowingEventArgs) Handles dgvData.EditingControlShowing
Select Case dgvData.Columns(dgvData.CurrentCell.ColumnIndex).Index
'// ColumeIndex 0, 2 is Integer and ColumnIndex 3 is double.
Case 0, 2, 3
'// Force to validate value at ValidKeyPress Event.
RemoveHandler e.Control.KeyPress, AddressOf ValidKeyPress
AddHandler e.Control.KeyPress, AddressOf ValidKeyPress
End Select
End Sub

คัดลอกไปที่คลิปบอร์ด

เราจะทำการตรวจสอบก่อนว่ามันอยู่ในหลักที่เราต้องการหรือไม่ ในที่นี้คือหลัก 0, 2 และ 3 ดังนั้นในการกดคีย์แต่ละครั้ง เราจะบังคับให้มันไปเช็คก่อนว่าจะรับคีย์หรือไม่ โดยสั่งไปที่เหตุการณ์ ValidKeyPress

' / --------------------------------------------------------------------------------
Private Sub ValidKeyPress(sender As System.Object, e As System.Windows.Forms.KeyPressEventArgs)
Dim tb As TextBox = sender
Select Case dgvData.CurrentCell.ColumnIndex
Case 0, 2 '// Integer
Select Case e.KeyChar
Case "0" To "9" ' digits 0 - 9 allowed
Case ChrW(Keys.Back) ' backspace allowed for deleting (Delete key automatically overrides)
Case Else ' everything else ....
'// True = CPU cancel the KeyPress event
e.Handled = True '// and it's just like you never pressed a key at all
End Select
Case 3 '// Double
Select Case e.KeyChar
Case "0" To "9"
'// Allowed "."
Case "."
'// But it can present "." only one.
If InStr(tb.Text, ".") Then e.Handled = True
Case ChrW(Keys.Back)
Case Else
e.Handled = True
End Select
End Select
End Sub

คัดลอกไปที่คลิปบอร์ด

ในหลัก 0 และ 2 จะเป็นการดักเฉพาะค่าตัวเลขเท่านั้น ส่วนหลัก 3 นอกจากจะรับค่าเฉพาะตัวเลขเท่านั้น จะต้องมีการตรวจสอบการกดคีย์เครื่องหมายจุดซ้ำอีกหรือไม่

มาดูโค้ดฉบับเต็ม ...

' / --------------------------------------------------------------------------------
' / Developer : Mr.Surapon Yodsanga (Thongkorn Tubtimkrob)
' / eMail : thongkorn@hotmail.com
' / URL: http://www.g2gnet.com (Khon Kaen - Thailand)
' / Facebook: http://www.facebook.com/g2gnet (for Thailand)
' / Facebook: http://www.facebook.com/commonindy (Worldwide)
' / Purpose: Validating keypress each cells DataGridView Control.
' / Microsoft Visual Basic .NET (2010)
' /
' / This is open source code under @Copyleft by Thongkorn Tubtimkrob.
' / You can modify and/or distribute without to inform the developer.
' / --------------------------------------------------------------------------------
Public Class frmDataGridValidCell
Private Sub frmDataGridValidCell_Load(sender As Object, e As System.EventArgs) Handles Me.Load
Call InitializeGrid()
Call FillData()
End Sub
' / --------------------------------------------------------------------------------
Private Sub FillData()
Dim dt As New DataTable
dt.Columns.Add("Primary Key", GetType(Integer))
dt.Columns.Add("ID")
dt.Columns.Add("Number Field", GetType(Integer))
dt.Columns.Add("Double Field", GetType(Double))
'//
Dim RandomClass As New Random()
For i As Long = 0 To 5
Dim dr As DataRow = dt.NewRow()
dr(0) = i + 1
dr(1) = "ID" & i + 1
dr(2) = RandomClass.Next(1, 99999)
dr(3) = FormatNumber(RandomClass.Next(100, 1000) + RandomClass.NextDouble(), 2)
dt.Rows.Add(dr)
Next
dgvData.DataSource = dt
End Sub
' / --------------------------------------------------------------------------------
' / Initialized settings for DataGridView @Run Time.
' / --------------------------------------------------------------------------------
Private Sub InitializeGrid()
With dgvData
.RowHeadersVisible = False
.AllowUserToAddRows = False
.AllowUserToDeleteRows = False
.AllowUserToResizeRows = False
.MultiSelect = False
'// Need to modify each cell.
.SelectionMode = DataGridViewSelectionMode.CellSelect
.ReadOnly = False
'//
.Font = New Font("Tahoma", 8)
' Automatically set the width.
.AutoSizeColumnsMode = DataGridViewAutoSizeColumnsMode.Fill
.AutoResizeColumns()
' Adjust Header Styles
With .ColumnHeadersDefaultCellStyle
.BackColor = Color.Navy
.ForeColor = Color.White
.Font = New Font("Tahoma", 8)
End With
End With
End Sub
' / --------------------------------------------------------------------------------
Private Sub dgvData_EditingControlShowing(sender As Object, e As System.Windows.Forms.DataGridViewEditingControlShowingEventArgs) Handles dgvData.EditingControlShowing
Select Case dgvData.Columns(dgvData.CurrentCell.ColumnIndex).Index
'// ColumeIndex 0, 2 is Integer and ColumnIndex 3 is double.
Case 0, 2, 3
'// Force to validate value at ValidKeyPress Event.
RemoveHandler e.Control.KeyPress, AddressOf ValidKeyPress
AddHandler e.Control.KeyPress, AddressOf ValidKeyPress
End Select
End Sub
' / --------------------------------------------------------------------------------
Private Sub ValidKeyPress(sender As System.Object, e As System.Windows.Forms.KeyPressEventArgs)
Dim tb As TextBox = sender
Select Case dgvData.CurrentCell.ColumnIndex
Case 0, 2 '// Integer
Select Case e.KeyChar
Case "0" To "9" ' digits 0 - 9 allowed
Case ChrW(Keys.Back) ' backspace allowed for deleting (Delete key automatically overrides)
Case Else ' everything else ....
'// True = CPU cancel the KeyPress event
e.Handled = True '// and it's just like you never pressed a key at all
End Select
Case 3 '// Double
Select Case e.KeyChar
Case "0" To "9"
'// Allowed "."
Case "."
'// But it can present "." only one.
If InStr(tb.Text, ".") Then e.Handled = True
Case ChrW(Keys.Back)
Case Else
e.Handled = True
End Select
End Select
End Sub
Private Sub frmDataGridValidCell_FormClosed(sender As Object, e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
Me.Dispose()
Application.Exit()
End Sub
End Class

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดต้นฉบับ VB.NET (2010) ได้ที่นี่

hot2 · โพสต์ 2018-10-14 19:28:48

ขอบคุณครับเฮียกำลังมึนๆได้ที่อยู่พอดี

gp1619 · โพสต์ 2019-7-11 16:57:10

ทำไม คลิกเมาส์ขวา แล้ว Paste ได้ แต่กด ctrl+v ไม่ได้ครับ
รบกวนด้วยครับอาจารย์

thongkorn · โพสต์ 2019-7-17 13:50:32

gp1619 ตอบกลับเมื่อ 2019-7-11 16:57
ทำไม คลิกเมาส์ขวา แล้ว Paste ได้ แต่กด ctrl+v ไม่ได้ครับ
รบกวนด้วยครับอาจารย์

มันเป็นขีดจำกัดของ DataGridView ของไมโครซอฟท์ครับ (ดูคีย์บอร์ดชอร์ทคัทที่สามารถใช้งานกับตารางกริดได้ที่นี่) ที่ไมโครซอฟท์ไม่ได้ทำ Control หรือ Component ต่างๆออกมาให้ดียอดเยี่ยมไปเลย ก็เพราะต้องการลดต้นทุนตัวเอง และเปิดโอกาสให้ค่ายอื่นๆที่เราเรียกว่า Third Party ได้เข้ามามีส่วนร่วมแทน สำหรับกรณี DataGridView ของไมโครซอฟท์ เราพัฒนามันไปต่อได้ยากและเสียเวลามาก แม้ว่าจะสามารถทำให้มันใช้ Ctrl+C, X หรือ V ได้ก็ตามทีเหอะ เพราะค่าในคลิปบอร์ดเราต้องนำมาเช็คตลอดว่า เวลาจะนำไปไว้ใช้ตามเซลล์ต่างๆนั้น มันมีชนิดข้อมูลเป็นแบบไหนกันแน่ ผมแนะนำให้ไปใช้ของฟรีอย่าง Syncfusion แทนครับ (ตรวจสอบการป้อนค่าในแต่ละเซลล์ GridGroupingControl ของฟรีจากค่าย Syncfusion)

โค้ดตัวอย่างที่ยังไม่เสร็จสมบูรณ์ในการใช้ ShortCut Key บนตัวตารางกริด ...

Private Sub dgvData_CellClick(sender As Object, e As System.Windows.Forms.DataGridViewCellEventArgs) Handles dgvData.CellClick
GetCol = e.ColumnIndex
End Sub

คัดลอกไปที่คลิปบอร์ด

'/ Declare Public Variable in this form.
Dim GetCol As Integer
Dim StrTemp As String = String.Empty
'// Form Events KeyDown
Private Sub HandleKeyDown(ByVal sender As Object, ByVal e As KeyEventArgs) Handles MyBase.KeyDown
'// Use for Ctrl + X
If Not IsDBNull(dgvData.CurrentRow.Cells(GetCol).Value) Then
StrTemp = dgvData.CurrentRow.Cells(GetCol).Value
End If
'// Ctrl + C (Copy)
If e.KeyCode = Keys.C AndAlso e.Modifiers = Keys.Control Then
Clipboard.SetText(dgvData.CurrentRow.Cells(GetCol).Value)
'// Ctrl + V (Paste)
ElseIf e.KeyCode = Keys.V AndAlso e.Modifiers = Keys.Control Then
'/ ก่อนวางแปะ ต้องเช็คค่าว่าเป็นเลขจำนวนเต็ม หรือมีจุดทศนิยมในหลักนั้นๆก่อนด้วย
'/ Get the data stored in the clipboard
Dim iData As IDataObject = Clipboard.GetDataObject()
'/ Check to see if the data is in a text format
If iData.GetDataPresent(DataFormats.Text) Then
dgvData.CurrentRow.Cells(GetCol).Value = CType(iData.GetData(DataFormats.Text), String)
SendKeys.Send("{ENTER}")
End If
'// Ctrl + X (Cut)
ElseIf e.KeyCode = Keys.X AndAlso e.Modifiers = Keys.Control Then
'/ ก่อนตัด ต้องเช็คก่อนว่าหลักนั้นเป็น String หรือไม่ หากใช่ให้ใส่ค่าว่างแทน
If Not IsNothing(StrTemp) Then
Clipboard.SetText(dgvData.CurrentRow.Cells(GetCol).Value)
dgvData.CurrentRow.Cells(GetCol).Value = 0
SendKeys.Send("{ENTER}")
Else
dgvData.CurrentRow.Cells(GetCol).Value = 0
SendKeys.Send("{ENTER}")
End If
End If
End Sub

คัดลอกไปที่คลิปบอร์ด

		จำสถานะนี้ไว้ในครั้งหน้า	ลืมรหัสผ่าน
รหัสผ่าน			ลงทะเบียน

[VB.NET] การทำให้เซลล์ของตารางกริดรับค่าตัวเลขจำนวนเต็ม หรือจำนวนเลขทศนิยมได้เฉพาะหลักที่ต้องการ

ขออภัย! โพสต์นี้มีไฟล์แนบหรือรูปภาพที่ไม่ได้รับอนุญาตให้คุณเข้าถึง