[VB6] แจกฟรีโค้ดการพิมพ์ใบแจ้งค่าใช้จ่าย แบบกระดาษครึ่ง A4 ด้วย FarPoint Spread และ ActiveReports 2.0

thongkorn

แจกไปแล้วสำหรับสาย Dot Net ฟรีโค้ด VB.NET + ActiveReports.NET การพิมพ์ใบแจ้งค่าใช้จ่าย สำหรับหอพัก ห้องเช่า อพาร์ทเมนท์ แบบกระดาษครึ่ง A4 ... ประเดี๋ยวมิตรรักแฟนคลับ VB6 จะน้อยเนื้อต่ำใจหาว่าแอดมินทอดทิ้งเมียเก่าเมียแก่อย่าง VB6 ที่อยู่ด้วยกันมาอย่างยาวนาน สิ่งที่แอดมินอยากจะกล่าวถึงก็คือ เรื่องที่หลายต่อหลายคนมักชอบผูกข้อมูล (Bound Data) จากแหล่งจ่าย (Data Source) ยึดติดเข้าไว้กับบรรดา Control ต่างๆ เช่น TexBox หรือ DataGrid แน่นอนว่ามันเป็นวิธีการที่ค่อนข้างง่ายดายมากๆ แต่ในกรณีที่ไม่มี Data Source หรือไม่ใช่บรรดาพวก Relation DataBase ล่ะจะทำอย่างไร หรือมีแต่ต้องไปติดต่อผ่าน OLEDB (อ่านว่า โอเล่ดีบี) มาก่อน ก็จะทำให้เสียเวลาอีกนั่นแหละ ...

หากเรามีแหล่งข้อมูลอะไรก็ได้ เช่น XLS, CSV, XML หรืออื่นๆ ที่สามารถโหลดข้อมูลเข้าสู่ตารางกริด เพื่อต้องการจะพิมพ์งาน หรือต้องการนำข้อมูลไปใช้ในงานอื่นๆ เช่น ทำกราฟแสดงผล มันก็จะเกิดปัญหาขึ้น เพราะเราไม่สามารถผูกโยงฟิลด์ข้อมูลเข้าหา Control ได้ ดังนั้นเราจึงจำเป็นจะต้องใช้วิธีการ Unbound Data แทน นั่นก็คือการ Loop ข้อมูลจากตารางกริดมาใช้งานแทนซิครับทั่นผู้ชม นอกจากนี้แล้วแอดมินเลยรวบรัดแถมท้าย การจัดเก็บข้อมูลขนาดเล็กเอาไว้ใน Initialized File หรือ INI มาให้ศึกษากันด้วยนะขอรับกระผม ...


ข้อมูลตัวอย่างจาก Excel โดยแอดมินจะให้ทำการโหลดเข้าสู่ตารางกริดของ FarPoint Spread จากนั้นก็ทำการพิมพ์ข้อมูลออก ActiveReports เป็นการดึงข้อมูลจากแถว แต่มาพิมพ์เป็นหลักแทน ... เอ้า เริ่มงงกันล่ะซิ ก็ต้องตามไปดูครับผม

ดาวน์โหลดชุดติดตั้ง FarPoint Spread ActiveX และ Update 8.0.21 ล่าสุดจากผู้ผลิต (เฉพาะสมาชิกเท่านั้น)

ดาวน์โหลดชุดติดตั้ง ActiveReports 2.0 (เฉพาะสมาชิกเท่านั้น)

เริ่มต้นสร้างโปรเจค ...

VB6 Designer ...


Project --> References ...


Project --> Components ...


ActiveReports Designer ...


การประยุกต์ใช้ Initialized File (INI) เพื่อจัดเก็บข้อมูลขนาดเล็ก


ข้อมูลของ INI ... ซึ่งจะประกอบไปด้วย
[Section]
Key = Value

มาดูโค้ดกันเถอะ ... เป็นฟอร์มหลัก frmPaymentRoomMain.frm

1. Option Explicit
   
2. Dim XLSFile As String
   
3. Dim fpHandle As Integer
   
4. Dim fpFileName As String
   
5. 
   
6. '//
   
7. Dim rptPrint As Object
   
8. 
   
9. Private Sub cmbWorkSheet_Click()
   
10.     Dim lRet As Long
    
11.     If Not cmbWorkSheet.ListIndex = 0 Then _
    
12.         lRet = fp.ImportExcelSheet(fpHandle, cmbWorkSheet.ListIndex - 1)
    
13.    
    
