[VB6] โค้ดการทำ RibbonBar และ ToolBar ด้วย Codejock Xtreme Suite Pro

thongkorn

โค้ดการทำ RibbonBar และ ToolBar ด้วย Codejock Xtreme Suite Pro ... ซึ่งจะต้องใช้การเขียนด้วยโค้ด Visual Basic 6 ล้วนๆ ...



การเลือก Components เข้ามาใช้งาน ซึ่งจะต้องทำการดาวน์โหลด Xtreme Suite Pro มาทำการติดตั้งเข้าไปก่อน
ดาวน์โหลด Codejock Xtreme Suite Pro ได้ที่นี่ ... (เฉพาะสมาชิกเท่านั้น)


หน้าจอ Design ของ VB6 ซึ่งจะต้องจับลาก Components มาวางไว้บนฟอร์ม ...



ไอคอนที่จะต้องใช้ในการทำ RibbonBar ซึ่งจะต้องมีการวางไอคอนขนาด 32 x 32 Pixel ในทุกๆตัว และจะต้องเกิดการจัดเรียงตามลำดับให้สัมพันธ์กับโค้ดด้วย ...



ไอคอนที่ใช้ในการทำ ToolBar มีขนาด 32 x 32 Pixel



ในโค้ดตัวอย่างแอดมินแนบไฟล์ต้นฉบับ Photoshop (PSD) ทั้ง RibbonBar และ ToolBar ติดมาให้ด้วย


*** ขอย้ำว่าให้ศึกษาจากโค้ดให้ละเอียด เพราะการเขียนโค้ดจะมีความสัมพันธ์กันกับไอคอน หากเกิดความผิดพลาด ไอคอนจะไม่แสดงผลออกมา ***


มาดูโค้ดฉบับเต็มใน MDI Form หรือฟอร์มหลัก (frmMain.frm) กันเถอะ ...

1. '// --------------------------------------------------------------------------------------
   
2. '// Developer : Mr.Surapon Yodsanga (Thongkorn Tubtimkrob)
   
3. '// eMail : thongkorn@hotmail.com
   
4. '// URL: http://www.g2gnet.com (Khon Kaen - Thailand)
   
5. '// Facebook: https://www.facebook.com/g2gnet (For Thailand)
   
6. '// Facebook: https://www.facebook.com/commonindy (Worldwide)
   
7. '// More Info: http://www.g2gnet.com/webboard
   
8. ' /
   
9. '// Purpose: Create RibbonBar & ToolBar with Codejock Xtreme Suite Pro
   
10. '// Microsoft Visual Basic 6 (VB6)
    
11. ' /
    
12. '// This is open Source code under @Copyleft by Thongkorn Tubtimkrob.
    
13. '// You can modify and/or distribute without to inform the developer.
    
14. '// --------------------------------------------------------------------------------------
    
15. 
    
16. Option Explicit
    
17. 
    
18. ' ฟอนต์
    
19. Dim chkFont As Integer
    
20. 
    
21. Dim WithEvents StatusBar As XtremeCommandBars.StatusBar
    
22. Dim END_APP As Boolean  ' ใช้เป็นเงื่อนไขในการปิดโปรแกรม
    
23. Const AppName As String = "Codejock RibbonBar Sample"
    
24. 
    
25. Private Declare Function InitCommonControls Lib "Comctl32.dll" () As Long
    
26. 
    
27. ' About Program
    
28. Sub AboutProgram()
    
29.     Dim MoreInfo As String
    
30.     MoreInfo = "[พัฒนาโดยนายสุรพล ยอดสง่า - http://www.g2gnet.com]"
    
31.     Call ShellAbout(Me.hWnd, AppName, MoreInfo, Me.Icon)
    
32. End Sub
    
33. 
    
34. ' ตั้งค่า RibbonBar
    
35. Public Function RibbonBar() As XtremeCommandBars.RibbonBar
    
36.     Set RibbonBar = CommandBars.ActiveMenuBar
    
37. End Function
    
38. 
    
39. Private Sub MDIForm_Activate()
    
40.     Me.Caption = "Codejock RibbonBar Sample"
    
41.     On Error Resume Next
    
42. 
    
43.     ' Status Bar
    
44.     Set StatusBar = CommandBars.StatusBar
    
45.     StatusBar.Visible = True
    
46.     StatusBar.Font.Size = 10
    
47.     If StatusBar.Panes.Count = 0 Then
    
48.         StatusBar.AddPane 0
    
49.         StatusBar.AddPane ID_INDICATOR_CAPS
    
