[VB.NET] การสร้างหน้าจอ GUI ของการขายสินค้า แบบกราฟิค หรือโหมดทัชสกรีน

thongkorn

การสร้างหน้าจอ GUI ของการขายสินค้า แบบกราฟิค หรือโหมดทัชสกรีน ... โค้ดชุดนี้ถือว่าอยู่ในขั้นตอนของการออกแบบ จึงไม่มีการติดต่อเข้ากับระบบฐานข้อมูลใดๆ แต่อาศัยการใช้ข้อมูลสมมุติ หรือจำลอง ผ่านทาง DataTable ซึ่งจะมีการแบ่งกลุ่มหรือประเภทสินค้าเอาไว้ให้ 4 กลุ่ม และสามารถแสดงผลรายการสินค้าทั้งหมดออกมาได้ ...
ในการสร้าง Control ในลักษณะไดนามิค แบบนี้ (คือไม่รู้จำนวนรายการสินค้า หรือจำนวนกลุ่มที่แน่นอน) ก็ไม่ได้ยากเย็นมากนัก เริ่มจากการหาจำนวนกลุ่มสินค้าออกมาก่อน (ตัวอย่างมี 4 กลุ่ม + กลุ่มรวมทั้งหมด จะได้ 5 กลุ่ม) จากนั้นก็สร้าง TabPage และ Panel Control (เพื่อตีกรอบ Button Control ไม่ให้ล้น) มารองรับในแต่ละกลุ่ม เมื่อได้ Panel Control มาแล้ว ก็นำเอาจำนวนสินค้าที่อยู่ในแต่ละกลุ่มมาทำการแสดงผล โดยที่มีการคำนวณหาระยะของ Button อยู่ 2 ค่า คือ ...

1. หาค่าตำแหน่ง Left จะมาจากการหารเอาเศษ (MOD)
ตัวอย่างกำหนดเอาไว้ให้แสดงผลปุ่มคำสั่ง (Button) 3 หลัก
หาตำแหน่งซ้าย (Left) ... ด้วยการหารเอาเศษ (Mod) ด้วย 3 จะได้คำตอบ 0, 1, 2 ตลอด เพื่อใช้จัดวางตำแหน่งหลัก Button ได้ทีละ 3 หลัก
การหารเอาเศษจะได้ค่าสูงสุด คือ ค่าตัวหาร (Mod) ลบออก 1 เช่น X Mod 3 จะได้ค่า 0, 1, 2 (หรือ 3 - 1 = 2)
เริ่มนับจาก 0 ไปเรื่อยๆจนกว่าจะหมด (นับไปตามจำนวนรายการสินค้า)
0 Mod 3 = 0, 1 Mod 3 = 1, 2 Mod 3 = 2 ... รอบที่ 1
3 Mod 3 = 0, 4 Mod 3 = 1, 5 Mod 3 = 2 ... รอบที่ 2
6 Mod 3 = 0, 7 Mod 3 = 1, 8 Mod 3 = 2 ... รอบที่ 3 ... ทำไปเรื่อยๆ
มีคำตอบแค่ 0, 1, 2 เราก็เลยหาจำนวนหลักได้ตามที่กำหนด คือ 3 หลัก
เอาค่าที่ได้แต่ละหลักมาคูณความกว้างของปุ่มคำสั่ง
เป็นการเลื่อนตำแหน่งไปทางซ้าย ด้วยการคูณด้วย 0, 1 และ 2 เป็นจำนวนเท่าของความกว้างของ Button
B.Left = (iCount Mod ColCount) * B.Width

2. หาตำแหน่งบน (Top) ... ด้วยการหารตัดเศษ \ ... การหารปกติ 3 / 2 = 1.5, การหารตัดเศษ 3 \ 2 = 1
เริ่มนับจาก 0 ไปเรื่อยๆจนกว่าจะหมด (นับไปตามจำนวนรายการสินค้า)
0 \ 3 = 0, 1 \ 3 = 0, 2 \ 3 = 0 ... รอบที่ 1 (คำตอบคือ 0 เหมือนกัน)
3 \ 3 = 1, 4 \ 3 = 1, 5 \ 3 = 1 ... รอบที่ 2 (คำตอบคือ 1 เหมือนกัน)
6 \ 3 = 2, 7 \ 3 = 2, 8 \ 3 = 2 ... รอบที่ 3 (คำตอบคือ 2 เหมือนกัน) ... ทำไปเรื่อยๆ (คือการเพิ่มตัวคูณเข้าไปทีละ 1)
จะเห็นว่าหลักทั้ง 3 หรือ 3 ปุ่ม (Button) ในแต่ละแถว จะมีค่าคงที่ตลอด ไม่มีการเปลี่ยนค่าเลย จึงทำให้ตำแหน่ง Top ในแต่ละแถวเท่ากันเสมอ
เอาค่าที่ได้จากการหารตัดเศษในแต่ละแถว X (ความสูงของปุ่มคำสั่ง+ความสูงของลาเบล)
แถว 1 จึงคูณ (ความสูงของปุ่มคำสั่ง+ความสูงของลาเบล) ด้วย 0 ดังนั้น Top = 0
แถว 2 จึงคูณ (ความสูงของปุ่มคำสั่ง+ความสูงของลาเบล) ด้วย 1 ดังนั้น Top = (ความสูงของ Button+ความสูงของ Label) X 1
แถว 3 จึงคูณ (ความสูงของปุ่มคำสั่ง+ความสูงของลาเบล) ด้วย 2 ดังนั้น Top = (ความสูงของ Button+ความสูงของ Label) X 2
B.Top = (iCount \ ColCount) * (B.Height + LB.Height)

มาดูโค้ดฉบับเต็มกันเถอะ ...

1. Public Class frmFoodDrinkMain
   
2. 
   
3.     '/ กำหนดตำแหน่งการเก็บไฟล์ภาพ ... โฟลเดอร์เก็บ Execute File\Images\
   
4.     Dim strImagePath As String = MyPath(Application.StartupPath & "Images")
   
5. 
   
6.     ' / --------------------------------------------------------------------------------
   
7.     '/ ฟังค์ชั่นในการกำหนดพาธให้กับโปรแกรม
   
8.     Private Function MyPath(ByVal AppPath As String) As String
   
9.         MyPath = AppPath.ToLower.Replace("\bin\debug", "").Replace("\bin\release", "").Replace("\bin\x86\debug", "")
   
10.         '/ ASCII Code (92) = \ (Backslash)
    