14.     '/ ปกติเราควรไปตั้งค่าจากโปรแกรมย่อยแทน
    
15.     '/ แสดงแถบแสงหรือไม่แสดง
    
16.     fp.OperationMode = OperationModeSingle    ' แถบ Selection
    
17.     'fp.OperationMode = OperationModeNormal   ' เอาไว้ป้อนข้อมูล
    
18.     'fpSpread.OperationMode = OperationModeRead     ' ไม่มีแถบ
    
19.     'fpSpread.OperationMode = OperationModeRow
    
20.     '/ ไม่แสดงชื่อหลัก
    
21.     fp.ColHeadersShow = False
    
22. End Sub
    
23. 
    
24. ' / --------------------------------------------------------------------------------
    
25. ' / เริ่มต้นการเปิดไฟล์ Excel
    
26. Private Sub cmdOpenXLS_Click()
    
27.     '/ แบบไม่สนใจ Error สั่งให้ทำงานต่อ ... แบบนี้ไม่ค่อยดีเท่าไรนักหรอกครับ
    
28.     'On Error Resume Next
    
29.     '/ อันนี้คอยดัก Trap Error
    
30.     On Error GoTo ErrorHandler   ' Enable error-handling routine.
    
31.    
    
32.     Dim List() As String
    
33.     Dim ListCount As Integer
    
34.     Dim blnXLS As Boolean
    
35.    
    
36.     ReDim List(1)
    
37.    
    
38.     With dlgOpenFile
    
39.         .FileName = "*.xls"
    
40.         .DialogTitle = "Select Excel file to open"
    
41.         .Filter = "Excel 97-2003 files (*.xls)|*.xls"
    
42.         .FilterIndex = 0
    
43.         .InitDir = App.Path
    
44.         .Flags = cdlOFNHideReadOnly
    
45.         .ShowOpen
    
46.         
    
47.         If .FileName = "*.xls" Then Exit Sub
    
48.         
    
49.         txtFileXLS.Text = .FileName
    
50.         '/ GetExcelSheetList is a method and return boolean value.
    
51.         blnXLS = fp.GetExcelSheetList(.FileName, List, ListCount, "", fpHandle, True)
    
52.     End With
    
53.    
    
54.     cmbWorkSheet.Clear
    
55.     '/ Clear Rows
    
56.     fp.MaxRows = 0
    
57.     '/
    
58.     If blnXLS Then
    
59.         '/ Open XLS File
    
60.         fp.OpenExcel2007File txtFileXLS.Text, "", -1, -1, ""
    
61.         '/
    
62.         Me.cmbWorkSheet.AddItem ("")
    
63.         Dim i As Integer
    
64.         For i = 0 To ListCount - 1
    
65.             Me.cmbWorkSheet.AddItem (List(i))
    
66.         Next
    
67.     End If
    
68.    
    
69. ExitProc:
    
70.     Exit Sub
    
71.    
    
72. ErrorHandler:   ' Error-handling routine.
    
73.     MsgBox "Error: " & Err.Number & vbCrLf & Err.Description
    
74.     Resume ExitProc
    
75. End Sub
    
76. 
    
77. ' / --------------------------------------------------------------------------------
    
78. ' / เหตุการณ์ดับเบิ้ลคลิกเมาส์ มีการระบุตำแหน่งของหลักและแถว
    
79. Private Sub fp_DblClick(ByVal Col As Long, ByVal Row As Long)
    
80. ' / --------------------------------------------------------------------------------
    
81.     ' รับค่าหลักและแถวที่ส่งมา เพื่อระบุตำแหน่งเซลล์
    
82.     fp.Col = Col:    fp.Row = Row
    
83.     If fp.Text = "" Or Len(fp.Text) = 0 Or fp.Row = 1 Then Exit Sub
    
84.     'MsgBox "คุณเลือกรายการที่หลัก " & fp.Col & " แถว " & fp.Row & vbCrLf & "ข้อมูลในเซลล์ = " & fp.Text
    
85.     '// ActiveReports Setup
    
86.     Set rptPrint = New arSlipHalfA4
    
87.     Set Me.ARViewerSlip.object = rptPrint
    
88.     ARViewerSlip.Zoom = 90
    
89. End Sub
    
90. 
    
91. Private Sub fp_KeyPress(KeyAscii As Integer)
    
92.     If KeyAscii = 13 Then Call fp_DblClick(fp.ActiveCol, fp.ActiveRow)
    
93. End Sub
    
94. 
    