50.         StatusBar.AddPane ID_INDICATOR_NUM
    
51.         StatusBar.AddPane ID_INDICATOR_SCRL
    
52.     End If
    
53.     StatusBar.IdleText = "Developer : Mr.Surapon Yodsanga - [http://www.facebook.com/g2gnet]"
    
54. End Sub
    
55. 
    
56. Private Sub MDIForm_Initialize()
    
57.     Call InitCommonControls
    
58. End Sub
    
59. 
    
60. Private Sub MDIForm_Resize()
    
61.     On Error Resume Next
    
62.     If Me.WindowState = vbMaximized Then Exit Sub
    
63.     If Me.Width < 13000 Then Me.Width = 13000
    
64.     If Me.Height < 10000 Then Me.Height = 10000
    
65. End Sub
    
66. 
    
67. Private Sub MDIForm_Unload(Cancel As Integer)
    
68.     End
    
69. End Sub
    
70. 
    
71. Private Sub MDIForm_Load()
    
72.     ' ป้องกันการรันโปรแกรมซ้ำ
    
73.     If App.PrevInstance Then End
    
74.     ' ปรับ Skin ซึ่งไฟล์ INI (Initialize) อยู่ที่โฟลเดอร์ Styles
    
75.     'SkinFramework.LoadSkin App.Path + "\Styles\Office2007.cjstyles", "NORMALBLUE.ini"
    
76.     'SkinFramework.LoadSkin App.Path + "\Styles\Vista.cjstyles", "NORMALBLACK.INI"
    
77.     'SkinFramework.LoadSkin App.Path + "Styles\WinXP.Royale.cjstyles", ""
    
78.     SkinFramework.LoadSkin App.Path & "\Styles\Vista.cjstyles", "NORMALBLUE.INI"
    
79.     SkinFramework.ApplyWindow Me.hWnd
    
80.    
    
81.     CommandBarsGlobalSettings.App = App
    
82.     Me.SkinFramework.AutoApplyNewWindows = True
    
83.     ' ปรับหอร์มให้อยู่กึ่งกลางหน้าจอ
    
84.     Me.Move (Screen.Width - Width) \ 2, (Screen.Height - Height) \ 2
    
85.     ' โหลดภาพไอคอน
    
86.     Call LoadIcons
    
87.     ' สร้าง RibbonBar
    
88.     Call CreateRibbonBar
    
89.    
    
90.     ' อ่านค่าจาก Registry
    
91.     chkFont = CLng(GetSettingReg("SOFTWARE\CodejockRibbonBar\Setting", "FontSize", "2"))
    
92.    
    
93.     RibbonBar.EnableFrameTheme
    
94.     RibbonBar.RecalcLayout
    
95.     CommandBars.Options.KeyboardCuesShow = xtpKeyboardCuesShowWindowsDefault
    
96.     CommandBars.EnableCustomization False
    
97.    
    
98.     Me.Show
    
99.     If END_APP Then Unload Me
    
100. End Sub
     
101. 
     
102. ' การโหลดไอคอนเข้าสู่ RibbonBar
     
103. Private Sub LoadIcons()
     
104.     CommandBars.Options.UseSharedImageList = False
     
105. 
     
106.     ' การจัดเรียงไอคอนภาพกราฟิค (MainMenu.png) จะต้องให้ถูกต้อง หากขาดหรือเกิน ก็จะไม่แสดงผลภาพไอคอนออกมา
     
107.     ' ไอคอนกราฟิค จะมีความสัมพันธ์กับค่าคงที่ ต้องระมัดระวังอย่างมาก
     
108.     CommandBars.Icons.LoadBitmap App.Path & "\Icons\MainMenu.png", Array( _
     
109.             ID_FILE_EMPLOYEE, ID_FILE_COURSE, ID_FILE_CLASS, ID_FILE_ASSIGN, ID_FILE_TRAINER, _
     
110.             ID_SETUP_COMPACT, ID_SETUP_BACKUP, ID_SETUP_LOCATEDB, _
     
111.             ID_APP_LOGOUT, ID_APP_EXIT, _
     
112.             ID_SETUP_INIT, ID_SETUP_PASSWORD, ID_SETUP_LOCATEDB, ID_SETUP_COMPACT, ID_SETUP_BACKUP, _
     
113.             ID_PROGRAM_HELP, ID_PROGRAM_ABOUT, ID_PROGRAM_REGISTER), _
     
114.             XtremeCommandBars.XTPImageState.xtpImageNormal
     