11.         If Microsoft.VisualBasic.Right(MyPath, 1) <> Chr(92) Then MyPath = MyPath & Chr(92)
    
12.     End Function
    
13. 
    
14.     ' / --------------------------------------------------------------------------------
    
15.     '/ Don't forget to set Form has KeyPreview = True
    
16.     '/ เวลาทำการ Debugger ให้ปิด Handle ที่เหตุการณ์นี้
    
17.     Private Sub frmFoodDrinkMain_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
    
18.         Select Case e.KeyCode
    
19.             Case Keys.F8
    
20.                 '/ Remove Row
    
21.                 Call DeleteRow("btnDelRow")
    
22.         End Select
    
23.     End Sub
    
24. 
    
25.     ' / --------------------------------------------------------------------------------
    
26.     '// START HERE
    
27.     Private Sub frmFoodDrinkMain_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
    
28.         Me.KeyPreview = True  '/ สามารถกดปุ่มฟังค์ชั่นคีย์ลงในฟอร์มได้
    
29.         Call InitializeGrid()
    
30.         '// สร้าง TabPage แล้วตามด้วยสร้าง Panel จากนั้นให้สร้างปุ่มคำสั่ง (Button) ตามจำนวนรายการสินค้าที่อยู่ในแต่ละกลุ่ม/ประเภท
    
31.         Call AddTabPage()
    
32.         '//
    
33.         txtSumTotal.ReadOnly = True
    
34.         txtSumTotal.Text = "0.00"
    
35.         lblLastPrice.Text = ""
    
36.     End Sub
    
37. 
    
38.     ' / --------------------------------------------------------------------------------
    
39.     '// เพิ่มแท็บเพจ (TabPage) คอนโทรลแบบไดนามิคลงไปใน TabControl1
    
40.     ' / --------------------------------------------------------------------------------
    
41.     Private Sub AddTabPage()
    
42.         Dim CatDataTable As New DataTable
    
43.         '/ Remove First TabPage
    
44.         Me.TabControl1.TabPages.Remove(TabPage1)
    
45.         '// รับข้อมูลสมมุติมาจากตารางข้อมูล (DataTable) ในการจัดกลุ่ม/ประเภท (Category)
    
46.         CatDataTable = GetCatDataTable()
    
47.         '/ สร้าง Panel ตามจำนวนของกลุ่ม/ประเภท (Category) ในตัวอย่างมี 4 กลุ่ม และกลุ่มรวม (ALL) รวมเป็น 5 กลุ่ม
    
48.         Dim pn(CatDataTable.Rows.Count)
    
49.         Dim iCat As Byte = 0
    
50.         ' Loop and display the keys.
    
51.         For Each CatRow As DataRow In CatDataTable.Rows
    
52.             ' / Create a tabpage
    
53.             Dim tabPg As New TabPage
    
54.             ' / Set the tabpage to be your desired tab.
    
55.             tabPg.Name = "Tab" & CStr(iCat)
    
56.             '// แสดงชื่อกลุ่ม Category ใน TabPage
    
57.             tabPg.Text = CatRow(1).ToString
    
58.             '// เพิ่ม TabPage ลงใน TabControl1
    
59.             Me.TabControl1.Controls.Add(tabPg)
    
60.             '// เพิ่ม Panel
    
61.             pn(iCat) = New Panel
    
62.             pn(iCat).Name = "pn" & iCat
    
63.             '/ สลับสีพื้นหลังของ Panel
    
64.             With pn(iCat)
    
65.                 If (iCat Mod 2) = 0 Then
    
66.                     '/ เลขคู่แสดงสีนี้
    
67.                     .BackColor = Color.Beige
    
68.                 Else
    
69.                     '/ เลขคี่แสดงสีนี้
    
70.                     .BackColor = Color.PaleTurquoise
    
71.                 End If
    
72.                 '/ ปรับคุณสมบัติของ Panel แบบ Run-Time
    
73.                 .Dock = DockStyle.Fill
    
74.                 .Location = New System.Drawing.Point(1, 1)
    
75.                 .Size = New System.Drawing.Size(TabControl1.Width - 10, TabControl1.Height - 30)
    
76.                 .BackColor = Color.Moccasin
    
77.                 .AutoScroll = True
    
78.                 .Anchor = AnchorStyles.Bottom + AnchorStyles.Top
    
79.             End With
    
80.             '/ Add the panel into the TabControl
    
81.             tabPg.Controls.Add(pn(iCat))
    
82.             '/
    
83.             Dim dt As New DataTable
    
84.             dt = GetDataTable(CatRow(0).ToString)
    
85.             ' / --------------------------------------------------------------------------------
    
86.             '/ ไปที่โปรแกรมย่อยการเพิ่มปุ่มคำสั่ง (Button)
    
87.             '/ รอบแรกจะแสดงผลรายการสินค้าทั้งหมด เพราะส่งค่า 0 ออกไป ไม่ตรงกับค่ากลุ่มใดๆ
    
88.             '/ กำหนด 3 หลัก, นับจำนวนรายการเพื่อทำปุ่ม, Panel(กลุ่ม/ประเภทสินค้า), DataTable
    
89.             Call AddButton(3, dt.Rows.Count, pn(iCat), dt)
    
90.             ' / --------------------------------------------------------------------------------
    
91.             iCat += 1
    
92.             dt.Dispose()
    
93.         Next
    
94.         '/ ตั้งค่าที่แท็บเพจตัวแรก (ALL)
    
95.         TabControl1.SelectedIndex = 0
    
96.         CatDataTable.Dispose()
    
97.     End Sub
    
98. 
    
99.     ' / --------------------------------------------------------------------------------
    
100.     '// เพิ่มปุ่มคำสั่งแบบไดนามิค ตามจำนวนในแต่ละกลุ่ม/ประเภทสินค้า
     
101.     ' / --------------------------------------------------------------------------------
     
102.     Private Sub AddButton(ByVal ColCount As Byte, ByVal btnCount As Byte, ByRef pn As Panel, ByRef dt As DataTable)
     
103.         Dim iCount As Byte = 0
     
104.         '/ วนรอบไปจนกว่าจำนวนปุ่ม (Button) มันเกินค่าที่มีอยู่
     
105.         While btnCount <> iCount
     
106.             Dim B As New Button
     
107.             B.Height = 140
     
108.             B.Width = 140
     
109.             Dim LB As New Label
     
110.             With LB
     
111.                 .Height = 40
     
112.                 .Width = 140
     