95. ' / --------------------------------------------------------------------------------
    
96. Private Sub Form_Load()
    
97. ' / --------------------------------------------------------------------------------
    
98.     Me.Move (Screen.Width - Width) \ 2, (Screen.Height - Height) \ 2
    
99.     txtFileXLS.Text = ""
    
100.     cmbWorkSheet.Clear
     
101.     fp.ColHeadersShow = False
     
102. End Sub
     
103. 
     
104. Private Sub Form_Resize()
     
105.     On Error Resume Next
     
106.     '//
     
107.     fraOpenExcel.Width = Me.ScaleWidth - 30
     
108.     cmdExit.Left = fraOpenExcel.Width - cmdExit.Width - 75
     
109.     fraFP.Move 15, 1200
     
110.     fraFP.Width = Me.ScaleWidth - 30
     
111.     fraFP.Height = fp.Top - fraPrint.Top
     
112.     fp.Width = fraFP.Width - 75
     
113.     '//
     
114.     fraPrint.Width = Me.ScaleWidth - 15
     
115.     fraPrint.Height = Me.ScaleHeight - fraFP.Height - fraOpenExcel.Height
     
116.     ARViewerSlip.Move 15, 120, fraPrint.Width - 60, fraPrint.Height - 180
     
117. End Sub
     
118. 
     
119. Private Sub Form_Unload(Cancel As Integer)
     
120.     ' ลบไฟล์ Temporary ออกให้หมด
     
121.     If Dir$(App.Path & "\*.tmp") <> "" Then Kill App.Path & "\*.tmp"
     
122.     '//
     
123.     Set frmPaymentRoomMain = Nothing
     
124.     End
     
125. End Sub
     
126. 
     
127. Private Sub cmdExit_Click()
     
128.     Unload Me
     
129. End Sub
     
130. 
     
131. Private Sub mnuFileExit_Click()
     
132.     Unload Me
     
133. End Sub
     
134. 
     
135. Private Sub mnuFileSetup_Click()
     
136.     frmSetup.Show vbModal
     
137. End Sub

คัดลอกไปที่คลิปบอร์ด

โค้ดในส่วนของการพิมพ์รายงาน (arSlipHalfA4.dsr)

1. Option Explicit
   
2. Dim ItemNo As Integer
   
3. '// รับค่าแถวในการพิมพ์จากฟอร์มหลัก
   
4. Dim sRow As Integer
   
5. '//
   
6. Dim GrandTotal As Double
   
7. 
   
8. ' / --------------------------------------------------------------------------------
   
9. Private Sub ActiveReport_FetchData(EOF As Boolean)
   
10.     ItemNo = ItemNo + 1
    
11.     ' ตรวจสอบจำนวนการพิมพ์ตามหลักแล้วให้ลบออก 2 เพราะหลักแรกคือชื่อผู้เช่า หลักที่ 2 คือหมายเลขห้อง
    
12.     If ItemNo > frmPaymentRoomMain.fp.DataColCnt - 2 Then
    
13.         EOF = True
    
14.         Exit Sub
    
15.     Else
    
16.         EOF = False
    
17.     End If
    
18. End Sub
    
19. 
    
20. ' / --------------------------------------------------------------------------------
    
21. Private Sub ActiveReport_Initialize()
    
22.     '/ พิมพ์ตามแนวตั้ง
    
23.     PageSettings.Orientation = ddOPortrait
    
24.     '/ ขนาดกระดาษแบบกำหนดเอง
    
25.     PageSettings.PaperSize = 256
    
26.     PageSettings.LeftMargin = 500
    
27.     PageSettings.RightMargin = 60
    
28.     PageSettings.BottomMargin = 100
    
29.     PageSettings.TopMargin = 600
    
30.    
    
31.     '/ ขนาดปัจจุบันครึ่ง A4 (หรือ A5) มีหน่วยวัดเป็น Twip โดยที่ 1440 Twip = 1 นิ้ว หรือ 2.54 ซม.
    
32.     '/ (14.5 * 1440 / 2.54) คือการเทียบบัญญัติไตรยางค์กับหน่วยวัดเซนติเมตร
    
33.     PageSettings.PaperHeight = (14.5 * 1440 / 2.54)
    
34.     PageSettings.PaperWidth = (21 * 1440 / 2.54)
    
35.     '
    
36.     txtCname.Text = ""
    
37.     txtRoomNo.Text = ""
    
38.     txtDate.Text = ""
    
39.     txtDateMonth.Text = ""
    
40.     txtItem.Text = ""
    