115. 
     
116.     ' ไอคอนนี้จะอยู่บนมุมซ้ายของฟอร์ม
     
117.     CommandBars.Icons.LoadBitmap App.Path & "\Icons\Manager.png", ID_SYSTEM_ICON, XtremeCommandBars.XTPImageState.xtpImageNormal
     
118. 
     
119.     Dim ToolTipContext As ToolTipContext
     
120.     Set ToolTipContext = CommandBars.ToolTipContext
     
121.     ToolTipContext.Style = xtpToolTipOffice2007
     
122.     ToolTipContext.ShowTitleAndDescription True, xtpToolTipIconNone
     
123.     ToolTipContext.SetMargin 2, 2, 2, 2
     
124.     ToolTipContext.MaxTipWidth = 180
     
125.     ToolTipContext.ShowShadow = True
     
126. End Sub
     
127. 
     
128. ' สร้าง RibbonBar
     
129. Private Sub CreateRibbonBar()
     
130.     Dim TabMain As RibbonTab
     
131.     Dim TabSetup As RibbonTab
     
132.     Dim TabProgram As RibbonTab
     
133. 
     
134.     Dim GroupMain As RibbonGroup
     
135.     Dim GroupUtilities As RibbonGroup
     
136.     Dim GroupFont As RibbonGroup
     
137.     Dim GroupWindow As RibbonGroup
     
138.     Dim GroupSetup As RibbonGroup
     
139.     Dim GroupTools As RibbonGroup
     
140.     Dim GroupProgram As RibbonGroup
     
141. 
     
142.     Dim ControlFile As CommandBarPopup
     
143.     Dim RibbonBar As XtremeCommandBars.RibbonBar
     
144. 
     
145.     ' สร้าง RibbonBar
     
146.     Set RibbonBar = CommandBars.AddRibbonBar("The Ribbon")
     
147.     RibbonBar.EnableDocking xtpFlagStretched
     
148. 
     
149.     ' ปุ่ม System (มุมซ้ายบน)
     
150.     Set ControlFile = RibbonBar.AddSystemButton()
     
151.     ControlFile.IconId = ID_SYSTEM_ICON
     
152.     ControlFile.CommandBar.Controls.Add xtpControlButton, ID_APP_LOGOUT, "ออกจากระบบ"
     
153.     ControlFile.CommandBar.Controls.Add xtpControlButton, ID_APP_EXIT, "จบการทำงาน"
     
154.     ControlFile.CommandBar.SetIconSize 32, 32
     
155. 
     
156.     ' Tab: Main Menu
     
157.     Set TabMain = RibbonBar.InsertTab(0, "Main Menu")
     
158.     TabMain.Id = ID_TAB_MAIN
     
159. 
     
160.     Set GroupMain = TabMain.Groups.AddGroup("Main Job", ID_GROUP_MAIN)
     
161.     GroupMain.Add xtpControlButton, ID_FILE_EMPLOYEE, "Employee Data"
     
162.     GroupMain.Add xtpControlButton, ID_FILE_COURSE, "Course Categories"
     
163.     GroupMain.Add xtpControlButton, ID_FILE_CLASS, "Class Session"
     
164.     GroupMain.Add xtpControlButton, ID_FILE_ASSIGN, "Assignment"
     
165.     GroupMain.Add xtpControlButton, ID_FILE_TRAINER, "Trainer"
     
166. 
     
167.     Set GroupUtilities = TabMain.Groups.AddGroup("Utilities", ID_GROUP_UTILITIES)
     
168.     GroupUtilities.Add xtpControlButton, ID_SETUP_COMPACT, "Maintenance Data"
     
169.     GroupUtilities.Add xtpControlButton, ID_SETUP_BACKUP, "Backup Data"
     
170.     GroupUtilities.Add xtpControlButton, ID_SETUP_LOCATEDB, "Database Location"
     
171. 
     
172.     Set GroupFont = TabMain.Groups.AddGroup("Font Size", ID_GROUP_FONT)
     
173.     GroupFont.Add xtpControlCheckBox, ID_FONT_STANDARD, "Standard"
     
174.     GroupFont.Add xtpControlCheckBox, ID_FONT_MEDIUM, "Middle"
     
175.     GroupFont.Add xtpControlCheckBox, ID_FONT_LARGE, "Large"
     
176. 
     
177.     Set GroupWindow = TabMain.Groups.AddGroup("Operation", ID_GROUP_FILEEXIT)
     
178.     GroupWindow.Add xtpControlButton, ID_APP_LOGOUT, "User Logout"
     