113.                 '// สลับสีของป้ายลาเบล
     
114.                 If iCount Mod 2 = 0 Then
     
115.                     '// เลขคู่
     
116.                     .BackColor = Color.Orange
     
117.                 Else
     
118.                     '// เลขคี่
     
119.                     .BackColor = Color.Crimson
     
120.                 End If
     
121.             End With
     
122.             pn.Controls.Add(B)  '/ Add Button
     
123.             pn.Controls.Add(LB) '/ Add Label อยู่ด้านล่างของ Button
     
124.             '// Button
     
125.             With B
     
126.                 ' / ตัวอย่างกำหนดเอาไว้ให้แสดงผลปุ่มคำสั่ง (Button) 3 หลัก
     
127.                 ' / --------------------------------------------------------------------------------
     
128.                 '// หาตำแหน่งซ้าย (Left) ... ด้วยการหารเอาเศษ (Mod) ด้วย 3 จะได้คำตอบ 0, 1, 2 ตลอด เพื่อใช้จัดวางตำแหน่งหลัก Button ได้ทีละ 3 หลัก
     
129.                 '// การหารเอาเศษจะได้ค่าสูงสุด คือ ค่าตัวหาร (Mod) ลบออก 1 เช่น X Mod 3 จะได้ค่า 0, 1, 2 (หรือ 3 - 1 = 2)
     
130.                 '// เริ่มนับจาก 0 ไปเรื่อยๆ
     
131.                 '// 0 Mod 3 = 0, 1 Mod 3 = 1, 2 Mod 3 = 2 ... รอบที่ 1
     
132.                 '// 3 Mod 3 = 0, 4 Mod 3 = 1, 5 Mod 3 = 2 ... รอบที่ 2
     
133.                 '// 6 Mod 3 = 0, 7 Mod 3 = 1, 8 Mod 3 = 2 ... รอบที่ 3 ... ทำไปเรื่อยๆ
     
134.                 '// มีคำตอบแค่ 0, 1, 2 เราก็เลยหาจำนวนหลักได้ตามที่กำหนด คือ 3 หลัก
     
135.                 '// เอาค่าที่ได้แต่ละหลักมาคูณความกว้างของปุ่มคำสั่ง
     
136.                 '// เป็นการเลื่อนตำแหน่งไปทางซ้าย ด้วยการคูณด้วย 0, 1 และ 2 เป็นจำนวนเท่าของความกว้างของ Button
     
137.                 .Left = (iCount Mod ColCount) * B.Width
     
138.                 ' / --------------------------------------------------------------------------------
     
139.                 '/ Left ของ Button และ Label จะเท่ากัน
     
140.                 LB.Left = B.Left
     
141.                 ' / --------------------------------------------------------------------------------
     
142.                 '// หาตำแหน่งบน (Top) ... ด้วยการหารตัดเศษ \ ... การหารปกติ 3 / 2 = 1.5, การหารตัดเศษ 3 \ 2 = 1
     
143.                 '// เริ่มนับจาก 0 ไปเรื่อยๆ
     
144.                 '// 0 \ 3 = 0, 1 \ 3 = 0, 2 \ 3 = 0 ... รอบที่ 1 (คำตอบคือ 0 เหมือนกัน)
     
145.                 '// 3 \ 3 = 1, 4 \ 3 = 1, 5 \ 3 = 1 ... รอบที่ 2 (คำตอบคือ 1 เหมือนกัน)
     
146.                 '// 6 \ 3 = 2, 7 \ 3 = 2, 8 \ 3 = 2 ... รอบที่ 3 (คำตอบคือ 2 เหมือนกัน) ... ทำไปเรื่อยๆ (คือการเพิ่มตัวคูณเข้าไปทีละ 1)
     
147.                 '// จะเห็นว่าหลักทั้ง 3 หรือ 3 ปุ่ม (Button) ในแต่ละแถว จะมีค่าคงที่ตลอด ไม่มีการเปลี่ยนค่าเลย จึงทำให้ตำแหน่ง Top ในแต่ละแถวเท่ากันเสมอ
     
148.                 '// เอาค่าที่ได้จากการหารตัดเศษในแต่ละแถว X (ความสูงของปุ่มคำสั่ง+ความสูงของลาเบล)
     
149.                 '// แถว 1 จึงคูณ (ความสูงของปุ่มคำสั่ง+ความสูงของลาเบล) ด้วย 0 ดังนั้น Top = 0
     
150.                 '// แถว 2 จึงคูณ (ความสูงของปุ่มคำสั่ง+ความสูงของลาเบล) ด้วย 1 ดังนั้น Top = (ความสูงของ Button+ความสูงของ Label) X 1
     
151.                 '// แถว 3 จึงคูณ (ความสูงของปุ่มคำสั่ง+ความสูงของลาเบล) ด้วย 2 ดังนั้น Top = (ความสูงของ Button+ความสูงของ Label) X 2
     
152.                 .Top = (iCount \ ColCount) * (B.Height + LB.Height)
     
153.                 ' / --------------------------------------------------------------------------------
     
154.                 Dim row As DataRow = dt.Rows(iCount)
     
155.                 .Name = "Button" & row(0).ToString
     
156.                 .Text = "ID : " & row(1).ToString
     
157.                 '// นำค่า ProductPK (Primary Key) ไปซ่อนไว้ในคุณสมบัติ Tag ของ Button ในแต่ละตัว ซึ่งเราจะใช้ค่านี้เมื่อตอนคลิ๊กกดปุ่มคำสั่งในแต่ละตัว
     
158.                 '// เพื่อนำไปเปรียบเทียบค่าในตารางกริด (หลัก 0) หรือการค้นหาข้อมูลสินค้าด้วยค่า Primary Key
     
159.                 '// หรือใครที่กำหนดฟิลด์เอาไว้แค่ ID โดยไม่มี PK ... ก็ใช้ให้ ID ไปเลยก็ได้
     
160.                 .Tag = row(0).ToString
     
161.                 '// ทำการแสดงผลภาพลงบนปุ่ม
     
162.                 Dim imgFile As String = strImagePath & row(4).ToString
     
163.                 '/ ถ้าไม่ได้กำหนดรูป หรือหารูปภาพไม่เจอ ให้ใส่ภาพ NoImage.jpg ป้องกัน Error
     
164.                 If Not System.IO.File.Exists(imgFile) Then imgFile = strImagePath & "NoImage.jpg"
     
165.                 '/ นำภาพไปแสดงบน Button
     