41.     txtDesc.Text = ""
    
42.     txtQTY.Text = ""
    
43.     txtUnitPrice.Text = ""
    
44.     txtAmount.Text = ""
    
45.     txtGrandTotal.Text = 0
    
46.     '// รับค่าจากฟอร์มหลัก
    
47.     ' รับค่าหลักและแถวที่ส่งมา เพื่อระบุตำแหน่งเซลล์
    
48.     With frmPaymentRoomMain.fp
    
49.         .Col = .Col:    .Row = .Row
    
50.         '// เก็บค่า Select Row
    
51.         sRow = .Row
    
52.     End With
    
53.     '// อ่านค่า INI File
    
54.     Dim strFileINI As String
    
55.     strFileINI = App.Path & "\Config.ini"
    
56.     '// เช็คว่ามีไฟล์ Config.ini อยู่หรือไม่???
    
57.     '// หากไม่มีก็ตั้งค่าเริ่มต้นให้ก่อน
    
58.     If Dir(strFileINI) = "" Then
    
59.         sWriteINI strFileINI, "Config", "HeaderBill", "- ใบแจ้งค่าใช้จ่าย -"
    
60.         sWriteINI strFileINI, "Config", "Owner", "ทองก้อน อพาร์ทเมนท์ แอนด์ โฮมเพลย์สเตชั่น"
    
61.         sWriteINI strFileINI, "Config", "Address", "123/456 ถ.กลางเมือง ต.เมืองเก่า อ.เมือง จ.ขอนแก่น โทร.043-XXX-XXX"
    
62.         sWriteINI strFileINI, "Config", "Remark1", "[1] กรุณาชำระเงินภายในวันที่ 5 ของทุกเดือน"
    
63.         sWriteINI strFileINI, "Config", "Remark2", "[2] ชำระค่าปรับล่าช้าวันละ 50 บาท"
    
64.     End If
    
65.     '// อ่านค่า Config ต่างๆเข้ามา
    
66.     lblHeaderBill.Caption = sReadINI(strFileINI, "Config", "HeaderBill", "")
    
67.     txtOwner.Text = sReadINI(strFileINI, "Config", "Owner", "")
    
68.     txtAddress.Text = sReadINI(strFileINI, "Config", "Address", "")
    
69.     lblRemark1.Caption = sReadINI(strFileINI, "Config", "Remark1", "")
    
70.     lblRemark2.Caption = sReadINI(strFileINI, "Config", "Remark2", "")
    
71. End Sub
    
72. 
    
73. ' / --------------------------------------------------------------------------------
    
74. '// การวนรอบโดยนับตามจำนวนหลัก แต่แถวเป็นค่าเดิมตลอด (sRow)
    
75. Private Sub Detail_Format()
    
76.     txtItem.Text = ItemNo & "."
    
77.     With frmPaymentRoomMain
    
78.         '// อ่านแถวแรกสุด นั่นก็คือ Header เพื่อพิมพ์รายการหัวข้อ (Description)
    
79.         .fp.Col = ItemNo + 2
    
80.         .fp.Row = 1
    
81.         txtDesc.Text = .fp.Text
    
82.         '//
    
83.         txtQTY.Text = "1"
    
84.         '// ใช้หลักเดิมแต่เปลี่ยนแถว เพื่ออ่านค่าจำนวนเงินในการพิมพ์
    
85.         .fp.Col = ItemNo + 2: .fp.Row = sRow
    
86.         txtUnitPrice.Text = Format(.fp.Text, "#,##0.00")
    
87.         txtAmount.Text = Format(txtUnitPrice.Text, "#,##0.00")
    
88.     End With
    
89.     ' หาจำนวนเงินรวม
    
90.     GrandTotal = Format(GrandTotal + CDbl(txtAmount.Text), "#,##0.00")
    
91.     '// กระโดดไปโปรแกรมย่อย FetchData เข้ามาใหม่
    
92. End Sub
    
93. 
    
94. ' / --------------------------------------------------------------------------------
    
95. Private Sub GroupFooter1_Format()
    
96.     txtGrandTotal.Text = "รวมจำนวนเงินทั้งสิ้น: " & Format(GrandTotal, "#,##0.00") & ""
    
97. End Sub
    
98. 
    
99. ' / --------------------------------------------------------------------------------
    
100. ' / พิมพ์ส่วนหัว
     
101. Private Sub PageHeader_Format()
     
102.     With frmPaymentRoomMain
     
103.         '// เลือกหลัก 1
     