179.     GroupWindow.Add xtpControlButton, ID_APP_EXIT, "Exit Program"
     
180. 
     
181.     ' Tab: Setup
     
182.     Set TabSetup = RibbonBar.InsertTab(2, "Setup")
     
183.     TabSetup.Id = ID_TAB_SETUP
     
184. 
     
185.     Set GroupSetup = TabSetup.Groups.AddGroup("Setup", ID_GROUP_SETUP)
     
186.     GroupSetup.Add xtpControlButton, ID_SETUP_INIT, "ตั้งค่าเริ่มต้น"
     
187.     GroupSetup.Add xtpControlButton, ID_SETUP_PASSWORD, "เปลี่ยนรหัสผ่าน"
     
188. 
     
189.     Set GroupTools = TabSetup.Groups.AddGroup("Database", ID_GROUP_TOOLS)
     
190.     GroupTools.Add xtpControlButton, ID_SETUP_LOCATEDB, "ตำแหน่งฐานข้อมูล"
     
191.     GroupTools.Add xtpControlButton, ID_SETUP_COMPACT, "ซ่อมบำรุงข้อมูล"
     
192.     GroupTools.Add xtpControlButton, ID_SETUP_BACKUP, "สำรองข้อมูล"
     
193. 
     
194.     ' Tab: About Program
     
195.     Set TabProgram = RibbonBar.InsertTab(3, "About Program")
     
196.     TabProgram.Id = ID_TAB_PROGRAM
     
197. 
     
198.     Set GroupProgram = TabProgram.Groups.AddGroup("About", ID_GROUP_PROGRAM)
     
199.     GroupProgram.Add xtpControlButton, ID_PROGRAM_HELP, "ระบบช่วยเหลือ"
     
200.     GroupProgram.Add xtpControlButton, ID_PROGRAM_ABOUT, "เกี่ยวกับโปรแกรม"
     
201.     GroupProgram.Add xtpControlButton, ID_PROGRAM_REGISTER, "ลงทะเบียนโปรแกรม"
     
202. 
     
203.     RibbonBar.ControlQuickAccess.Visible = False
     
204.     RibbonBar.ShowQuickAccess = False
     
205. End Sub
     
206. 
     
207. ' อัปเดตสถานะ Font Size ทุกๆครั้งที่มีการคลิ๊ก CheckBox Control
     
208. Private Sub CommandBars_Update(ByVal Control As XtremeCommandBars.ICommandBarControl)
     
209.     On Error Resume Next
     
210.     Select Case Control.Id
     
211.         Case ID_FONT_STANDARD
     
212.             If chkFont = 1 Then
     
213.                 RibbonBar.FontHeight = 13
     
214.                 Control.Checked = True
     
215.                 SaveSettingReg "SOFTWARE\CodejockRibbonBar\Setting", "FontSize", CStr(chkFont)
     
216.             Else
     
217.                 Control.Checked = False
     
218.             End If
     
219. 
     
220.         Case ID_FONT_MEDIUM
     
221.             If chkFont = 2 Then
     
222.                 RibbonBar.FontHeight = 15
     
223.                 Control.Checked = True
     
224.                 SaveSettingReg "SOFTWARE\CodejockRibbonBar\Setting", "FontSize", CStr(chkFont)
     
225.             Else
     
226.                 Control.Checked = False
     
227.             End If
     
228. 
     
229.         Case ID_FONT_LARGE
     
230.             If chkFont = 3 Then
     
231.                 RibbonBar.FontHeight = 16
     
232.                 Control.Checked = True
     
233.                 SaveSettingReg "SOFTWARE\CodejockRibbonBar\Setting", "FontSize", CStr(chkFont)
     
234.             Else
     
235.                 Control.Checked = False
     
236.             End If
     
237.     End Select
     
238. End Sub
     
239. 
     
240. ' เหตุการณ์ Execute เมื่อกดปุ่มบน CommandBars เพื่อสั่งให้ไปทำอะไร
     
241. Private Sub CommandBars_Execute(ByVal Control As XtremeCommandBars.ICommandBarControl)
     
242.     On Error Resume Next
     
243.     Select Case Control.Id
     
244.         Case ID_FONT_STANDARD
     
245.             chkFont = 1
     
246.             RibbonBar.FontHeight = 13
     
247.             ' Save Registry (modRegistry.bas) บันทึกค่าของฟอนต์
     
248.             SaveSettingReg "SOFTWARE\CodejockRibbonBar\Setting", "FontSize", CStr(chkFont)
     