166.                 .BackgroundImage = New System.Drawing.Bitmap(imgFile)
     
167.                 .BackgroundImageLayout = ImageLayout.Stretch
     
168.                 '/ ปรับคุณสมบัติ Button
     
169.                 .Font = New Font("Century Gothic", 10, FontStyle.Bold)
     
170.                 .ForeColor = Color.Black
     
171.                 .TextAlign = ContentAlignment.BottomCenter
     
172.                 .TextImageRelation = TextImageRelation.ImageAboveText
     
173.                 .UseVisualStyleBackColor = True
     
174.                 .Cursor = Cursors.Hand
     
175.                 .FlatStyle = FlatStyle.Standard
     
176.                 '// ปรับคุณสมบัติของ Label
     
177.                 With LB
     
178.                     .TextAlign = ContentAlignment.MiddleCenter
     
179.                     .Top = B.Top + B.Height
     
180.                     .ForeColor = Color.White
     
181.                     .Font = New Font("Tahoma", 10, FontStyle.Bold)
     
182.                     '/ Label ป้ายบอกเพื่อแสดงราคาใน Label
     
183.                     .Text = row(2).ToString & vbCrLf & "ราคา: " & Format(Convert.ToDecimal(row(3).ToString), "#,##0.00")
     
184.                 End With
     
185.             End With
     
186.             iCount += 1
     
187.             ' / --------------------------------------------------------------------------------
     
188.             '// Event Handler ในการกดคลิ๊กที่ปุ่มคำสั่ง (Button)
     
189.             AddHandler B.Click, AddressOf ClickButton
     
190.             ' / --------------------------------------------------------------------------------
     
191.         End While
     
192.     End Sub
     
193. 
     
194.     ' / --------------------------------------------------------------------------------
     
195.     Public Sub ClickButton(ByVal sender As Object, ByVal e As System.EventArgs)
     
196.         Dim btn As Button = sender
     
197.         'MessageBox.Show("Primary Key: " & btn.Tag)
     
198.         '/ นำ Tag ซึ่งเก็บค่า ProductPK ไปใช้งานในการค้นหาสินค้า
     
199.         Call AddToDataGridView(btn.Tag)
     
200.     End Sub
     
201. 
     
202.     ' / --------------------------------------------------------------------------------
     
203.     ' / ค้นหารายการสินค้าของเดิมในตารางกริด ก่อนที่จะเพิ่มรายการแถวใหม่
     
204.     ' / อันนี้เขียนโค้ดกลับด้านกับเหตุการณ์ txtSearch_KeyPress
     
205.     ' / โดยใช้ค่า ProductPK (Primary Key ที่เป็นเลขจำนวนเต็ม) มาเปรียบเทียบกับค่าในตารางกริดก่อน
     
206.     ' / หากหาข้อมูลในตารางกริดไม่เจอ ก็จะไปค้นจาก DataTable อีกที
     
207.     ' / --------------------------------------------------------------------------------
     
208.     Private Sub AddToDataGridView(ByVal PK As Integer)
     
209.         Dim blnExist As Boolean = False
     
210.         '// ตรวจสอบว่า Primary Key มีอยู่ในตารางกริดหรือไม่ (หากมีให้ +เพิ่ม, หากไม่มีค่อยไปค้นหาข้อมูล)
     
211.         For iRow As Integer = 0 To dgvData.RowCount - 1
     
212.             ' / หากพบ Primary Key ในหลัก 0 มาตรงกันกับค่าในแถวของตารางกริด
     
213.             ' / ค่า Primary Key (PK) ตัวนี้ได้จากการกดปุ่ม (Button) โดยซ่อนค่าไว้ในคุณสมบัติ Tag ของ Button
     
214.             If dgvData.Rows(iRow).Cells(0).Value = PK Then
     
215.                 ' / ให้บวกจำนวนที่เลือกเพิ่มขึ้นอีก 1 (Quantity = Quantity + 1)
     
216.                 dgvData.Rows(iRow).Cells(3).Value = dgvData.Rows(iRow).Cells(3).Value + 1
     
217.                 '/ หลัก Index = 4 คือ UnitPrice
     
218.                 lblLastPrice.Text = "Last Price: " & Format(CDbl(dgvData.Rows(iRow).Cells(4).Value), "#,##0.00")
     
219.                 '// เจอข้อมูลเดิม
     
220.                 blnExist = True
     
221.                 '// ออกจากลูปไปเลย เพื่อไม่ให้เสียเวลา
     
222.                 Exit For
     
223.             End If
     
224.         Next
     
225.         '// ไม่พบข้อมูลในตารางกริด ก็ทำการเรียกจากตารางข้อมูลเข้ามาแสดงผล
     
226.         If Not blnExist Then
     
227.             '/ สร้าง DataTable สมมุติขึ้นมา
     
228.             Dim DT As DataTable = GetDataTable()
     
229.             '/ ค้นหาข้อมูลจาก DataTable แล้วรับค่ามาใส่ไว้ใน DataRow
     
230.             '/ การค้นหาข้อมูลแบบเลขจำนวนเต็ม เช่น ProductPK = 1
     
231.             Dim r() As DataRow = DT.Select(" ProductPK = " & PK)
     
232.             '// หากพบข้อมูลใน DataTable
     
233.             If r.Count > 0 Then
     
234.                 '/ จากโครงสร้าง DataTable
     
235.                 '/ Primary Key, Product ID, Product Name, Quantity, UnitPrice, Total
     
236.                 dgvData.Rows.Add(r(0).Item(0), r(0).Item(1), r(0).Item(2), "1", Format(CDbl(r(0).Item(3).ToString), "0.00"), "0.00")
     
237.                 lblLastPrice.Text = "Last Price: " & CDbl(r(0).Item(3)).ToString("0.00")
     
238.             End If
     
239.             DT.Dispose()
     
240.         End If
     
241.         '// หาจำนวนเงินรวมใหม่
     
242.         Call CalSumTotal()
     
243.         '// โฟกัสไปที่ DataGridView แล้วย้ายไปแถวล่าสุด และไปทางซ้ายเพื่อไปที่ช่องจำนวน (Quantity)
     
244.         'dgvData.Focus()
     
245.         'SendKeys.Send("^{END}{LEFT}{LEFT}{LEFT}")
     
246.     End Sub
     
247. 
     
248.     ' / --------------------------------------------------------------------------------
     
249.     ' / DataTable ของกลุ่ม/ประเภทสินค้า (Category)
     
250.     ' / --------------------------------------------------------------------------------
     