104.         .fp.Col = 1
     
105.         '// แถวที่เลือก
     
106.         .fp.Row = sRow
     
107.         '// รับค่าจากหลัก 1 แถวที่เลือก เพื่อพิมพ์ชื่อผู้เช่า
     
108.         txtCname.Text = "" & .fp.Text
     
109.         .fp.Col = 2
     
110.         '// รับค่าจากหลัก 2 แถวที่เลือก เพื่อพิมพ์หมายเลขห้อง
     
111.         txtRoomNo.Text = "" & .fp.Text
     
112.     End With
     
113.     txtDate.Text = Format(Now(), "dd/mm/yyyy") & " เวลา: " & Format(Now(), "HH:MM")
     
114.     Dim strDate As String
     
115.     '// อ่านชื่อ WorkSheet และทำการตัดค่าบางตัวทิ้งไป คือ $ และ '
     
116.     strDate = frmPaymentRoomMain.cmbWorkSheet.Text
     
117.     strDate = Replace$(strDate, "[        DISCUZ_CODE_1        ]quot;, "")
     
118.     strDate = Replace$(strDate, "'", "")
     
119.     txtDateMonth.Text = strDate
     
120. End Sub

คัดลอกไปที่คลิปบอร์ด

โค้ดในส่วนของ INI เพื่อทำการตั้งค่าหัวข้อและรายละเอียดการพิมพ์

1. Option Explicit
   
2. Dim strFileINI As String
   
3. 
   
4. Private Sub cmdExit_Click()
   
5.     Unload Me
   
6. End Sub
   
7. 
   
8. Private Sub cmdSave_Click()
   
9.     strFileINI = App.Path & "\Config.ini"
   
10.     '// เก็บค่า Config เอาไว้ใน INI ก่อนที่จะไปทำงานอื่นต่อ
    
11.     sWriteINI strFileINI, "Config", "HeaderBill", txtHeaderBill.Text
    
12.     sWriteINI strFileINI, "Config", "Owner", txtOwner.Text
    
13.     sWriteINI strFileINI, "Config", "Address", txtAddress.Text
    
14.     sWriteINI strFileINI, "Config", "Remark1", txtRemark1.Text
    
15.     sWriteINI strFileINI, "Config", "Remark2", txtRemark2.Text
    
16.     MsgBox "บันทึกข้อมูลเรียบร้อย.", vbOKOnly + vbInformation, "รายงานสถานะ"
    
17.     Unload Me
    
18. End Sub
    
19. 
    
20. ' / --------------------------------------------------------------------------------
    
21. Private Sub Form_Load()
    
22.     '/
    
23.     strFileINI = App.Path & "\Config.ini"
    
24.     '// เช็คว่ามีไฟล์ Config.ini อยู่หรือไม่???
    
25.     '// หากไม่มีก็ตั้งค่าเริ่มต้นให้ก่อน
    
26.     If Dir(strFileINI) = "" Then
    
27.         txtHeaderBill.Text = "- ใบแจ้งค่าใช้จ่าย -"
    
28.         txtOwner.Text = "ทองก้อน อพาร์ทเมนท์ แอนด์ โฮมเพลย์สเตชั่น"
    
29.         txtAddress.Text = "123/456 ถ.กลางเมือง ต.เมืองเก่า อ.เมือง จ.ขอนแก่น โทร.043-XXX-XXX"
    
30.         txtRemark1.Text = "[1] กรุณาชำระเงินภายในวันที่ 5 ของทุกเดือน"
    
31.         txtRemark2.Text = "[2] ชำระค่าปรับล่าช้าวันละ 50 บาท"
    
32.         '// เก็บค่า Config เอาไว้ใน INI ก่อนที่จะไปทำงานอื่นต่อ
    
33.         sWriteINI strFileINI, "Config", "HeaderBill", txtHeaderBill.Text
    
34.         sWriteINI strFileINI, "Config", "Owner", txtOwner.Text
    
35.         sWriteINI strFileINI, "Config", "Address", txtAddress.Text
    
36.         sWriteINI strFileINI, "Config", "Remark1", txtRemark1.Text
    
37.         sWriteINI strFileINI, "Config", "Remark2", txtRemark2.Text
    
38.     Else
    
39.         '// อ่านค่า Config ต่างๆเข้ามา
    
40.         txtHeaderBill.Text = sReadINI(strFileINI, "Config", "HeaderBill", "")
    
41.         txtOwner.Text = sReadINI(strFileINI, "Config", "Owner", "")
    
42.         txtAddress.Text = sReadINI(strFileINI, "Config", "Address", "")
    
43.         txtRemark1.Text = sReadINI(strFileINI, "Config", "Remark1", "")
    
44.         txtRemark2.Text = sReadINI(strFileINI, "Config", "Remark2", "")
    
45.     End If
    
46. End Sub
    
47. 
    
48. Private Sub Form_Unload(Cancel As Integer)
    
49.     ' ลบไฟล์ Temporary ออกให้หมด
    
50.     If Dir$(App.Path & "\*.tmp") <> "" Then Kill App.Path & "\*.tmp"
    
51.     Set frmSetup = Nothing
    
52.     Unload Me
    
53. End Sub

คัดลอกไปที่คลิปบอร์ด

โมดูล (Module) ฟังค์ชั่นในการปฏิบัติการกับ Initialized File (modINI.bas) ...

1. Option Explicit
   
2. 
   
3. 'API DECLARATIONS
   
4. Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" ( _
   
5.     ByVal lpApplicationName As String, _
   
6.     ByVal lpKeyName As Any, _
   
7.     ByVal lpDefault As String, _
   
8.     ByVal lpReturnedString As String, _
   
9.     ByVal nSize As Long, _
   
10.     ByVal lpFileName As String _
    
11.     ) As Long
    