249. 
     
250.         Case ID_FONT_MEDIUM
     
251.             chkFont = 2
     
252.             RibbonBar.FontHeight = 15
     
253.             SaveSettingReg "SOFTWARE\CodejockRibbonBar\Setting", "FontSize", CStr(chkFont)
     
254. 
     
255.         Case ID_FONT_LARGE
     
256.             chkFont = 3
     
257.             RibbonBar.FontHeight = 16
     
258.             SaveSettingReg "SOFTWARE\CodejockRibbonBar\Setting", "FontSize", CStr(chkFont)
     
259. 
     
260.         ' ตัวอย่างการเปิดฟอร์ม
     
261.         Case ID_FILE_EMPLOYEE
     
262.             'MsgBox "คุณเลือกเปิดฟอร์มข้อมูลรายชื่อพนักงาน"
     
263.             If FormLoaded("frmEmployeeMain") = True Then
     
264.                 frmEmployeeMain.ZOrder 0
     
265.             Else
     
266.                 frmEmployeeMain.Show
     
267.             End If
     
268. 
     
269.         Case ID_FILE_COURSE
     
270.             'MsgBox "คุณเลือกเปิดฟอร์มการฝึกอบรมพนักงาน"
     
271.             If FormLoaded("frmCourseMain") = True Then
     
272.                 frmCourseMain.ZOrder 0
     
273.             Else
     
274.                 frmCourseMain.Show
     
275.             End If
     
276. 
     
277.         Case ID_FILE_CLASS
     
278.             MsgBox "คุณเลือกเปิดฟอร์มจัดคลาสการฝึกอบรม"
     
279.         
     
280.         Case ID_FILE_ASSIGN
     
281.             MsgBox "คุณเลือกเปิดฟอร์ม Assignment การฝึกอบรมพนักงาน"
     
282.             
     
283.         Case ID_PROGRAM_REGISTER
     
284.             MsgBox "คุณเลือกเปิดฟอร์มลงทะเบียนโปรแกรม"
     
285.         
     
286.         Case ID_PROGRAM_ABOUT
     
287.             Call AboutProgram
     
288.         
     
289.         Case ID_SETUP_COMPACT
     
290.             MsgBox "คุณเลือกเปิดฟอร์มในการ Maintenance DataBase"
     
291.         
     
292.         Case ID_APP_LOGOUT
     
293.             MsgBox "คุณเลือกการ Logout ออกจากระบบ"
     
294. 
     
295.         Case ID_APP_EXIT
     
296.             Unload Me
     
297.     End Select
     
298. End Sub
     
299. 
     
300. Private Sub MDIForm_QueryUnload(Cancel As Integer, UnloadMode As Integer)
     
301.     On Error Resume Next
     
302.     If END_APP = True Then Exit Sub
     
303.     Dim Msg As String, Response%
     
304.     Msg = "คุณแน่ใจว่าต้องการจบการทำงานของโปรแกรม ?"
     
305.     Response = MsgBox(Msg, vbQuestion + vbOKCancel + vbDefaultButton2, "ยืนยันการจบรายการ")
     
306.     Select Case Response
     
307.         Case vbCancel
     
308.             Cancel = -1
     
309.         Case vbOK
     
310.             ' ลบไฟล์ขยะ *.tmp ทิ้งออกไป
     
311.             If Dir$(App.Path & "\*.tmp") <> "" Then Kill App.Path & "\*.tmp"
     
312.             End
     
313.     End Select
     
314. End Sub

คัดลอกไปที่คลิปบอร์ด

มาดูโค้ดเต็มของการเปิดฟอร์มลูก (Child Form) ของพนักงาน (frmEmployeeMain)

1. '// --------------------------------------------------------------------------------------
   
2. '// Developer : Mr.Surapon Yodsanga (Thongkorn Tubtimkrob)
   
3. '// eMail : thongkorn@hotmail.com
   
4. '// URL: http://www.g2gnet.com (Khon Kaen - Thailand)
   
5. '// Facebook: https://www.facebook.com/g2gnet (For Thailand)
   
6. '// Facebook: https://www.facebook.com/commonindy (Worldwide)
   
7. '// More Info: http://www.g2gnet.com/webboard
   
8. ' /
   
9. '// Purpose: Create RibbonBar & ToolBar with Codejock Xtreme Suite Pro
   
10. '// Microsoft Visual Basic 6 (VB6)
    
11. ' /
    
12. '// This is open Source code under @Copyleft by Thongkorn Tubtimkrob.
    