251.     Function GetCatDataTable() As DataTable
     
252.         Dim DT As New DataTable
     
253.         With DT
     
254.             .Columns.Add("CategoryPK", GetType(Byte)) '<<< Index = 0
     
255.             .Columns.Add("CategoryName", GetType(String))    '<< Index = 1
     
256.         End With
     
257.         '// ... Add rows in the Category.
     
258.         With DT
     
259.             .Rows.Add(0, "ALL")
     
260.             .Rows.Add(1, "Coffee")
     
261.             .Rows.Add(2, "Burger")
     
262.             .Rows.Add(3, "Soft Drink")
     
263.             .Rows.Add(4, "Beverages")
     
264.         End With
     
265.         Return DT
     
266.     End Function
     
267. 
     
268.     ' / --------------------------------------------------------------------------------
     
269.     ' / S A M P L E ... D A T A T A B L E (Products)
     
270.     ' / --------------------------------------------------------------------------------
     
271.     Function GetDataTable(Optional ByVal Cat As Byte = 0) As DataTable
     
272.         '// Add Column
     
273.         Dim DT As New DataTable
     
274.         With DT
     
275.             .Columns.Add("ProductPK", GetType(Integer)) '<< Index = 0
     
276.             .Columns.Add("ProductID", GetType(String))    '<< 1
     
277.             .Columns.Add("ProductName", GetType(String)) '<< 2
     
278.             .Columns.Add("UnitPrice", GetType(Double)) '<< 3
     
279.             .Columns.Add("PictureName", GetType(String)) '<< 4
     
280.             .Columns.Add("CategoryFK", GetType(Byte))   '<< 5 (เอากลุ่ม/ประเภทสินค้า Foreign Key มาไว้ท้ายสุด เพราะในตารางข้อมูลจริงจะเชื่อมความสัมพันธ์กัน)
     
281.         End With
     
282.         '// ... Add rows in the first category. (1 - Coffee)
     
283.         '/ ProductPK, ProductID, ProductName, UnitPrice, PictureName, CategoryFK
     
284.         With DT.Rows
     
285.             .Add(1, "01", "กาแฟร้อน", "50.00", "Coffee.jpg", 1)
     
286.             .Add(2, "02", "กาแฟเย็น", "60.00", "Coffee4.png", 1)
     
287.             .Add(3, "03", "คาปูชิโน่", "75.00", "Cappuccino.jpg", 1)
     
288.             .Add(4, "04", "คาปูชิโน่ - ลาเต้", "80.00", "CappuccinoLatte.jpg", 1)
     
289.             .Add(5, "05", "เอ็กซ์เพรสโซ่", "90.00", "Expresso.jpg", 1)
     
290.         End With
     
291.         '// ... Add rows in category. (2 - Burger)
     
292.         With DT.Rows
     
293.             .Add(11, "11", "Classic Chicken", "20.00", "BurgerChicken.png", 2)
     
294.             .Add(12, "12", "Mexicana", "25.00", "BurgerMexicana.png", 2)
     
295.             .Add(13, "13", "Lemon Shrimp", "30.00", "BurgerLemonShrimp.png", 2)
     
296.             .Add(14, "14", "Bacon", "40.00", "BurgerBacon.png", 2)
     
297.             .Add(15, "15", "Spicy Shrimp", "45.00", "BurgerSpicyShrimp.png", 2)
     
298.             .Add(16, "16", "Tex Supreme", "50.00", "BurgerTexSupreme.png", 2)
     
299.             .Add(17, "17", "Fish", "55.00", "BurgerFish.png", 2)
     
300.         End With
     
301.         '// ... Add rows in category. (3 - Soft Drink)
     
302.         With DT.Rows
     
303.             .Add(21, "21", "Pepsi Can", "20.00", "PepsiCan.png", 3)
     
304.             .Add(22, "22", "Coke Can", "20.00", "CokeCan.png", 3)
     
305.             .Add(23, "23", "7Up Can", "20.00", "7upCan.png", 3)
     
306.             .Add(24, "24", "Pepsi 2 ลิตร", "50.00", "Pepsi2L.jpg", 3)
     
307.             .Add(25, "25", "Coke 2 ลิตร", "50.00", "Coke2L.jpg", 3)
     
308.             .Add(26, "26", "น้ำเปล่า", "15.00", "Water.jpg", 3)
     
309.         End With
     
310.         '// ... Add rows in category. (4 - Whisky)
     
311.         With DT.Rows
     
312.             .Add(41, "41", "วิสกี้ (เพียว)", "100.00", "Whisky.jpg", 4)
     
313.             .Add(42, "42", "เหล้าขาว (เป๊ก)", "40.00", "Pek.png", 4)
     
314.             .Add(43, "43", "ม้ากระทืบโรง (เป๊ก)", "50.00", "Horse.jpg", 4)
     
315.             .Add(44, "44", "เบียร์สิงห์ (กระป๋อง)", "80.00", "SinghaCan.jpg", 4)
     
316.             .Add(45, "45", "เบียร์ลีโอ (กระป๋อง)", "70.00", "LeoCan.jpg", 4)
     
317.             .Add(46, "46", "เบียร์ช้าง (กระป๋อง)", "70.00", "ChangCan.jpg", 4)
     
318.             .Add(47, "47", "Spy Wine Cooler", "50.00", "Spy.jpg", 4)
     
319.             .Add(48, "48", "โซจู (สตรอเบอรี่)", "90.00", "Soju.jpg", 4)
     
320.         End With
     
321.         '// กรองเอาเฉพาะพวกที่แบ่งกลุ่ม/ประเภทสินค้า โดยมีการค้นหาด้วย CategoryFK (หลักสุดท้ายใน DataTable)
     
322.         If Cat > 0 Then
     
323.             Dim Result() As DataRow = DT.Select("CategoryFK = " & Cat)
     
324.             Dim MyDT As New DataTable
     
325.             If Not Result.Length = 0 Then MyDT = Result.CopyToDataTable
     
326.             Return MyDT
     
327.             '// เอาข้อมูลสินค้าทั้งหมด
     
328.         Else
     
329.             Return DT
     
330.         End If
     
331.     End Function
     
332. 
     
333.     ' / --------------------------------------------------------------------------------
     
334.     ' / ตั้งค่าเริ่มต้นให้กับ DataGridView แบบ Run Time (ใช้โค้ดทั้งหมด)
     
335.     Private Sub InitializeGrid()
     
336.         With dgvData
     