12. 
    
13. Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" ( _
    
14.     ByVal lpApplicationName As String, _
    
15.     ByVal lpKeyName As Any, _
    
16.     ByVal lpString As Any, _
    
17.     ByVal lpFileName As String _
    
18.     ) As Long
    
19. 
    
20. Public Function sReadINI(sINIFile As String, sSection As String, sKey As String, sDefault As String) As String
    
21.     Dim sTemp As String * 256
    
22.     Dim nLength As Integer
    
23.     sTemp = Space$(256)
    
24.     nLength = GetPrivateProfileString(sSection, sKey, sDefault, sTemp, 255, sINIFile)
    
25.     sReadINI = Left$(sTemp, nLength)
    
26. End Function
    
27. 
    
28. Public Sub sWriteINI(sINIFile As String, sSection As String, sKey As String, sValue As String)
    
29.     Dim n As Integer
    
30.     Dim sTemp As String
    
31.     sTemp = sValue
    
32.     '/ Replace any CR/LF characters with spaces
    
33.     For n = 1 To Len(sValue)
    
34.         If Mid$(sValue, n, 1) = vbCr Or Mid$(sValue, n, 1) = vbLf Then Mid$(sValue, n) = " "
    
35.     Next n
    
36.     n = WritePrivateProfileString(sSection, sKey, sTemp, sINIFile)
    
37. End Sub

คัดลอกไปที่คลิปบอร์ด

Conclusion: แอดมินไม่ได้ข้ามขั้นตอนสอนวิธีการใช้งาน FarPoint และ ActiveReports แบบเบื้องต้นมาก่อนหรอกครับ แต่มันอยู่ในเว็บบอร์ดตัวเดิมก่อนที่จะย้ายโอสติ้งใหม่ หาก FC VB6 ที่ติดตามแอดมินมาโดยตลอดก็คงจะทราบดีกันอยู่แล้ว แต่สำหรับสมาชิกใหม่หรือท่านที่พึ่งรู้จักกับเว็บบอร์ดของแอดมิน หากมีข้อสงสัยประการใด ก็ขอเรียนเชิญถามมาได้ที่เว็บบอร์ด หรือที่เฟซบุ๊คของแอดมินแทนไปก่อนล่ะกันครับ ...

ดาวน์โหลดโค้ดต้นฉบับแบบเต็ม VB6 ได้ที่นี่ ...

MrDen

สุดยอดครับ แอดมิน

MrDen

ขอบคุณอีกครั้งครับ กำลังจะตามไปเป็นมือใหม่ที่ Dot Net อาจารย์เดินหน้าไปเลยไม่ต้องห่วงหลัง ขอบคุณครับ

downrung

ผมเริ่มกลับมาสนใจตัว FarPoint grapecity อย่างมากๆ แต่ก็ชั่งใจจะถอยกลับไป vb6

thongkorn

downrung ตอบกลับเมื่อ 2023-10-31 17:45
ผมเริ่มกลับมาสนใจตัว FarPoint grapecity อย่างมากๆ แต่ก็ชั่งใจจะถอยกลับไป vb6

ผมจำได้ว่าผมเคยใช้ FarPoint ActiveX บน VB.NET ได้นะครับ