13. '// You can modify and/or distribute without to inform the developer.
    
14. '// --------------------------------------------------------------------------------------
    
15. 
    
16. Option Explicit
    
17. ' Group View สำหรับเลือกการแสดงผลรายงาน
    
18. Dim GroupView As Integer
    
19. 
    
20. Private Sub Form_Activate()
    
21.     Me.ZOrder 0
    
22.     If Me.WindowState <> vbMaximized Then Me.WindowState = 2
    
23. End Sub
    
24. 
    
25. Private Sub Form_Load()
    
26.     Me.Move 0, 0
    
27.     Me.Caption = "Employee Data"
    
28.    
    
29.     Call CreateToolBars
    
30.     GroupView = 1
    
31. End Sub
    
32. 
    
33. Sub CreateToolBars()
    
34.     Dim Control As CommandBarControl
    
35.     Dim ControlOptions As CommandBarPopup
    
36. 
    
37.     CommandBars.ActiveMenuBar.Visible = False
    
38.    
    
39.     Dim Toolbar As CommandBar
    
40.     Set Toolbar = CommandBars.Add("Standard", xtpBarTop)
    
41.     With Toolbar.Controls
    
42.         .Add xtpControlButton, ID_FILE_ADDDATA, "New"
    
43.         .Add xtpControlButton, ID_FILE_EDITDATA, "Edit"
    
44.         .Add xtpControlButton, ID_FILE_DELETEDATA, "Delete"
    
45.         .Add xtpControlButton, ID_FILE_EXPORTXLS, "Export Excel"
    
46.         
    
47.         ' การใส่ Comment หรือ ไม่มีการกำหนดค่าคงที่ นั่นคือการไม่ให้แสดงไอคอน PRINT ขึ้นมา
    
48.         '.Add xtpControlButton, ID_FILE_PRINTDATA, "Print"
    
49. 
    
50.         .Add xtpControlButton, ID_FILE_COLLAPSEDATA, "Collapse"
    
51.         .Add xtpControlButton, ID_FILE_EXPAND, "Expand"
    
52.         '
    
53.         Set Control = .Add(xtpControlSplitButtonPopup, ID_FILE_LISTDATA, "Report")
    
54.         Control.CommandBar.Controls.Add xtpControlButton, ID_FILE_LISTDATA1, "All Records"
    
55.         Control.CommandBar.Controls.Add xtpControlButton, ID_FILE_LISTDATA2, "Report Job Roles"
    
56.         Control.CommandBar.Controls.Add xtpControlButton, ID_FILE_LISTDATA3, "Report Status"
    
57.         
    
58.         .Add xtpControlButton, ID_FILE_EXITDATA, "Close"
    
59.     End With
    
60.     Toolbar.ShowTextBelowIcons = True
    
61.     ' ปิดการกดเมาส์ขวา
    
62.     Toolbar.Closeable = False
    
63.     'Change Icon Size
    
64.     Toolbar.SetIconSize 32, 32
    
65.    
    
66.     'Disable MenuBar Docking
    
67.     CommandBars.ActiveMenuBar.EnableDocking xtpFlagStretched
    
68.     ' ขยาย ToolBar ออกเต็มจอ
    
69.     Toolbar.EnableDocking xtpFlagStretched
    
70.     Dim Items()
    
71.     ' การจัดเรียงไอคอนภาพกราฟิคจะต้องให้ถูกต้อง หากขาดหรือเกิน ก็จะไม่แสดงผลภาพไอคอนออกมา
    
72.     ' ไอคอนบางตัวอาจจะไม่ได้ใช้งาน เช่น ID_FILE_PRINTDATA ก็จะไม่แสดงผลไอคอนออกมา
    
73.     Items = Array(ID_FILE_ADDDATA, ID_FILE_EDITDATA, ID_FILE_DELETEDATA, ID_FILE_SEARCHDATA, ID_FILE_REFRESHDATA, _
    
74.                             ID_FILE_PRINTDATA, ID_FILE_EXITDATA, ID_FILE_EXPORTXLS, ID_FILE_EXPORTPDF, _
    
75.                             ID_FILE_COLLAPSEDATA, ID_FILE_EXPAND, ID_FILE_LISTDATA)
    
76.             
    
77.     If (ImageManager.IsAlphaIconsSupported) Then
    
78.         ImageManager.Icons.LoadBitmap App.Path & "\Icons\SubMenu.PNG", Items, xtpImageNormal
    
79.     End If
    