337.             .RowHeadersVisible = False
     
338.             .AllowUserToAddRows = False
     
339.             .AllowUserToDeleteRows = False
     
340.             .AllowUserToResizeRows = False
     
341.             .MultiSelect = False
     
342.             .ReadOnly = False
     
343.             .RowTemplate.MinimumHeight = 27
     
344.             .RowTemplate.Height = 27
     
345.             '/ Columns Specified
     
346.             '/ Index = 0
     
347.             .Columns.Add("PK", "Primary Key")
     
348.             With .Columns("PK")
     
349.                 .ReadOnly = True
     
350.                 .DefaultCellStyle.BackColor = Color.LightGoldenrodYellow
     
351.                 .Visible = False '/ ปกติหลัก Primary Key จะต้องถูกซ่อนไว้
     
352.             End With
     
353.             '/ Index = 1
     
354.             .Columns.Add("ProductID", "Product ID")
     
355.             .Columns("ProductID").ReadOnly = True
     
356.             .Columns("ProductID").Visible = False
     
357.             '/ Index = 2
     
358.             .Columns.Add("ProductName", "Product Name")
     
359.             .Columns("ProductName").ReadOnly = True
     
360.             .Columns("ProductName").DefaultCellStyle.BackColor = Color.LightGoldenrodYellow
     
361.             '/ Index = 3
     
362.             .Columns.Add("Quantity", "Quantity")
     
363.             .Columns("Quantity").ValueType = GetType(Integer)
     
364.             '/ Index = 4
     
365.             .Columns.Add("UnitPrice", "Unit Price")
     
366.             .Columns("UnitPrice").ValueType = GetType(Double)
     
367.             '/ Index = 5
     
368.             .Columns.Add("Total", "Total")
     
369.             .Columns("Total").ValueType = GetType(Double)
     
370.             .Font = New Font("Tahoma", 11)
     
371.             '/ Total Column (5)
     
372.             With .Columns("Total")
     
373.                 .ReadOnly = True
     
374.                 .DefaultCellStyle.BackColor = Color.LightGoldenrodYellow
     
375.                 .DefaultCellStyle.ForeColor = Color.Blue
     
376.                 .DefaultCellStyle.Font = New Font(dgvData.Font, FontStyle.Bold)
     
377.             End With
     
378.             '// เพิ่มปุ่มลบ (Index = 6)
     
379.             Dim btnDelRow As New DataGridViewButtonColumn
     
380.             dgvData.Columns.Add(btnDelRow)
     
381.             With btnDelRow
     
382.                 .HeaderText = "Delete F8"
     
383.                 .Text = "Delete"
     
384.                 .UseColumnTextForButtonValue = True
     
385.                 .Width = 30
     
386.                 .ReadOnly = True
     
387.                 .HeaderCell.Style.Alignment = DataGridViewContentAlignment.MiddleCenter
     
388.                 .SortMode = DataGridViewColumnSortMode.NotSortable  '/ Not sort order but can click header for delete row.
     
389.             End With
     
390.             '/ Alignment MiddleRight only columns 3 to 5
     
391.             For i As Byte = 3 To 5
     
392.                 '/ Header Alignment
     
393.                 .Columns(i).HeaderCell.Style.Alignment = DataGridViewContentAlignment.MiddleRight
     
394.                 '/ Cell Alignment
     
395.                 .Columns(i).DefaultCellStyle.Alignment = DataGridViewContentAlignment.MiddleRight
     
396.             Next
     
397.             '/ Auto size column width of each main by sorting the field.
     
398.             .AutoSizeColumnsMode = DataGridViewAutoSizeColumnsMode.Fill
     
399.             '/ Adjust Header Styles
     
400.             With .ColumnHeadersDefaultCellStyle
     
401.                 .BackColor = Color.RoyalBlue
     
402.                 .ForeColor = Color.White
     
403.                 .Font = New Font("Tahoma", 11, FontStyle.Bold)
     
404.             End With
     
405.             .ColumnHeadersHeightSizeMode = DataGridViewColumnHeadersHeightSizeMode.DisableResizing
     
406.             .ColumnHeadersHeight = 36
     
407.             '/ กำหนดให้ EnableHeadersVisualStyles = False เพื่อให้ยอมรับการเปลี่ยนแปลงสีพื้นหลังของ Header
     
408.             .EnableHeadersVisualStyles = False
     
409.         End With
     
410. 
     
411.     End Sub
     
412. 
     
413.     ' / --------------------------------------------------------------------------------
     
414.     ' / การค้นหาข้อมูลในช่อง TextBox
     
415.     ' / --------------------------------------------------------------------------------
     
416.     Private Sub txtSearch_KeyPress(sender As Object, e As System.Windows.Forms.KeyPressEventArgs) Handles txtSearch.KeyPress
     
417.         '// เมื่อกดคีย์ ENTER เพื่อเริ่มต้นการค้นหาข้อมูล
     
418.         If e.KeyChar = Chr(13) Then
     
419.             '/ Replace some word for reserved in DataBase.
     
420.             txtSearch.Text = txtSearch.Text.Trim.Replace("'", "").Replace("*", "").Replace("%", "")
     
421.             e.Handled = True    '// ปิดเสียง
     
422.             '/ สร้าง DataTable สมมุติขึ้นมา
     
423.             Dim DT As DataTable = GetDataTable()
     
424.             '/ ค้นหาข้อมูลจาก DataTable แล้วรับค่ามาใส่ไว้ใน DataRow
     
425.             '/ การค้นหาข้อมูลแบบ String จะต้องใส่เครื่องหมาย Single Quote ครอบเอาไว้ เช่น ProductID = '01'
     
426.             Dim r() As DataRow = DT.Select(" ProductID = " & "'" & txtSearch.Text.Trim & "'")
     
427.             '// หากพบข้อมูลใน DataTable
     
428.             If r.Count > 0 Then
     
429.                 '/ ตัวแปรบูลีน Flag แจ้งการค้นหาข้อมูลในตารางกริด (True = พบรายการในแถว, False = ไม่พบ)
     
430.                 Dim blnExist As Boolean = False
     
431.                 '/ ต้องค้นหาข้อมูลจากตารางกริดก่อน เพื่อค้นหาว่ามีรายการสินค้าเดิมหรือไม่?
     
432.                 '/ หากในตารางกริดยังไม่มีแถวรายการ ก็จะข้าม For Loop นี้ไปเพิ่มรายการใหม่ทันที (ครั้งแรกที่ยังไม่มีข้อมูลในตารางกริด)
     
433.                 For iRow As Integer = 0 To dgvData.RowCount - 1
     
434.                     '/ ทดสอบด้วย Primary Key r(0).Item(0) หรือ Product ID r(0).Item(1) ก็ได้
     
435.                     If r(0).Item(0) = dgvData.Rows(iRow).Cells(0).Value Then
     
436.                         '/ เมื่อพบรายการเดิม ก็ให้เพิ่มจำนวนขึ้น 1
     
437.                         dgvData.Rows(iRow).Cells(3).Value += 1
     
438.                         lblLastPrice.Text = "Last Price: " & CDbl(dgvData.Rows(iRow).Cells(4).Value).ToString("0.00")
     
439.                         '/ Flag แจ้งว่าพบข้อมูลเดิมแล้ว
     
440.                         blnExist = True
     
441.                         '/ เมื่อเจอสินค้าเดิมในตารางกริดแล้ว ไม่ว่าจะอยู่แถวลำดับที่เท่าไหร่ ก็ให้ออกจาก For Loop การค้นหาได้เลย
     
442.                         '/ เพราะรายการสินค้าใดๆ จะต้องมีอยู่เพียงแค่รายการเดียว ไม่ต้องเสียเวลาวนรอบกลับไปทำให้จนครบจำนวนแถว
     
443.                         Exit For
     
444.                     End If
     
445.                 Next
     
446.                 '/ กรณีที่พบสินค้าในตารางกริด กำหนด blnExist = True ทำให้ Not True = False จะทำให้ข้ามเงื่อนไขนี้ออกไป
     
447.                 '/ กรณีที่ไม่พบข้อมูลสินค้าเดิมในตารางกริด กำหนด blnExist = False ทำให้ Not False = True เพิ่มรายการสินค้าแถวใหม่เข้าไปในตารางกริดได้
     
448.                 If Not blnExist Then
     
449.                     '/ Primary Key, Product ID, Product Name, Quantity, UnitPrice, Total
     
450.                     dgvData.Rows.Add(r(0).Item(0), r(0).Item(1), r(0).Item(2), "1", Format(CDbl(r(0).Item(3).ToString), "0.00"), "0.00")
     
451.                     lblLastPrice.Text = "Last Price: " & CDbl(r(0).Item(3)).ToString("0.00")
     
452.                 End If
     
453.                 '/ หากไม่ใช้ NOT ก็จะต้องเขียนโปรแกรมแบบนี้
     
454.                 '/ If blnExist = True Then
     
455.                 '/     ไม่ต้องทำอะไร
     
456.                 '/ Else
     
457.                 '/     ทำคำสั่งเพิ่มรายการ
     
458.                 '/ End If
     
459.                 '// คำนวณผลรวมใหม่
     
460.                 Call CalSumTotal()
     
461.                 DT.Dispose()
     
462.             End If
     
463.             txtSearch.Clear()
     
464.             txtSearch.Focus()
     
465.         End If
     
466.     End Sub
     
467. 
     
468.     ' / --------------------------------------------------------------------------------
     
469.     ' / Calcualte sum of Total (Column Index = 5)
     
470.     ' / ทำทุกครั้งที่มีการเพิ่มหรือลบแถวรายการ และมีการเปลี่ยนแปลงค่าในเซลล์ Quantity, UnitPrice
     
471.     Private Sub CalSumTotal()
     
472.         txtSumTotal.Text = "0.00"
     
473.         '/ วนรอบตามจำนวนแถวที่มีอยู่ปัจจุบัน
     
474.         For i As Integer = 0 To dgvData.RowCount - 1
     
475.             '/ หลักสุดท้ายของตารางกริด = [จำนวน x ราคา]
     
476.             dgvData.Rows(i).Cells(5).Value = Format(dgvData.Rows(i).Cells(3).Value * dgvData.Rows(i).Cells(4).Value, "#,##0.00")
     
477.             '/ นำค่าจาก Total มารวมกันเพื่อแสดงผลในสรุปผลรวม (x = x + y)
     
478.             txtSumTotal.Text = Format(CDbl(txtSumTotal.Text) + CDbl(dgvData.Rows(i).Cells(5).Value), "#,##0.00")
     
479.         Next
     
480.     End Sub
     
481. 
     
482.     ' / --------------------------------------------------------------------------------
     
483.     ' / โปรแกรมย่อยในการลบแถวรายการที่เลือกออกไป
     
484.     Private Sub DeleteRow(ByVal ColName As String)
     
485.         If dgvData.RowCount = 0 Then Return
     
486.         '/ ColName เป็นชื่อของหลัก Index = 6 ของตารางกริด (ไปดูที่โปรแกรมย่อย InitializeGrid)
     
487.         If ColName = "btnDelRow" Then
     
488.             '// ลบรายการแถวที่เลือกออกไป
     
489.             dgvData.Rows.Remove(dgvData.CurrentRow)
     
490.             '/ เมื่อแถวรายการถูกลบออกไป ต้องไปคำนวณหาค่าผลรวมใหม่
     
491.             Call CalSumTotal()
     
492.         End If
     
493.         txtSearch.Focus()
     
494.     End Sub
     
495. 
     
496.     ' / --------------------------------------------------------------------------------
     
497.     ' / ปุ่มลดจำนวนสินค้าลงทีละ 1 ... แถวของตารางกริดที่ถูกโฟกัส
     
498.     Private Sub btnDecrement_Click(sender As System.Object, e As System.EventArgs) Handles btnDecrement.Click
     
499.         If dgvData.RowCount = 0 Then Return
     
500.         dgvData.Focus()
     
501.         For iRow As Integer = 0 To dgvData.RowCount - 1
     
502.             ' / หากพบ Primary Key ในหลัก 0 มาตรงกันกับค่าปัจจุบันในแถวของตารางกริด
     
503.             If dgvData.Rows(iRow).Cells(0).Value = dgvData.CurrentRow.Cells(0).Value Then
     
504.                 If dgvData.Rows(iRow).Cells(3).Value = 0 Then
     
505.                     '/ หรือหากจำนวนมีค่าเป็น 0 ก็ลบแถวออกไปเลย
     
506.                     'dgvData.Rows.Remove(dgvData.CurrentRow)
     
507.                     'dgvData.Refresh()
     
508.                     Exit For
     
509.                 Else
     
510.                     ' / ให้ลดจำนวนลง 1 (Quantity = Quantity - 1)
     
511.                     dgvData.Rows(iRow).Cells(3).Value -= 1
     