80.     CommandBars.VisualTheme = xtpThemeOffice2007
    
81.    
    
82.     CommandBars.Icons = ImageManager.Icons
    
83.     CommandBars.Options.UseDisabledIcons = True
    
84.     CommandBars.Options.ShowExpandButtonAlways = False
    
85.     CommandBars.Options.SyncFloatingToolbars = False
    
86.    
    
87. End Sub
    
88. 
    
89. Private Sub CommandBars_Execute(ByVal Control As XtremeCommandBars.ICommandBarControl)
    
90.     On Error Resume Next
    
91.    
    
92.     Select Case Control.Id
    
93.         Case ID_FILE_ADDDATA:
    
94.             MsgBox "คุณเลือกเพิ่มข้อมูลรายชื่อพนักงาน"
    
95.         Case ID_FILE_EDITDATA:
    
96.             MsgBox "คุณเลือกแก้ไขข้อมูลรายชื่อพนักงาน"
    
97.         Case ID_FILE_DELETEDATA:
    
98.             MsgBox "คุณเลือกลบข้อมูลรายชื่อพนักงาน"
    
99.         Case ID_FILE_REFRESHDATA:   'Call RefreshData
    
100.         Case ID_FILE_EXPORTXLS: 'Call ExportExcel
     
101.         Case ID_FILE_COLLAPSEDATA: ' จะให้ทำอะไรก็ใส่ชุดคำสั่งใน Sub Program ไว้ที่นี้
     
102.         Case ID_FILE_EXPAND: ' จะให้ทำอะไรก็ใส่ชุดคำสั่งใน Sub Program ไว้ที่นี้
     
103.         ' ปิดหน้าจอฟอร์มลูก
     
104.         Case ID_FILE_EXITDATA:
     
105.             Set frmEmployeeMain = Nothing
     
106.             Unload Me
     
107.         
     
108.         ' กำหนดการแสดงผลข้อมูล จะส่งค่าไปที่ CommandBars_Update
     
109.         Case ID_FILE_LISTDATA1:
     
110.             GroupView = 1
     
111.         Case ID_FILE_LISTDATA2:
     
112.             GroupView = 2
     
113.         Case ID_FILE_LISTDATA3:
     
114.             GroupView = 3
     
115.     End Select
     
116. End Sub
     
117. 
     
118. Private Sub CommandBars_Update(ByVal Control As XtremeCommandBars.ICommandBarControl)
     
119.     On Error Resume Next
     
120.     ' หากเลือกตัวไหน ก็จะแสดงเครื่องหมายถูกออกมา
     
121.     Select Case Control.Id
     
122.         Case ID_FILE_LISTDATA1:
     
123.             If GroupView = 1 Then
     
124.                 Control.Checked = True
     
125.             Else
     
126.                 Control.Checked = False
     
127.             End If
     
128.         Case ID_FILE_LISTDATA2:
     
129.             If GroupView = 2 Then
     
130.                 Control.Checked = True
     
131.             Else
     
132.                 Control.Checked = False
     
133.             End If
     
134.         Case ID_FILE_LISTDATA3:
     
135.             If GroupView = 3 Then
     
136.                 Control.Checked = True
     
137.             Else
     
138.                 Control.Checked = False
     
139.             End If
     
140.     End Select
     
141. End Sub

คัดลอกไปที่คลิปบอร์ด

********** สำคัญมาก **********
การกำหนดค่าคงที่ให้กับ RibbonBar หรือ ToolBar จะต้องกำหนดค่าตัวเลขจำนวนเต็มที่ไม่ซ้ำกัน (modDefinations.bas)

1. Option Explicit
   
2. 
   
3. ' ค่าคงที่สำหรับการใช้งาน RibbonBar แนะนำให้ใช้ตั้งแต่ 1000 - 9999 ก็เหลือเฟือแล้วครับ
   
4. ' ขออย่าให้มีค่าซ้ำกันเท่านั้นพอ
   
5. 
   
6. ' --- Ribbon Tabs ---
   
7. Public Const ID_TAB_MAIN As Integer = 1300
   
8. Public Const ID_TAB_SETUP As Integer = 1301
   
9. Public Const ID_TAB_PROGRAM As Integer = 1302
   
10. 
    
11. ' --- Groups ---
    
12. Public Const ID_GROUP_MAIN As Integer = 5000
    
13. Public Const ID_GROUP_UTILITIES As Integer = 5001
    
14. Public Const ID_GROUP_FONT As Integer = 5002
    
15. Public Const ID_GROUP_FILEEXIT As Integer = 5003
    