512.                     Exit For
     
513.                 End If
     
514.             End If
     
515.         Next
     
516.         '// รวมจำนวนเงิน
     
517.         Call CalSumTotal()
     
518.     End Sub
     
519. 
     
520.     ' / --------------------------------------------------------------------------------
     
521.     ' / ปุ่มเพิ่มจำนวนสินค้าขึ้นทีละ 1 ... แถวของตารางกริดที่ถูกโฟกัส
     
522.     Private Sub btnIncrement_Click(sender As System.Object, e As System.EventArgs) Handles btnIncrement.Click
     
523.         If dgvData.RowCount = 0 Then Return
     
524.         dgvData.Focus()
     
525.         For iRow As Integer = 0 To dgvData.RowCount - 1
     
526.             ' / หากพบ Primary Key ในหลัก 0 มาตรงกันกับค่าปัจจุบันในแถวของตารางกริด
     
527.             If dgvData.Rows(iRow).Cells(0).Value = dgvData.CurrentRow.Cells(0).Value Then
     
528.                 ' / ให้เพิ่มจำนวนขึ้น 1 (Quantity = Quantity + 1)
     
529.                 dgvData.Rows(iRow).Cells(3).Value += 1
     
530.                 Exit For
     
531.             End If
     
532.         Next
     
533.         '// รวมจำนวนเงิน
     
534.         Call CalSumTotal()
     
535.     End Sub
     
536. 
     
537.     Private Sub dgvData_CellClick(sender As Object, e As System.Windows.Forms.DataGridViewCellEventArgs) Handles dgvData.CellClick
     
538.         Select Case e.ColumnIndex
     
539.             '// Delete Button
     
540.             Case 6
     
541.                 'MsgBox(("Row : " + e.RowIndex.ToString & "  Col : ") + e.ColumnIndex.ToString)
     
542.                 Call DeleteRow("btnDelRow")
     
543.         End Select
     
544.     End Sub
     
545. 
     
546.     ' / --------------------------------------------------------------------------------
     
547.     ' / After you press Enter
     
548.     Private Sub dgvData_CellEndEdit(ByVal sender As Object, ByVal e As System.Windows.Forms.DataGridViewCellEventArgs) Handles dgvData.CellEndEdit
     
549.         '/ เกิดการเปลี่ยนแปลงค่าในหลัก Index ที่ 3 หรือ 4
     
550.         Select Case e.ColumnIndex
     
551.             Case 3, 4 '/ Column Index = 3 (Quantity), Column Index = 4 (UnitPrice)
     
552.                 '/ Quantity
     
553.                 '/ การดัก Error กรณีมีค่า Null Value ให้ใส่ค่า 0 ลงไปแทน
     
554.                 If IsDBNull(dgvData.Rows(e.RowIndex).Cells(3).Value) Then dgvData.Rows(e.RowIndex).Cells(3).Value = "0"
     
555.                 Dim Quantity As Integer = dgvData.Rows(e.RowIndex).Cells(3).Value
     
556.                 '/ UnitPrice
     
557.                 '/ If Null Value
     
558.                 If IsDBNull(dgvData.Rows(e.RowIndex).Cells(4).Value) Then dgvData.Rows(e.RowIndex).Cells(4).Value = "0.00"
     
559.                 Dim UnitPrice As Double = dgvData.Rows(e.RowIndex).Cells(4).Value
     
560.                 dgvData.Rows(e.RowIndex).Cells(4).Value = Format(CDbl(dgvData.Rows(e.RowIndex).Cells(4).Value), "0.00")
     
561. 
     
562.                 '/ Quantity x UnitPrice
     
563.                 dgvData.Rows(e.RowIndex).Cells(5).Value = CDbl((Quantity * UnitPrice).ToString("#,##0.00"))
     
564.                 '/ Calculate Summary
     
565.                 Call CalSumTotal()
     
566.         End Select
     
567.     End Sub
     
568. 
     
569.     ' / --------------------------------------------------------------------------------
     
570.     Private Sub dgvData_EditingControlShowing(ByVal sender As Object, ByVal e As System.Windows.Forms.DataGridViewEditingControlShowingEventArgs) Handles dgvData.EditingControlShowing
     
571.         Select Case dgvData.Columns(dgvData.CurrentCell.ColumnIndex).Name
     
572.             ' / Can use both Colume Index or Field Name
     
573.             Case "Quantity", "UnitPrice"
     
574.                 '/ Stop and Start event handler
     
575.                 RemoveHandler e.Control.KeyPress, AddressOf ValidKeyPress
     
576.                 AddHandler e.Control.KeyPress, AddressOf ValidKeyPress
     
577.         End Select
     
578.     End Sub
     
579. 
     
580.     ' / --------------------------------------------------------------------------------
     
581.     Private Sub ValidKeyPress(ByVal sender As System.Object, ByVal e As System.Windows.Forms.KeyPressEventArgs)
     
582.         Dim tb As TextBox = sender
     
583.         Select Case dgvData.CurrentCell.ColumnIndex
     
584.             Case 3  ' Quantity is Integer
     
585.                 Select Case e.KeyChar
     
586.                     Case "0" To "9"   ' digits 0 - 9 allowed
     
587.                     Case ChrW(Keys.Back)    ' backspace allowed for deleting (Delete key automatically overrides)
     
588. 
     
589.                     Case Else ' everything else ....
     
590.                         ' True = CPU cancel the KeyPress event
     
591.                         e.Handled = True ' and it's just like you never pressed a key at all
     
592.                 End Select
     
593. 
     
594.             Case 4  ' UnitPrice is Double
     
595.                 Select Case e.KeyChar
     
596.                     Case "0" To "9"
     
597.                         ' Allowed "."
     
598.                     Case "."
     
599.                         ' can present "." only one
     
600.                         If InStr(tb.Text, ".") Then e.Handled = True
     
601. 
     
602.                     Case ChrW(Keys.Back)
     
603.                         '/ Return False is Default value
     
604. 
     
605.                     Case Else
     
606.                         e.Handled = True
     
607. 
     
608.                 End Select
     
609.         End Select
     
610.     End Sub
     
611. 
     
612.     Private Sub frmFoodDrinkMain_FormClosed(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
     
613.         Me.Dispose()
     
614.         GC.SuppressFinalize(Me)
     
615.         Application.Exit()
     
616.     End Sub
     
617. 
     
618. End Class

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดต้นฉบับ VB.NET (2010) ได้จากที่นี่ ...