16. Public Const ID_GROUP_SETUP As Integer = 5004
    
17. Public Const ID_GROUP_TOOLS As Integer = 5005
    
18. Public Const ID_GROUP_PROGRAM As Integer = 5006
    
19. 
    
20. ' --- Menu Items: Main Job ---
    
21. Public Const ID_FILE_EMPLOYEE As Integer = 5100
    
22. Public Const ID_FILE_COURSE As Integer = 5101
    
23. Public Const ID_FILE_CLASS As Integer = 5102
    
24. Public Const ID_FILE_ASSIGN As Integer = 5103
    
25. Public Const ID_FILE_TRAINER As Integer = 5104
    
26. 
    
27. ' --- Menu Items: Utilities ---
    
28. Public Const ID_SETUP_COMPACT As Integer = 5200
    
29. Public Const ID_SETUP_BACKUP As Integer = 5201
    
30. Public Const ID_SETUP_INIT As Integer = 5202
    
31. Public Const ID_SETUP_PASSWORD As Integer = 5203
    
32. Public Const ID_SETUP_LOCATEDB As Integer = 5204
    
33. 
    
34. ' --- Font Settings ---
    
35. Public Const ID_FONT_STANDARD As Integer = 5300
    
36. Public Const ID_FONT_MEDIUM As Integer = 5301
    
37. Public Const ID_FONT_LARGE As Integer = 5302
    
38. 
    
39. ' --- System / App ---
    
40. Public Const ID_SYSTEM_ICON As Integer = 5400
    
41. Public Const ID_APP_LOGOUT As Integer = 5401
    
42. Public Const ID_APP_EXIT As Integer = 5402
    
43. Public Const ID_PROGRAM_HELP As Integer = 5403
    
44. Public Const ID_PROGRAM_ABOUT As Integer = 5404
    
45. Public Const ID_PROGRAM_REGISTER As Integer = 5405
    
46. 
    
47. ' ============ ฟอร์มลูก =============
    
48. Public Const ID_FILE_ADDDATA As Integer = 500
    
49. Public Const ID_FILE_EDITDATA As Integer = 501
    
50. Public Const ID_FILE_DELETEDATA As Integer = 502
    
51. Public Const ID_FILE_SEARCHDATA As Integer = 503
    
52. Public Const ID_FILE_REFRESHDATA As Integer = 504
    
53. Public Const ID_FILE_PRINTDATA As Integer = 505
    
54. Public Const ID_FILE_EXITDATA As Integer = 506
    
55. Public Const ID_FILE_EXPORTXLS As Integer = 507
    
56. Public Const ID_FILE_EXPORTPDF As Integer = 508
    
57. Public Const ID_FILE_COLLAPSEDATA As Integer = 509
    
58. Public Const ID_FILE_EXPANDDATA As Integer = 510
    
59. Public Const ID_FILE_EXPAND As Integer = 511
    
60. 
    
61. ' การทำรายงานควรเปลี่ยนชื่อให้ตรงกับงาน อันนี้คือตัวอย่างครับ
    
62. Public Const ID_FILE_LISTDATA As Integer = 600
    
63. Public Const ID_FILE_LISTDATA1 As Integer = 601
    
64. Public Const ID_FILE_LISTDATA2 As Integer = 602
    
65. Public Const ID_FILE_LISTDATA3 As Integer = 603
    
66. 
    
67. ' ====================================================
    
68. ' --- StatusBar Panes ค่าคงที่ระบบจะเปลี่ยนแปลงไม่ได้ ต้องเปิดดูจากคู่มือด้วย ---
    
69. Public Const ID_INDICATOR_CAPS As Long = 59137
    
70. Public Const ID_INDICATOR_NUM As Long = 59138
    
71. Public Const ID_INDICATOR_SCRL As Long = 59139
    
72. 
    
73. ' --- Shortcut Constants ---
    
74. Public Const FCONTROL As Integer = 8
    
75. 
    
76. Public Const FSHIFT As Integer = 4
    
77. Public Const FALT As Integer = 16
    
78. ' ====================================================
    

คัดลอกไปที่คลิปบอร์ด

โค้ดฟอร์มลูก frmCourseMain ก็จะเหมือนกันกับ frmEmployeeMain ส่วนโมดูลอื่นๆให้ดาวน์โหลดไปศึกษาจากโค้ดต้นฉบับไปดูได้ ...

ดาวน์โหลดโค้ดต้นฉบับ Visual Basic 6 (VB6) ได้ที่นี่ ...